Excel Maniacs

第59回 整序問題 解答例

急遽、外出することになってしまい

minさんから、解答例を頂いて

それをUPすることができません。

申し訳ありませんが、解答用の板を立てて

おきますので、よろしくお願いします。

尚、きっちーさんから、解答ファイルを頂いておりますので

ご覧下さい。

きっちーさんのファイル：2010_Q59_kittii.lzhをダウンロード

・・・と言っていたら、minさんから解答例が届きました。

＊

＊

＊

さて、今回の問題ですが、
大したアイデアは出ませんでした。
気に入ったものはありませんが出題者としては出さないわけに
はいかないので、

３ケタの整数のみでは、８４文字
{=INDEX(A:A,MATCH(LARGE(-LEFT(A$2:A$11&"00",3),ROW()-1),-LEFT(A$2:A$11&"00",3),)+1)}

少数あり、桁数制限なしでは、１２８文字
{=IF((A3<"")*SUM(N(A$2:A$12=C3),-(C3:C$12=C3)),C3,INDEX(A:A,MATCH(ROW(),MMULT(H1:S1+1,N(0&A$1:A$12<=0&TRANSPOSE(A$1:A$12))),)))}


作業列ありでは、計７０文字
{=SUM(N(0&A$2:A$11<0&A2),N(A$1:A2=A2))}
=INDEX(A:A,MATCH(ROW(A1),B:B,))

でした。

皆さんのアイデア、、ずるを含めて楽しみです。

　　　　　　　　　　　　　　　　　　　　　　　　　　　（minさん談）

第５９問 整序問題

【問題】

A列の数値を並び替えてC列に表示するだけです。　

ただし、並び替えのルールは、先頭の数値が小さい順に並び替えます。

したがって、

　　１１１と９を比較すると１１１のほうが上
　　１１１と１９を比較すると１１１のほうが上

に表示されます。

数値は、一応０から９９９までで重複はありとします。

作業セルなしが望ましいのですが、結構難しいような気がしますので、

作業セルを使う場合は、B列（B2:B11)を使ってください。

数式はB2及びC3の式を下にコピーしてください。解答発表までは

作業列を使う場合は、B2とC2の式のそれぞれの文字数を宣言してください。

作業列を使わない場合は、C2の式の文字数を宣言してください。

こんなのQ&Aで確立されてるのかな？？
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（minさん出題）

*

*

*

*

*

*

*

解答用参考ファイル：2010_Q59.lzhをダウンロード

**********************************************************************************

尚、解答発表は５／22（土）の午後８時の予定です。（状況によっては

変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************

第58回 魔方陣

【問題】
3×３の魔法陣をVBAを使わずに作ってください。

もちろん式一つでできたら素晴らしいのですが、私はワークセルを

沢山使ってやっと実現できました。

ですから、条件はVBA禁止で後はなんでもありで行きます。

もちろん循環参照OK。また、字数がどうこうというコンテストではなく、

お互いの手法を鑑賞するということでいかがでしょうか。

説明は不要でしょうが、魔法陣とは１から升の数までの数字を９重複なく配置して

縦横斜めの合計がすべて等しくなる表です。

３×３の魔法陣では縦横斜めの合計が15になるように配置します。

3×３の魔法陣は対称形やら回転対称で8個あるのですが、

実質はここに例示した一通りだけですので、一つ作成できればOKです。

なお、4×4の魔法陣では、対称形を省いても880通り、

5×5は何通りあるか存じませんが無茶苦茶沢山あるはずです。

　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん出題）

解答用参考ファイル：2010_Q58.lzhをダウンロード

**********************************************************************************

尚、解答発表は５／１（土）の午後８時の予定です。（状況によっては

変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************

第57回 2人の女王Ⅱ 解答例

では、、、

むりやり、、１４８

{=MID("       QQ       Q Q      Q  Q     Q   Q    Q    Q   Q     Q  Q      Q Q       Q",randbetween(0,6)*10+randbetween(0,8)+ROW()*3+COLUMN()-10,1)}

９セル同時に、配列・・・・・（ちょっと苦しかった)
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー３さん談）

第57回 2人の女王Ⅱ

問　B3:D5の範囲に出現する女王が2人になるような式は？

　　但し、B3の式を他のセルにコピーするものとする。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー３さん出題）

***********************************************************************

尚、解答発表は４／２４（土）の午後８時です。

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************

第５６問 ２枚の王将 解答例

５８は分かりませんでした。

二人の　Ｑ　と同様の解き方で、、

すぐ７０になりましたが、、
７０　　=IF((B3&C3&D3＞"")*(B5&C5&D5＞"")+(B3&B4&B5＞"")*(D3&D4&D5＞""),"平穏","争い")

短縮で、、、５８にはならないなーーー64,62
で、、
64    =IF(((B3&C3&D3=B5&C5&D5)+(B3&B4&B5=D3&D4&D5))*(C4=""),"平穏","争い")
62    =IF(OR(B3&C3&D3=B5&C5&D5,B3&B4&B5=D3&D4&D5)*(C4=""),"平穏","争い")

ならば、、別法を探って、、・・・
これは、みなさんの、、、共通的な手法かも、、、特にsakudaさんは、、なさりそう、、でも、、59が58にならん、、

59     =IF(MIN(COUNTIF(OFFSET(B3:C4,{0,1},{0;1}),""))=2,"争い","平穏")
てわけで、初日あたりから全然進歩がない。
58をきる回答者ジョー3は出番がないかも、、
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー３さん談）

****************************************************************************************

58：=IF(OR(B3&B4=B5,D4&D5=D3)*OR(B3&C3=D3,B5&C5=D5),"争い","平穏")
70：=IF(OR(B3&B4&B5="",D3&D4&D5="")*OR(B3&C3&D3="",B5&C5&D5=""),"争い","平穏")
82：=IF(ISERR(FIND("QQ",B3&B4&C3&0&C3&D3&D4&0&B4&B5&C5&0&C5&D4&D5&0&C4&C4)),"平穏","争い")
86：=IF(ISERR(FIND("QQ",B3&B4&C3&C4&0&C3&C4&D3&D4&0&B4&B5&C4&C5&0&C4&C5&D4&D5)),"平穏","争い")
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　(通りすがりさんの解答）

第５６問 ２枚の王将

【問題】

３×３のマス（B3:D5)にランダムに「王」が２つ表示される。

その２つの「王」が「利き目」にあるときはセルH5に「争い」と

そうでないときは「平穏」と表示させたい。どのような式を

使えばよいか？但し、ここで言う「利き目」にある状態とは

どちらかの「王」を縦、横、または斜め45度方向に一マス移動させると

重なってしまう状態のことである。

　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー３さん、通りすがりさん出題）

***********************************************************************

尚、解答発表は４／１７（土）の午後８時です。

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************

第55回 2人の女王 解答例

１：一番最初のころ　　１０７
=IF(SUM(B3&D4="QQ",C3&D5="QQ",D3&C5="QQ",D4&B5="QQ",D5&B4="QQ",C5&B3="QQ",B5&C3="QQ",B4&D3="QQ"),"平穏","争い")

2番目のもの、、、　７９　　簡単に78になるか?
=IF(FIND("Q1Q",B3&1&D4&1&B5&1&C3&1&D5&1&B4&1&D3&1&C5&1&B3&"1Q1Q")<10,"平穏","争い")

3番目のもの、、、７５

=IF(SUM(B5=C3,C3=D5,D5=B4,B4=D3,D3=C5,C5=B3,B3=D4,D4=B5,C4>"")=6,"平穏","争い")

６３　と、、５７は、、、回答者：ジョー3

第55回 2人の女王

URLが変わってはじめての問題です。

【問題】

３×３のマス（B3:D5)にランダムにQが２つ表示される。

その２つのQが「利き目」にあるときはセルH5に「争い」と

そうでないときは「平穏」と表示させたい。どのような式を

使えばよいか？但し、ここで言う「利き目」にある状態とは

どちらかのQを縦、横、または斜め9045度方向に移動させると

重なってしまう状態のことである。

　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー３さん出題）

＊

＊

*

*

*

*

*

解答用参考ファイル：Q55_2010.lzhをダウンロード

***********************************************************************

尚、解答発表は４／１０（土）の午後８時です。

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************

URLが変わってしまいました。

ＪｕｓｔＳｙｓｔｅｍが３月いっぱいでブログ事業から撤退したので

URLが変わってしまいました。Googleなどの検索サービスを

利用すると全てリンク切れになっているので本当に困ったもんです(T.T)

今までこのサイトを閲覧してくれていた方の中には突然、消えてしまったので

どうしたのだろうと心配してくれているかたもいらっしゃるのではないかと

思います。

　サイト移行後も９月までは無料だそうなんですがその後から

有料になるということで困ったもんだ・・・

第５４回 ３目並べ（Tic tac toe） 解答例

三目並べ出題者解答

最短はどちらかが勝ちになるまでは＃Valueになるエラー無視の130でした。

{=MID("○×",MAX((CHOOSE(ROW(1:8),B3&C3&D3,B4&C4&D4,B5&C5&D5,B3&B4&B5,C3&C4&C5,D3&D4&D5,B3&C4&D5,D3&C4&B5)={"○○○","×××"})*{1,2}),1)}

これは途中にブランクを表示するよう手当てすると133となります。

最初にやったのはなまじ難しく考えすぎて349にもなりましたｗ

{=MID("　○×",SUM((MMULT(IF(B3:D5="○",1,IF(B3:D5="×",0.1,-9)),1^ROW(1:3))={3,0.3})*{1,2},(MMULT(1^COLUMN(A:C),IF(B3:D5="○",1,IF(B3:D5="×",0.1,-9)))={3;0.3})*{1;2},(SUM(IF(COLUMN(B3:D5)=ROW(B3:D5)-1,IF(B3:D5="○",1,IF(B3:D5="×",0.1,-9)),0))={3,0.3})*{1,2},(SUM(IF(COLUMN(B3:D5)+ROW(B3:D5)=7,IF(B3:D5="○",1,IF(B3:D5="×",0.1,-9)),0))={3,0.3})*{1,2})+1,1)}

多少はダイエットできそうですが、やってません。

次にやったのはモロに素朴にやった191

{=IF((B3>0)*(AND(B3=C3:D3)+AND(B3=B4:B5)+AND(B3=C4,B3=D5)),B3,IF(AND(C3=C4:C5,C3>0),C3,IF((D3>0)*(AND(D3=D4:D5)+AND(D3=C4,D3=B5)),D3,IF(AND(B4=C4:D4,B4>0),B4,IF(AND(B5=C5:D5,B5>0),B5,"")))))}

これも作っただけでダイエットはしてません。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん談）

第５４回 ３目並べ（Tic tac toe）

基本的には、スロットマシンなんかと同じです。

ただ、縦横斜めすべてを判定するのでやたら面倒になると思います。

何でもありなんですが、基本的には式一つの回答を希望します＾＾

＊

*

*

*

*

*

【問題】

G5に勝敗を記号で表示してください。

勝負が決まるまでと引き分けの時は

エラーでも空でもOKです。

【三目並べのルール】

３×３の板に交互に○と×を置き、縦・横・斜めの

いずれかに3つならべた方が勝ちです。

解答用参考ファイル：Q54.lzhをダウンロード

***********************************************************************

尚、解答発表は３／２７（土）の午後８時です。

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************

第53回 十枚の領収書（その２） 解答例

作業セルなしで、・・・・・

とは、言ったものの、、

長いよね～ーー　　370文字・・・・・

最初思いついたまーーんま、、、

・・・・・・・

ほんとは、

2日目ぐらいから、、整理して、短縮の予定だったが、、

sakudaさんの文字数を聞いた途端に、、、整理の、意欲がなくなった。

・・・・・

まったくのお恥ずかしい・・・・・・

{=INT(MOD(MATCH($M8,((MOD(ROW($4:$1027),2)=1)*$K$6+(MOD(ROW($4:$1027),4)＞1)*$J$6+(MOD(ROW($4:$1027),8)＞3)*$I$6+(MOD(ROW($4:$1027),16)＞7)*$H$6+(MOD(ROW($4:$1027),32)＞15)*$G$6+(MOD(ROW($4:$1027),64)＞31)*$F$6+(MOD(ROW($4:$1027),128)＞63)*$E$6+(MOD(ROW($4:$1027),256)＞127)*$D$6+(MOD(ROW($4:$1027),512)＞255)*$C$6+(ROW($4:$1027)＞511)*$B$6),0),2^(12-COLUMN()))/2^(11-COLUMN()))}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー３さん談）

第53回 十枚の領収書（その２）

　ジョー３さんから「MAB５３」という問題ファイルが送られてきた。

これは例の「ナップサック問題」で「関数で出来ますか～？」の

第４回「十枚の領収書」で既に取り上げたものだと思うのだが・・・

【問題ファイル】

MAB53.xlsをダウンロード

＊

＊

*

*

*

*

第52問 おいらの関数・・・ 問題＆解答例

supermabさんから「関数で出来ますか～？」用に頂いた問題を

倉庫の奥に封印していました。しかし、興味があるので見せてみろと

いう声が高まってきたのでその封印をときます。

それは・・・オイラーのΦ関数です。

**************************************************************************************

　オイラーのφ関数は、

　正の整数 n に対して、1 から n までの自然数のうち
　n と互いに素なものの個数を φ(n) として与えることによって定まる
　数論的関数 φ である。

　例えば、1, 2, 3, 4, 5, 6 のうち 6 と互いに素なのは 1, 5 の 2 個であるから、
　定義に拠れば φ(6) = 2 である。

　また例えば 1, 2, 3, 4, 5, 6, 7 のうち 7 以外は全て 7 と互いに素だから、φ(7) = 6 と定まる。

　慣例的に φ(n) と表記されるため、オイラーの φ 関数（ファイかんすう、phi function）とも呼ばれる。

　※：上の説明は、「http://ja.wikipedia.org/wiki/オイラーのφ関数」 の引用です。

問題

セルC4に２以上１０００以下の整数を入力し、それをｎとする時、

φ(n)をセルC6に表示させよ。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　（supermabさん談）

*

*

*

*

*

supermabさんの参考ファイル：up0390.zipをダウンロード

第５１問 くまぷー先生の日曜日の補習授業 解答例

出題時の解答例です。

=MID(
SUBSTITUTE(
SUBSTITUTE(
B$5&B$6&B$7&B$8&B$9,F3,""),F4,""),
INT(RAND()*(10-ROW()))*2+1,2)

　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー３さん談）

第５１問 くまぷー先生の日曜日の補習授業

３時間授業です

科目選択は、５教科（対象科目）から３教科ランダムに決めます

１時間目、２時間目、３時間目は別な科目です

１時間目から、２、３時間目が自動的に決ってはいけません

確率は、公平が望ましいです

F9で切り替わるようにお願いいたします

関数のみです

f５セルに入力

ｆ６、ｆ７にその式を貼り付け

作業セルも禁止です

　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー３さん出題）

*

*

*

*

*

*

*

解答用参考ファイル：Q51_2010.lzhをダウンロード

***********************************************************************

尚、解答発表は２／２７（土）の午後８時です。

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************

第50問 はいるかな？ 解答例

「関数で出来ますか～？」もいよいよ最後か？！

とうとう感動？の第５０回をむかえました！！

さて、出題者のsupermabさんのコメントはたった一言・・・

「関数で出来ますか？なのに～。関数使うの忘れた～。」

・・・でした。

・・・で式は・・・

=(D5+D6<=D3)*(D7+D8<=D4)
+(D5+D7<=D3)*(D6+D8<=D4)
+(D5+D8<=D3)*(D6+D7<=D4)
+(D5+D8<=D4)*(D6+D7<=D3)
+(D5<=D4)*(D6+D7+D8<=D3)
>0

・・・の１２２文字でした。

supermabさん、出題並びに解答例の作成、ありがとうございました。

***********************************************************************************

kirさんの解答例です。

ご覧下さい。

2010_Q50_kir_san.zipをダウンロード

第50問 はいるかな？

A3からA8に10から100までの整数がランダムに表示されます。
一番大きい値がF3に、2番目に大きい値がF4に表示されます。

3番目から6番目の値を上手にH3,H4、J3,J4に当てはめて
式１、式２を同時に成立させることができるとき
D10にTRUE、そうでない時にはFALSEと表示させて下さい。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（supermabさん出題）

＊

＊

*

*

*

*

*

解答用参考ファイル：2010_Q50.xlsをダウンロード

***********************************************************************

尚、解答発表は２／１３（土）２／２０（土）の午後８時です。

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************

第４９回 この月のカレンダーは何行になりますか？ 解答例

今回のはなんかないと終わっちゃうということで

でっち上げたもので、御容赦ください。

で、自分でもあまり興味がわかず、

問題の検証で作成した54からほとんど進歩なしでした。

54
=ROUNDUP((MOD(DATE(B5,C5,),7)+DAY(DATE(B5,C5+1,)))/7,)

皆さんの40台を見て焦ったのですが、結局上記から逃れられず、

47で終戦でした＾＾；

=INT((WEEKDAY(B5&-C5)+DAY(DATE(B5,C5+1,))+5)/7)

どうやったら40台前半になるのか楽しみです。
　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん談）

第４９回 この月のカレンダーは何行になりますか？

「関数で出来ますか～？」もいよいよファイナルか？！

出題はsakudaさんです。

【問題】

カレンダーの日付の部分の行数は通常5行ですが、2月では4行の
場合もあり、6行になる月もあります。

指定された月のカレンダーの日付部分の行数を計算してください
カレンダーは日曜日が左端にくる普通のものとします。

例によって、純粋な式だけでやってください。
＊

＊

*

*

*

*

*

*

解答用参考ファイル：Q49_2010.lzhをダウンロード

***********************************************************************

尚、解答発表は１／３０（土）の午後８時です。

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************

第４８回 ブラック・ジャック 解答例

　みなさんのお蔭で「関数できますか～？」も４８回目を迎えました。

５０回まであともう少しです・・・

さて解答です・・・

　まず、F2です。F2にはセルB2,C2に表示される２枚のカードの合計値を

表示します。くまぷーのハウスルールでキング、クイーン、ジャック、エースも

全て１０点なので最大値は２０にしかなりません。よってエースを１点扱いに

する場合を考えなくて済みます。よってセルB2,C2の第１文字が数値なら

そのまま、絵札ならば１０点扱いで合計します。

{=SUM(IF(ISNUMBER(--LEFT(B2:C2)),--LEFT(B2:C2),10))}　（５２文字）

次にG2に３枚目のカードの値を表示します。３枚目がエースだった場合は

１０点扱いにするか１点扱いにするかを判定しなければなりません。

F2が１２点以上なら、エースを１０点扱いにすると３枚の合計が２２を越えてしまうので

１点扱いにしなければなりません。

　また、３枚目がエースでない時、絵札ならば１０点扱い、そうでなければ

そもままの数値として扱います。よって・・・

{=IF(LEFT(D2)="A",IF(F2<12,10,1),IF(ISNUMBER(--LEFT(D2)),LEFT(D2),10))}　（７１文字）

最後にH2に得点を表示させます。３枚のカードの合計値が２２以上なら

０点になるので・・・

=IF(D3,IF(F2+G2>21,0,F2+G2),F2)　（３１文字）

３つのセルの総合計文字数が１５６になってしまいました(^^ゞ

第48回 ブラック・ジャック

ブラック・ジャックは２枚または３枚のカードを使います。

合計が２１以下で一番大きくなるようにします。２２になると０点です。

くまぷーのハウスルール

１．ジャック、クイーン、キングは全て１０点

２．エースは２枚目までは１０点扱い。３枚目の時は１点か１０点の

　　都合の良い方になります。

遊び方

1.「OPEN」「ONE　MORE」のチエックを外すと下のような初期状態になります。

＊

＊

＊

2.「OPEN」のチエックをすると２枚のカードが開きます。

 

＊

＊

＊

3.「ONE　MORE」のチエックをすると3枚目のカードが開きます。

   

＊

＊

＊

問題

得点を計算してF2，G2,H2にそれぞれ2枚の合計値、３枚目の値、

総得点を表示させて下さい。

解答用参考ファイル：Q48_2010.lzhをダウンロード

***********************************************************************

尚、解答発表は１／１６（土）の午後８時です。

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************

第47回 ｎ番目の問題は？ 解答例

問題を作り、できるかどうか検証した時作った76です。

=INDEX(B1:B46,LOOKUP(G3-1,COUNTIF(INDIRECT("C3:C"&ROW(3:46)),E3),ROW(4:47)))

何種類かつくりましたが、一番短くなったのは↓の48でした。

{=OFFSET(B3,1/LARGE((C4:C46=E3)/ROW(1:43),G3),)}

常連の皆さんが、立て続けに47と仰っておられるので、

もっと普通の手段がありそうなのですが、思いつきませんでした。

                                                                            （y sakudaさん談）

第47回 ｎ番目の問題は？

　ときどき、Q/A掲示板で「テーブルから複数の該当項目を

Vlookupで抜き出せないでしょうか？」と言うのが出てきます。

もちろんそんなものはオートフィルタかフィルタオプションでやればよい訳で、

私はそういう回答しか付けたことがありません。

　これはくまぷーさんが12月4日に投稿された、「関数で出来ますか～？・・・雑談」を

見ていて思いつきました。テーブルの並びから言って

もちろんVlookupにはならないのですが、要うはn番目のヒット行を

式で検出するという問題です。

一応、100字以内で可能であることは確認してありますが、

例によってそれ以上の検討はしておりません。

一体どんな手段がでてくるんですかねーー

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん談）

【問題】

E3に入力された出題者のG3番目の出題問題名を

E5に表示してください。

恒例により、作業列、名前等は一切禁止です。

なお、エラー処理をすると長くなるだけのようですから、

G3に0とか出題数以上の数（例えば２題出題の方に５）が

入力された場合は#N/A等のエラー表示の放置で良いことにします。

*

*

*

*

*

*

*

*

解答用参考ファイル：Q47_2010.lzhをダウンロード

***********************************************************************

尚、解答発表は１／１０（日）の午後８時です。

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************

第４６回 矩形の面積 解答例

まとも？な解答を・・・

A1:I9の範囲を参照 107：

{=SUM(INDIRECT(CHAR(MIN(CODE(T2:W2)))&MIN(--RIGHT(T2:W2))&":"&CHAR(MAX(CODE(T2:W2)))&MAX(--RIGHT(T2:W2))))}

非参照82：

=(AVEDEV(LARGE(CODE(T2:W2),{1,4}))*2+1)*(AVEDEV(LARGE(-RIGHT(T2:W2),{1,4}))*2+1)}

69と45はとりあえずみなさんにお任せします。

面白い解答を期待しつつ、携帯から参加します。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（minmaxさん談）

第４４回 夕食の数 解答例

みなさん、あけましておめでとうございます。m(__)m

ジョー３さんが行方不明ですので・・・

この問題は二つの条件を満たす数の和を取る問題です。

掲示板にもよく現れるアレです。

定番の解答であればSumproductを使った

４３：=SUMPRODUCT((C3:C6<=H2)*(D3:D6>H2)*(E3:E6))

定番の配列数式であれば・・・

４１：{=SUM(IF((C3:C6<=H2)*(D3:D6>H2),E3:E6,))}

２００７であればSumifsで・・・

３５：=SUMIFS(E:E,C:C,"<"&H2,D:D,">="&H2)

配列禁止、sumproduct禁止であれば面白くはないけれど・・・

８０：=(H2>=C3)*(H2<D3)*E3+(H2>=C4)*(H2<D4)*E4+(H2>=C5)*(H2<D5)*E5+(H2>=C5)*(H2<D5)*E5

************************************************************************

吉田VS石井が終わってふと見たら

ジョー３さんから出題者解答例が送られてきました。

************************************************************************

いやはや、、、ぜんぜんだめでしたーーー

ちょっと、自分の作表で人数を調べた。でも、、もっといい手ないかなーー

{=SUM((C3:C6<=H2)*(D3:D6>H2)*E3:E6)}

てわけで、出題・・・・これが、最初の式です。

そのご・・・・だめでした。

第４５回 第１木曜は？ 解答例

　新年あけましておめでとうございます。

今年もよろしくお願いします。m(__)m

supermabさんじゃないけれど日付は

苦手です。こんなところでお許しを・・・

５４：{=SUM(IF(WEEKDAY(DATE(A1,A2,ROW(1:7)))=5,ROW(1:7),0))}

ジョー３さんが行方不明なのでこれも代打です。

※上記A2をB1にしてください。

************************************************************************

吉田VS石井が終わってふと見たら

ジョー３さんから出題者解答例が送られてきました。

************************************************************************

最初は、こんな感じだったかなーー　　
ちょっと短くしてね、、
=DAY(INT(DATE(A1,B1,2)/7)*7+5)
でも、、今考えたら、どうしてこうなったか？？わからん
次は、最初からmod使おうと思っていたけど、２４
=MOD(-DATE(A1,B1,3),7)+1

第４６回 矩形の面積

【問題】

ポイント１から４にそれぞれセル番地を入力します。
入力されたセル番地を囲む最小の長方形の面積は？
・（今回は）ポイント1から４に入力するセル番地はA1からI9までとします。
・1つのセルの面積は１とします。

例示の場合は、C3からH7を囲む四角形の面積30が答えとなります。

*

*
*

*

*

*

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（minmaxさん出題）

解答用参考ファイル：Q46_2009.lzhをダウンロード

***********************************************************************

尚、解答発表は１／３（日）の午後８時です。

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************

第４５回 第一木曜は？

この問題はジョー３さんのコメントから頂いたものです。

【問題】

セルA1に年を表す数値、セルB1に月を表す数値を入力する。

その日付の第一木曜日を表す数値をC1に表示させたい。

さて、さて、 ２０１１年の場合、第一木曜は？ 1月から12月まで、

6,3,3,7,5,2,7,4,1,6,3,1ですかね、？？ で、

書式設定も、条件付き書式も、名前定義も、なしで・・・・

関数のみで、最短何文字？・・・・

***********************************************************************

尚、解答発表は１２／３１（木）の深夜１２時です。

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************

第４４回 夕食の数

　復活第一弾は「夕食の数」。ジョー３さん出題です。

この問題は質問掲示板でよく見られる定番の問題です。

エクセルコンテストで言えば「腕自慢」と言うよりも「腕試し」に

あたる問題です。(o^^o)

【問題】

上はある旅館の宿泊予約名簿である。

指定日に何人分の夕食を用意すればよいかを調べたい。

尚、チェックインは午後３時まで、チェックアウトは午前１０時まで、

夕食は午後７時とする。

【条件】

名前、書式、ワークエリアは禁止で、純粋に式一つで計算願います。

*

*

*

*

*

*

解答用参考ファイル：Q44_2009.lzhをダウンロード

***********************************************************************

尚、解答発表は１２／３１（木）の深夜１２時です。

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************

関数で出来ますか～？・・・雑談

現在４３回で休止中の「関数で出来ますか～？」ですが

出題者別に回数を調べてみました。以下の通りです。

出題者	回数
くまぷー	12
sakudaさん	10
からくちさん	7
ジョー３さん	6
む印さん	4
ますたあさん	2
minmaxさん	1
supermabさん	1
合計	43

後半はみなさんに助けて頂き、ラクをさせてもらったのですが

なんとか１２題出題で大家としての面目を保ったようです(^^ゞ

（全４３回の問題は下記URLにて）

http://www.geocities.jp/kuma_pooh1958/index.htm

第43回 何個必要ですか？ 解答例

私は、結局のところ出題前に用意したものから全く進歩しませんでした。
私の最短は51です。

=SUM(N(MMULT(B7:K7,N(COLUMN(B:K)>ROW(1:10)))<B5))+1

Mougで付いていた解答は良く覚えていませんが、SubtotalとSubproduct
を使ったものだったと記憶してます。
私なりにSubtotalを使ったバージョンは配列数式の54でした

{=COUNT(0/(SUBTOTAL(9,OFFSET(B7,,,,ROW(1:10)))<B5))+1}

他にはあまり短くならなかった、Frequencyを使用した56

=FREQUENCY(MMULT(B7:K7,N(COLUMN(B:K)>ROW(1:10))),B5-1)+1

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん）

第43回 何個必要ですか？

Mougか何かで、VBAとして出た質問です。

回答の方もVBAで回答していた方も多いのですが、

最後には関数でもできますと言うことで、

お定まりのSubproductを使った回答もついていました。

簡単そうに見えるのですが、やってみると結構厄介でした＾＾；

【問題】
B7から順次加算して行って、目標値以上にするために必要な
データ個数がいくつであるか計算してください。
上の例で言うと
目標値：1190⇒個数：２
目標値：1200⇒個数：２
目標値：1210⇒個数：３

なお、10個足しても目標値を下回る場合は11と表示してください。

【条件】
名前、書式、ワークエリアは禁止で、純粋に式一つで計算願います。
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん出題）

＊

＊

*

*

*

*

解答用参考ファイル：Q43_2009.lzhをダウンロード

***********************************************************************

尚、解答発表は１１／１４（土）の８：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第42回 文字をバラすと 解答例

私が用意出来たのは、問題作った時にやって見たものを

ちょっと整理した56一つだけです。

{=CHAR(SMALL(CODE(MID($B4,ROW(A:A),1)&"　"),COLUMN()-1))}

スレッドで何人かの方が仰っていた、見かけだけとか本物というのが

結局理解できませんでした＾＾；

さて、いったいどんなのがでてくるんですかね？

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　(y sakudaさん談)

第42回 文字をバラすと

ACUOの裏問です。本当は文字をコード順に並べ替えた文字列と

言いたいところなんですが、配列数式で＆で繋げるのは

無理見たいですから、バラしてソートするだけになりました。

なんか、あまりバリエーションがなさそうなので疑問符付きの問題です＾＾；

（ACUOの提灯のつもりだったのでその辺は無視でした）

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん談）

【問題】
B1に入力された12文字以内の文字列（半角ブランク、半角の英大文字）
を1文字づつにバラしてB8:M8に一文字づつ、コード順に表示してください。
（B8の式をC8～M8にコピー）

【条件】
いつも通り、ワークエリア、名前等は禁止です
＊

*

*

*

*

*

*

解答用参考ファイル：Q42_2009.lzhをダウンロード

***********************************************************************

尚、解答発表は１１／０７（土）の８：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第41回 関数で出来ますか～？ 解答例

「関数で出来ますか？」出題者解答

足し算：
少ない文字数でなら、、、=-(-B3-D3)
これでは関数を使って無いので、、、=ABS(-B3-D3)
しかし、納得出来ない。
これは、関数で値を得ていると言えるのか。。。
こんな使い方、、、どれ程認知されているか。
=TRIMMEAN((B3,D3),)*2
でも文字数で、、、却下。

引き算：
Ｑ＆Ａでは余りと言うか、殆ど使われない関数。
それでも知名度はそれなりにあると思う関数。
=SLOPE(IF({1,0},B3,D3),{2;1})
こんな式、、、結構好きです。

掛け算：
ある意味、１番厄介に感じました。
数値を扱う関数は、結構内部で掛け算を扱っているのが多い。
果してそれを使ってもいいものか・・・で悩みました。
結局、文字数が余りにも違い過ぎるので、、、妥協。

割り算：
以前の問題でSUMの代わりに使用。
故に、足し算では禁止関数に。
でも、掛け算・割り算部門では禁止関数にしていない。
この辺り、、、少々ズルイ。

（＋）：=MEDIAN(B3,D3)*2

（－）：=SLN(B3,D3,1)

（×）：=PV(,B3,-D3)

（÷）：=NPV(D3-1,B3)

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

第41回 関数で出来ますか～？

カテゴリー名「関数で出来ますか～？」に敬意を払い
そのまんまの問題「関数で出来ますか」

足し算・引き算・掛け算・割り算
ただこれだけ
関数の出番は全くありません

でもそれでは問題にならないので、、、
そこで逆に必要の無い関数を態々使い
同じ計算をしていただこう、、、と
これぞ「関数で出来ますか～？」に相応しい問題かと

ただかもすると「本当に関数で出来ますか」の意もチョッピリ、、、あるや無しや

でも十人十色の答えになる可能性も、、、また大
今から答え合わせを見るのが楽しみです

【問題】関数で出来ますか？

Ｂ３とＤ３の数値を足し算・引き算・掛け算・割り算してください
ただし、足し算では（＋）の使用禁止
引き算（－）掛け算（ * ）割り算（ / ）も同様

そして代わりに関数を使用していただきます
ただし足し算でＳＵＭを使われては問題になりません
従いまして使用禁止関数を設定させていただきます

＜足し算・引き算 部門の禁止関数＞
ＳＵＭ・ＮＰＶ・ＡＶＥＲＡＧＥ・ＳＱＲＴ
及びこれを含む関数すべて
（例）ＳＵＭＰＲＯＤＵＣＴ等
＜掛け算・割り算 部門の禁止関数＞
ＰＲＯＤＵＣＴ・ＭＭＵＬＴ
及びこれを含む関数すべて

若しかして、、、チョッと厄介、、、かも・・・
わたしの勝手な判断
易しい＜ 足し算＜割り算＜引き算＜掛け算＜難しい

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん出題）

解答用参考ファイル：Q41_2009.lzhをダウンロード

***********************************************************************

尚、解答発表は１０／３１（土）の８：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

   

第40回 スーパーボールXLIV その２ 解答例

スーパーボールXLIV　その２ 出題者解答

今回は問題自体がつまらなかったのか、意外と難しかったのか
もりあがりませんでしたね。
出題者として反省しておりますm(__)m

今回はどれも発想は同じで、使う関数で多少バリエーションはありますが、最短は115どまりでした。

{=SUM((MID(B4,ROW(1:8),1)={"I","V","X","L","C"})*{1,5,10,50,100},(ISERR(FIND({"IV","IX";"XL","XC"},B4))-1)*{2;20})}

ROMANを使ったものも参考に提示しておきます。29です。

{=MATCH(B4,ROMAN(ROW(A:A)),)}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん談）

第40回 スーパーボールXLIV その２

これは、スーパーボールXLIVの裏問です。やって見たら、

こっちの方が工夫の余地があるみたいで、私には面白かったです。

ただ、ROMAN使えば簡単かつ短くできるのですが、ROMAN禁止ですので、

長くならざるを得ません。私は110は切れていません。

【問題】
B4にIVXLCの5種の文字を使って1～100のローマ数字が入力されます。
これをD4にアラビア数字で表示してください。

【条件】
１．ワークエリア、名前等は禁止、純粋な式一つでやってください。
２．一応ROMANの使用は禁止します。
　　（ROMANを使えば秒殺で出来ちゃうと思います）

【確認】
１．結果確認のボタンを押すと、１～100のチェックを自動的に行います。
２．D4に入っている式を文字列化してE4に表示し、E5に文字数が表示されます。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん出題）

解答用参考ファイル：Q40_2009.lzhをダウンロード

***********************************************************************

尚、解答発表は１０／２４（土）の８：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第３９回 数字をつくる （その３） 解答例

「数字を作る その３」出題者解答

この問題、作業列を使えばエクセルと出合って間もない方でも出来るのでは。
その１つが提示の表です。作業列がそのまま表に。

Ｂ３は１０桁と決まっていますが、最後まで迷ったのが
桁数を決めないで２～２０桁の範囲で、、、
とするつもりでした。
いま想うに、、、その方が良かったかな～
う～ん、でも如何だろう。

でもこれだけはハッキリ言える。
やっぱ出題って、、、難しい。

：{=RIGHT(SUM(MID(A1,ROW(1:10),1)*{1;9;6;4;6;6;4;6;9;1}))}

今回はみなさん仲良く同じ様な式と言うことで
・・・すみません・・・
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん談）

第３９回 数字をつくる （その３）

第１案
作業列あり：エクセルと出会ってまだ１ヶ月頃のわたしでも解けたでしょう。
作業列なし：う～ん、どう考えたらいいのかな。初見時にこの感覚はまず無いな。

出題者がこれでは・・・で、、、

第２案
作業列禁止：これならそれなりに易しさと難しさが同居している、、、かも。
急遽作ったにしては、、、自己満足。（自画自賛）

【問題】
Ｂ３に１０桁の数字を入れます。
それを、、、隣り合わせになった数（１０桁目と９桁目の様に）を加算。
その下１桁を得る。
これを順に繰り返していくと、最後に１桁の数字が残る。
この最後の１桁の数字を求めて下さい。

ただしいつもの様に、作業列等は無しでお願い致します。
結果は、数値・数字、どちらもＯＫと致します。　　　　　（からくちさん談）

*

*

*

*

*

*

解答用参考ファイル：Q39_2009.lzhをダウンロード

***********************************************************************

尚、解答発表は１０／１７（土）の８：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第38回 ACUOになります。 解答例

出題者解答

問題考えた時に思ったのはFrequencyの例題だということで、その時考えたものを整理したのが、
103の↓です。
=AND(FREQUENCY(CODE(MID(B4,ROW(1:12),1)&0),ROW(1:99))=FREQUENCY(CODE(MID(B6,ROW(1:12),1)&0),ROW(1:99)))

出題後、Large,Smallでも同じということで配列数式にはなりますが、97
{=AND(LARGE(CODE(RIGHT(0&B4,ROW(1:12))),ROW(1:12))=LARGE(CODE(RIGHT(0&B6,ROW(1:12))),ROW(1:12)))}

で、これからが、問題で、単純にCodeの和ではダメなことはあきらかなので、自乗和で比較・・・・・
でも、これは、本当に大丈夫、つまり、文字を入れ替えても同じ値になるケースがないということが証明できない・・・
疑惑の68
{=VAR(CODE(MID(B4,ROW(1:12),1)&0))=VAR(CODE(MID(B6,ROW(1:12),1)&0))}
もちろんRow(A:A)にすれば二文字減ります。

そういうことで、ただしいと確信もてるのは73の↓です。
{=SUM(LN(CODE(MID(B4,ROW(1:12),1)&0))-LN(CODE(MID(B6,ROW(1:12),1)&0)))=0}

正しいと考える理由は次の通りです。
１．eを底にした対数は無理数ですから、整数の対数はすべて無理数になる
２．従って、文字を入れ替えて同じ数になることはあり得ない
３．同じ理由で、複数の文字を違う文字数の複数の文字と入れ替えることも不可能
ただし、Excelの実数は打ち切られているので有限小数つまり有理数ですから、厳密に言えば
上記は成り立ちません。でも、32、65～90の範囲ではそんな奇跡みたいなことは起こり得ないと
割り切りました＾＾；

からくちさんはRow(1:12)は使ってないとのこと。一体全体からくちさんの68ってのはどんなんだろ？
楽しみです。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ y sakudaさん談）

第38回 ACUOになります。

ACUOコメント
問題の中にも書きましたが、ACUOブログコンテストの提灯持ち問題として
考えたものです。
10月1日で判定するっての、後になるまでしらなかったｗ

で、お題優先ですから、問題は単純で、B6にランダムに入っている文字を並べ変えて（アナグラム）
B4に入っている文字列がつくれるかどうか判定するというだけです。
両方のセルに入る文字は12文字以内で半角大文字＆半角ブランクのみとします。
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん談)

【問題】
B4に12文字以下の半角大文字、半角ブランクで構成された文字列があります
B6にやはり、半角大文字と半角ブランクで任意の文字列が入っています
この、B6の文字を並べ変えて、正解文字列にできる場合は判定欄E4に
True、正解文字列にできない場合はFalseを入れてください

上の例では
使用文字列:ACEOOTTLUb ならTrue（最後のbは半角ブランクの意味です）
使用文字列:ACEEOTTLUb ならFalse（最後のbは半角ブランクの意味です）
とします。

【条件】
名前、ワークエリア等を使用せず、純粋な式一つでやってください。

解答用参考ファイル：Q38_2009.lzhをダウンロード

***********************************************************************

尚、解答発表は１０／１０（土）の８：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

LOTTE お口の恋人　ACUO

第37回 スーパーボールXL 解答例

名前を上手く使えば結構短くなるのではと思ってたのですが、

170文字位のしかできませんでした。結局一番短いのが、

からくちさんの言葉を借りれば、明白な有罪と

思われるこれだけでした＾＾；

141=TRIM(MID(" X XX XXX XL L LX LXX LXXXXC C",INT(B4/10)*4+1,4))&TRIM(MID(" I II III IV V VI VII VIIIIX",MOD(B4,10)*4+1,4))

単純明快かつ面白くもなんともない・・・・・・

皆さんの回答楽しみにしてます＾＾；

　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん談）

第37回 スーパーボールXL

１～100までのアラビア数字をLXIVCの5文字を使って変換するだけです。

当然のことながら、ROMANは使用禁止にします。

ただ、式一つでやるのは面倒くさいだけみたいなので、

名前、ワークエリアを活用して  スマートな解答を作ってください。

裏問として、ローマ数字を数値変換するというのが考えられますが、

こちらは出し方によっては簡単かつ同一回答になりそうなので、

後日考えます。

解答用参考ファイル：Q37_2009.lzhをダウンロード

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん出題）

***********************************************************************

尚、解答発表は１０／３（土）の８：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

これより下はくまのワルアガキです。m(__)m

お口の恋人LOTTE ACUOのブログコンテストに参加しました。

http://acuoblog.jp/blog_user.php?id=418

現時点で参加ブログ数４９３です。（予約投稿時）

中にはブログの名前をLOTTE　ACUO　・・・なんて名前に

しているものもいて・・・wwwww

いやあ,やる気満々と取るか、なりふり構わずととるか・・・(^^ゞ

第３６問 出た目で称号を獲得 解答例

出た目で称号を獲得 出題者解答

以前のことですが、、、Ｑ＆Ａ掲示板で
「０以上で最小値を求める式は？」と言う質問に
定番と言うか、決まりきった回答が付いていました。
{=MIN(IF(A1:A10>0,A1:A10))}

その時、一般式で出来るのにと
=LARGE(A:A,COUNTIF(A:A,">0"))
と回答を入れました。
この質問に一般式での回答は、過去無かったと思います。

そしたら直ぐ後に
=SMALL(A:A,COUNTIF(A:A,"<=0")+1)
「これでも出来ます」と、こんな回答が付きました。

何と言うか、、、情けないやら、哀しいやら。。。

それ以降この様な回答は思うだけで
無意識に避ける様になってしまったようで。

そんな考え方（式）は忘れようとしても溜まる一方。
その中の１つを使った問題でした。

：=INDEX(F:F,IF(C4=MAX(C:C),4,
  MATCH(VLOOKUP(LARGE(C:C,COUNTIF(C:C,">"&C4)),C:D,2,),F:F,)+1))

　　　　　　　　　　　　（からくちさん談）

お口の恋人LOTTE ACUO・・・

お口の恋人LOTTE ACUOのブログコンテストに参加しました。

http://acuoblog.jp/blog_user.php?id=418

一定期間経過後、Googleブログ検索した結果、

ランキング１位の方には賞金１００万円をプレゼントというエサに

つられてしまいました。(^^ゞ

　本来ならば「関数で出来ますか～？」第３６問の途中でこのような

記事をアップするべきではないのですが、何せ応募期間締め切りが

迫っているのでご容赦を・・・m(__)m

　エクセルには直接は関係ないけれどEXCEL WORLDの

バナーでこのコンテストを見つけたんだから

常連のみなさん、許してd(^-^)ネ!

***********************************************************************

ACUOブログ力コンテスト

http://acuoblog.jp/index.html

第３６問 出た目で称号を獲得

最初に作った問題と比べ、可也難易度を和らげることが出来たと思います。
しかしわたしが出題した前回・前々回の問題と比べますと
まだまだその比では無いと思います。

と言うことでヒントにならないヒントを。
←・・・（それってヒント？）
あることに気が付くとその難度は愕然と低下。
もっともそれに気付き難いからこそ、、、高難度なのか。

この問題の意図は条件にあります。
従いまして条件の変更はこの問題の意味無し。

が、、、それはあくまでエクセル学（そんな単語聞いたこと無い）の追求。
故にそんな固いことは言いません。

如何しても出来ない、、、そんな時は、配列・作業列を使ってください。
少ない文字数で、、、の問題ではありません。
文字数はあくまで結果としてください。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん談）

【問題】
出目（Ｃ列）の数値が大きい順にＦ列の位を称号（Ｄ列）に表示する。

≪条件 その１≫
仮に最大値が２名居た場合、その２名共に１番上の『皇帝』の称号を与える。
その次に大きい数値（３番目）には２番目の位である『国王』の称号を与える。
ＲＡＮＫ関数の順位の付け方と違い順位を飛ばさない。（１位・１位・３位では無く１位・１位・２位とすること）

≪条件 その２≫
※ 答え（式）はＤ４に入れその式をＤ１３まで、、、とする。
※ セル参照（Ｃ４）は構いませんが、範囲指定は列指定（Ｃ：Ｃ）のみとする。（Ｃ４：Ｃ１３は禁止）
※ 配列数式の禁止。（ＩＮＤＥＸ・ＭＭＵＬＴ等でCtrl + Shift + Enterの代わりをするのも当然禁止）
    ただし通常の使用法でのＩＮＤＥＸ・ＭＭＵＬＴ等の関数使用は制限するものではありません。
※ 作業列・名前・書式等の使用も、今までの問題と同様に禁止。

*

*

*

*

*

*

*

*

解答用参考ファイル：Q36_2009.lzhをダウンロード

***********************************************************************

尚、解答発表は９／２５（土）の８：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第３５問 曜日合わせ（その２） 解答例

ある意図があり、それに出来るだけ適う式がないか
それを探しながら回答（解答）しています。
もちろんですが、わたしの勝手な意図です。
仮にそれに可也適う式が出来たところで
それがみなさんに通じるものでも無い事は分かっています。
その事について何の説明もしないのですから、当り前と言えば当たり前ですが。

今回「曜日合わせ」の問題を何気に眺めていたら
「その２」の問題と、その意図に可也適った解答式が同時に浮かびました。
故に本来であるなら、む印さんの案にもかかわらず
この問題を出させていただきました。
む印さん、ありがとうございます。

当然ですがこの問題そのものを解くとするなら
もっといい式があるでしょう。
しかし上記を自分なりに捕らえると
この式は可也適っていると自負しています。
と言うことで、式の良さ・式の短さ等を無視していますが（何時もの事かも）
この式をわたしの解答式とさせていただきます。

：{=LEFT(VLOOKUP(TEXT(B3,"!*mm/daaa"),TEXT(B3+ROW(A:A),"yyy/mm/ddaaa"),1,),10)*1}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん談）