Excel Maniacs

第１０４回 孫の積み木

第一希望：面白い＆独自性の方法、

第2希望：文字数、

第3希望：22パターン公平性ってことで、

あ、、、賞品が残ってる。               
  （5点満点）    （4点満点）   （3点満点）   12点満点の合計点を競う   

賞の推薦は、常連の5名様で、またお願いしたい。               （ジョー３さん出題）

解答用参考ファイQ104をダウンロード

**********************************************************************************

尚、解答締め切りは１０／２９（土）の午後８時の予定です。状況によっては

変更される可能性があります。

また、解答発表までは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

********************************************************************************

 

第１０３回 買い物履歴（野菜の部） 解答例

全角文字をＭＩＤＢで切り分けると半角のスペースになることを利用すると、

式が短くできるという問題を考えたつもりでした、、

70文字{=SUM(1*MIDB(A2:A9&C3&1%%,FINDB("、"&C3,"、"&A2:A9&"、"&C3)+LENB(C3),2))}

 最終的には皆さん行き着くところは同じかと思っていたのですが・・・

>A列、参照してないし・・・楽しみです！^^

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（む印さん談）

 

第１０３回 買い物履歴（野菜の部）

『買い物履歴（野菜の部）』　A2:A9には各行、その都度買い物した複数の各野菜名と

その個数が読点（、）を区切り文字として文字列で入力されています。

※個数を表す数字のみ半角、それ以外はすべて全角文字で

 野菜名は『野菜リスト』にある通り、正しく入力されているものとします。

問題：　『検索野菜』（セルＣ3 ：リストＢＯＸ）で野菜を選択すると、セルＥ3に

『買い物履歴（野菜の部）』（Ａ2：Ａ9セル）にあるその野菜の個数を

合計表示する式はどうすればいいでしょうか？ 　・・・というい問題です。

 　尚、『買い物履歴（野菜の部）』の野菜と個数の入力に関しては、

細かいことを言い出すとキリがないのであくまで、このファイルにある範囲内で

お考えください。m(__)m　　　　　　　　　　　　　　　　（む印さん出題）

 

解答用参考ファイル：Q103をダウンロード

**********************************************************************************

尚、解答締め切りは１０／２２（土）の午後８時の予定です。状況によっては

変更される可能性があります。

また、解答発表までは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

********************************************************************************

 

第102回 アッパよ～ 解答例

解答例

問題発表時点で、68文字というものもありますが、わかりやすいと思いますのでこれを解答例とします。

82{=AND(EXACT(MID("A"&A2,COLUMN(1:1)*2-1,2),PROPER(MID("a"&A1,COLUMN(1:1)*2-1,2))))}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　 （minさん）

第１０２回 アッパよ～

こんなの簡単・・・だと思いますが、
自分には、短くする方法が今のところ見つかりません。。

【問題】
A1にはすべて小文字の英字が入力される。
A2には大文字小文字の別なく英字が入力される。
A2に入力された英字が、
A1の2文字目、４文字目、6文字目、・・・偶数文字目が大文字となっていてほかはそのまま小文字となっている場合にTRUEと表示したい。

例
A1が「abcdeｆｇ」の場合で 、
A2が「aBcDeFg」の場合 　　TRUE
A2が「aBcDeFG」の場合 　 FALSE
A2が「aBcDeF」の場合 FALSE
A2が「abcdefg」の場合 FALSE
A2が「aBcDeFd」の場合 　　FALSE

【条件】
英字はすべて半角で入力されている。
A1の文字列の最長は、100文字位でいいかな、、
ま、あんまり関係ないと思うけど100文字としておきます。

こんな単純な問題無かったですよね？？
（minさん　出題）

**********************************************************************************

尚、解答締め切りは１０／１５（土）の午後８時の予定です。状況によっては

変更される可能性があります。

１０／１２（水）午後８時までは回答案の文字数を書き込むことは

ご遠慮下さい。 

また、解答発表までは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

********************************************************************************

 

第101回 孫の指 解答例

出題者案は、、４４です。

=OFFSET(B25,MIN(MOD(J3-1,8),8-MOD(J3-1,8)),)

短さでも、完敗

アイデアでも、完敗・・・・

・・・・・・・・・・・・・

　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー３さん談）

第１０１回 孫の指

さて孫の手というのは聞いたことがありますが

孫の指とは？！

－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－

お久しぶりです
 
では、
 
リハビリ用の・・・・
簡単問題・・・・・・・・
 
な、、はずです。
 
なにしろ、、、もうすぐ3歳の孫と、,,指数え・・・・・だから、、
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー３さん出題）

 

解答用参考ファイル：Q101をダウンロード

**********************************************************************************

尚、解答締め切りは１０／８（土）の午後８時の予定です。状況によっては

変更される可能性があります。

１０／４（火）午後８時までは回答案の文字数を書き込むことは

ご遠慮下さい。 

また、解答発表までは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

********************************************************************************

 

 

 



誰か見てますか～？

久しぶりにお題を頂戴しました。これで今度は１０１回目の

「関数でできますか～？」になるわけですが

今、ほとんど誰も見てくれていない状態なので

お題公開後、１週間で締め切りにすると

出題者のジョー３さんを除けば

sakudaさんしか、参加者がいないのではないかという不安が・・・

さて、どうしよう・・・

結果発表 第１００回 分数の足し算問題

１００回目の結果（皆さんの評価まとめ）ですが、、、
今回も、評価が分かれて、・・・・・
一致して、賞に推薦と言う状況に、なれませんでした。
 
・・・・・・
思いがけない手法を・・・・引き出す、、、問題、、、ないかなーーー・・・・・
・・・・・・・・・・・・・・・・・・・・・・・
 
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん談）

第１００回 分数の足し算問題 解答例

お世話になります。

 

エクセルさんは、分数をどのように計算してるのかなーー（表示形式）

と、思って、問題にしました。

 

５６＋１５＋４４＋７＝１２２の出題時の出題者案です。

{=MAX(IF(1/ROW(1:100)+1/COLUMN(1:1)=B10,ROW(1:100),""))}

=1/(F5/F6-1/B6)

{=MIN(SUBSTITUTE(B10*ROW(1:10000),".",1)*1)}

=F5/B10

 

一応短くする努力もしてみました。

５１＋１８＋７＋２３＝９９の回答者ジョー3案です

 

{=MAX((1/ROW(1:100)+1/COLUMN(1:1)=B10)*ROW(1:100))}

=INT(1/(B10-1/B6))

=B10*F6

=B6*D6/GCD(B6*D6,B6+D6)

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん）

*******************************************************************************************

52:{=MAX((1/ROW(1:100)+1/COLUMN(A:CV)=B10)*ROW(1:100))}
14:=B6/(B6*B10-1)
25:=(B6+D6)/GCD(B6+D6,B6*D6)
17:=B6*D6*F5/(B6+D6)

･･･で計108文字です　(^^ゞ                  （くまぷー）

***************************************************************************************

＜分数の足し算問題＞

色々な解法（考え方）が出来る問題は今までもあった
しかしこの問題ほど全く別アングルが幾つも存在するのは珍しいかも

ここの処、良い回答にも関わらず受賞者が出ていない
原因はその解法に違いが殆んど無いため差が付けられない

これはある意味致し方ないと思います
より短い式（主旨）を追求すれば
優れた人ばかりなので、皆同じ所に行き着いてしまう

そこで今回、評価(採点）を無視した（正解と言えない）解法を
わたしの回答としました。。。（これで被っていたら最悪）

（ア）=-(SQRT(F5^2-4*F6)-F5)/2

（イ）=F5-B6

（ウ）=LEFT(TEXT(B10,"?  /????"),3)

（エ）=F5/B10

この問題を二次方程式と捉えた解法
その為 F5＾2＜F6*4 では値を出せない（エラー）
故に、、、正解とは言えない

それにしても正解では無いと分かっている式を回答するとは・・・
お遊び式、、、バンザイ！

因みに、正解の式は（同様の式が多数提示されると思われる）
LOOKUPを使った式・MATCHで得る式、、、などなどです             （からくちさん）

*************************************************************************************************

こんにちは　ｎｉです。　第100回の解答をお送りします。

チェックは通らないけれど、正しい答えを出すもの

９８　（ア）{=MAX((1/ROW(1:100)+1/COLUMN(A:CV)=B10)*ROW(1:100))}

（イ）=1/(B10-1/B6)&""

（ウ）=F6*B10

（エ）=B6*D6/GCD(B6+D6,B6*D6)

チェックを通るもの１０１

（ア）{=MAX((1/ROW(1:100)+1/COLUMN(A:CV)=B10)*ROW(1:100))}

（イ）=1/(B10-1/B6)&""

（ウ）=F6*B10&""

（エ）=B6*D6/GCD(B6+D6,B6*D6)

ウが違うだけです。 素直に数値にするもの１００　

（ア）{=MAX((1/ROW(1:100)+1/COLUMN(A:CV)=B10)*ROW(1:100))}

（イ）=INT(1/(B10-1/B6))

（ウ）=F6*B10

（エ）=B6*D6/GCD(B6+D6,B6*D6)

 チェックを通すには、ウをINTで囲むだけです(105文字)INTで誤差を殺すか、

文字列に変換しないとGCDがへんな答えを出してしまいます。     （niさん）

********************************************************************************************

いちぎょうです。
 
一先ず、現時点の送付します。
 
（ア）52　{=MAX((B10=1/ROW(1:100)+1/COLUMN(A:CV))*ROW(1:100))}
（イ）14　=1/(B10-B5/B6)
（ウ）12　=int(B10*F6)
（エ）30　=RIGHT(TEXT(B10,"?/0000"),4)*1
 
（ア）+（イ）+（ウ）+（エ）=108
 
 
おまけ：
 
残念な数式、、、
 
（ア）39　{=MATCH(,MOD(1/(B10-1/ROW(1:100)),1),)}
 
下14～16桁ぐらいの誤差が、、、
 
（ア）44　{=MATCH(,(MOD(1/(B10-1/ROW(1:100))+99,1)),)}
 
大き目の数字を足したら誤差を無視してくれたが、
そもそもマイナスの数字や１００以上の数の組み合わせ
までもが。。。                                        （いちぎょうさん）

*********************************************************************************************

私は104までしか行きませんでした。
ア 51 {=MAX((1/ROW(1:100)+1/COLUMN(1:1)=B10)*ROW(1:100))}
イ 18 =INT(1/(B10-1/B6))
ウ 12 =F6/B6+F6/D6
エ 23 =B6*D6/GCD(B6*D6,B6+D6)
合計　104

で、こっちはアイデアが付きちゃいましたので、配列数式じゃないのを

少しやってみましたので参考出品します。二種類（どちらもアの数式で他は変わりません

92で合計145　

=LOOKUP(,0/(ABS(1/(B10-1/ROW(1:100))-50.5)<50)/(MOD(1/(B10-1/ROW(1:100)),1)<1%%),ROW(1:100))

103で合計156　

=INT(LOOKUP(,0/(1/INT((ROW(1:10000)-1)/100+1)+1/(MOD(ROW(1:10000)-1,100)+1)=B10),ROW(1:10000)-1)/100)+1

なお、全部フルチェックでOKになったものです。                      （y　sakudaさん）

**************************************************************************************************

Excelの小数問題（詳細な時間や分数 等）ははっきり言ってよく解ってないので

いつも避けているのですが、第100回問題ということなので、一応提出しました。

参加したというだけの答案でスミマセンm(__)m 何故かチェックを通過できたもの（？？？）　

（ア）　｛=MAX((FIND("1/",TEXT(B10-1/ROW(1:100),"?/?????")&"1/")=1)*ROW(1:100))｝　

（イ）　　=1/(B10-1/B6)

（ウ）　　=LEFT(TEXT((B6+D6)/(B6*D6),"# /######"),3)*1　

（エ）　　=RIGHT(TEXT((B6+D6)/(B6*D6),"#/ ######"),5)*1

チェックを通過できなかったもの　※式を立てた順　

（ア）　｛=MATCH("1/*",TEXT(B10-1/ROW(1:100),"?/?????"),)｝　

（イ）　　=1/(B10-1/B6)　

（エ）　　=B6*D6/GCD(B6,D6)　

（ウ）　　=B10*F6　

－－－－－－－－－－－－－－－－－－－－－－－－－－－－－　

（ウ）　　=B10/TEXT(B10,"0 1/??????")　

（エ）　　=F5/B10　

（ア）　｛=MAX((F6*COLUMN(1:1)/ROW(1:100)=F5*COLUMN(1:1)-ROW(1:100))*ROW(1:100))｝　

（イ）　　=1/(B10-1/B6)             （ む印さん）

********************************************************************************************

とりあえずやったということで、、
あ…53{=101-MATCH(1=1,LEN(1%/(B10-1/(101-ROW(1:100))))<5,)}
い…13=1/(B10-1/B6)
う…7=F6*B10
え…33=B6*D6/GCD(B6+YEN(D6),B6*YEN(D6))
計１０６文字
これではチェックを通りません
 
しょうがなく
あ…53{=101-MATCH(1=1,LEN(1%/(B10-1/(101-ROW(1:100))))<5,)}
い…13=1/(B10-1/B6)
う…14=--YEN(F6*B10)
え…40=--YEN(B6*D6/GCD(B6+YEN(D6),B6*YEN(D6)))
計１２０文字
変な式ですみません。。
 
100回記念ということで何も出さないわけにいきませんので、、
 
チェックを通過したものをちょっと短くしたので
大したものではないですが間に合ったら追加願います。
あ…53{=101-MATCH(1=1,LEN(1%/(B10-1/(101-ROW(1:100))))<5,)}
い…18=INT(1/(B10-1/B6))
う…12=INT(F6*B10)
え…23=B6*D6/GCD(B6+D6,B6*D6)
計106文字                                          （minさん）

***********************************************************

全然うまく行きませんが、とりあえず送ります。
チェックはしていません。

(ア)３パターン
４１{=MATCH(,MOD(1/(B10-1/ROW(A1:A100)),1),)}
５９{=MATCH(B10,1/INT(1/(B10-1/ROW(A1:A100)))+1/ROW(A1:A100),)}
８８{=MATCH(B10,(1/INT(1/(B10-1/ROW(A1:A100)))+1/ROW(A1:A100))*

(B10-1/ROW(A1:A100)>1/101),)}

(イ)１８=INT(1/(B10-1/B6))
(ウ)１７=(B6+D6)*F6/B6/D6
(エ)２３=B6*D6/GCD(B6+D6,B6*D6)                      （りすさん）
 
 

 

 

 

第１００回 分数の足し算問題

 
 
問１　（ア）（イ）に入れる数式は？

問２　（ウ）（エ）に入れる数式は？　（但し、既約分数になるようにする）

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（出題　ジョー3さん）

解答用参考ファイル：Q100_2011をダウンロード

）**********************************************************************************

尚、解答締め切りは０６／１１（土）の午後８時の予定です。（状況によっては

変更される可能性があります）締め切りまでに私までメールで解答をお知らせ下さい。

解答発表までは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

********************************************************************************

優秀者発表 第９９回 鏡 （数字を作る その９）

皆さんのご意見では、
３０台の四名様・・・・
 
同様にすばらしいので、・・・・・
残念ながら、賞はまたもや見送り、、
 
１００問目は、、、きっと、差が出るに違いない・・・・
 
手法も、文字数も、、、４問の総合評価だから（実質２問だけどね）
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん）

第９９回 鏡 （数字を作る その９） 解答例

【鏡 問題 出題者解答例】

言い訳。。。

問題を解く時、、、始めは脳内何時も無・・・
これがわたしの理想

しかし己が作った問題ではこれが非常に難しい
余りにも問題の核心を知り過ぎているが故
逆にそのトラップから抜け出せなくなっている
始めは無、、、どころか始めから嵌っている

４０台・３０台の文字数を見た時、、、１００％観客モード
故に問題作成時のまま何も変化無し

このまま出題者解答例は無し、、、としたい所ですが
皆さんの回答が楽しみなので、、、

：=MAX(MAX(2:1000)-ROW()+1,A2-1,(A2=0)*EVEN(ROW())/2)

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

*********************************************************************************************

やっぱりまともなのはこの38だと思います。
=INT(ABS(COUNT(A2:A$1000,)-ROW())/2)+1

A2:A$1000　を　2:1000　としてしまえば35（多分みなさんも同じ）になりますが、
シートに数字のゴミがあると気が狂いますので、ちょっと・・・・ですね。
今回は最初できた時ABSと/2の位置がおかしいのに気付かず（）が一組余計になっていました。
minmaxさんがおかしいなとおっしゃらなかったら40⇒37で終わってました＾＾；

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（sakudaさん）

***************************************************************************************************

問題を考え出題される皆さんは「スゴイなぁ～」と常々思っておりますが

シンプルだけど難しい「数字を作る・シリーズ」にはいつも悩まされっぱなしです、、、

今回も最初、どうすればいいのかサッパリでしたがりすさんのおかげで

なんとか解答できた次第ですm(__)m

Ａ列のみ使用の1000行までなら

３４=INT(ABS(ROW()-COUNT(2:999,))/2+1)

 ６０{=TEXT(MAX(SUM(N(A2:A999>0),B$1:B1-1,1)*{1,-1})/2+0.5,0)*1} 

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　 （む印さん）

***************************************************************************************

こんにちは　ｎｉです。 ９９回解答をお送りします。

３５　=INT(ABS(ROW()-COUNT(2:999)-1)/2)+1

COUNT(1:999)が使えれば　-1　が不要になって2文字減るんだけど、

循環参照になってしまう。  最初につくった

３７　=INT(ABS(ROW(A2)-COUNT(2:999)-2)/2)+1

別案　あまり変わり栄えしないけど

３６　=EVEN(ABS(ROW()-COUNT(2:999)-1)+1)/2

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（niさん）

*****************************************************************************************

今回の問題も難しかったですね。 当初次の式の1種類しか解答ができませんでした。

 37=INT(AVEDEV(COUNT(A2:A999,),ROW()))+1

無理すれば２文字減りますが。はたしてこれが皆さんと一緒なんだろうか？

次にやったもの

46=ROUND(ROWS(A1:INDEX(A:A,COUNT(A2:A999,)))/2,)

これは無理すれば３文字減りますが。 一般的には、ABSとか使わないとダメかなと考えると

思うんですが、そこを何とかするのがつぼかなあ？？？

 もうちょっとやったので追加です。

これが一番単純かな。

38=INT(ABS((COUNT(A2:A999,)-ROW())/2)+1)

ちょっと変形

44=TEXT((COUNT(A2:A999,)-ROW())/2.001,"0;0")+1  min

追加

52=IF(A2,A2+SIGN(COUNT(A2:A999)-ROW()),INT(ROW(A2)/2))
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（minさん）

***************************************************************************************

 皆さんの数字にかなわないので、、、
じたばたしないで、、、
・・・・・・・・・・・・
最初の素材のまんま・・・・
 
５０：
=INT(ABS(COUNTA(A2:A1000)/2-ROWS(A$1:A1)/2+0.5))+1
５０：
=ROUND(ROWS(A1:OFFSET(A$1,COUNT(A2:A1000),0))/2,0)

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん） 

*********************************************************************************************

いちぎょうです。 すみません、タイムオーバーですが、、、

どちみち、３０台に行けてませんが＾＾； 

 63　{=MAX(INT(((8^5-COUNTBLANK(A2:A$1000)/2+0.5-ROW())*{1,-1}+1)))}

50　=MAX(INT((COUNT(A2:A$1000)-ROW()+1)*{0.5,-0.5}))+1

46　=ROUND(ABS((COUNT(A2:A$1000)-ROW()+1)/2)+0.5,)

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（いちぎょうさん）

*************************************************************************************************

第９９回 鏡 （数字を作る その９）

A1に式を入れてください
そのA1を下へズリズリ
その結果が鏡のように、上下対象に表示されるようにしてください
たったこれだけ、、、至って単純な問題ですみません

1 1 2 2 3 3 4 4
   1 1 1 2 2 3 3
      2 1 1 1 2 2
         2 2 1 1 1
            3 2 2 1
               3 3 2
                  4 3
                     4

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん出題）**********************************************************************************

尚、解答締め切りは０６／０４（土）の午後８時の予定です。（状況によっては

変更される可能性があります）締め切りまでに私までメールで解答をお知らせ下さい。

解答発表までは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

********************************************************************************

優秀者発表 第９８回 給与計算 解答例

うわーーーー
色んなところに、、出したら、、、
多くは、、、驚愕の式・・・・・と、、思う。
しかしーーーーー
他人に対して以上に、、自分に厳しい
皆さんは、、、・・・・・・・・驚愕が、、なかったようだ。
・・・・・・・・・・・・・・・・・・・・・
自分と、同類＆同等の？式が多かった?
て、ことで、
受賞者無し！！（きびしいーーー）
もう少しで、銅賞＝からくちさん、、、
３，４人の方、、、、ぴたりと、追走、、、、、
今回も、ジョー３は・・・・しんがりを勤めたのだったけど、、、、
（これは残念ながら、、評価がかなり、、、一致＝あはは）
　

　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん談）

第９８回 給与計算 解答例

今回も出題者完敗ですねーー

出題した時可能であることを確認するために作ったのは84でした。

{=SUM(FREQUENCY((ROW(8:17)>=D8*24)*(ROW(8:17)<E8*24)*-ROW(8:17),A5:A10*-24)*B5:B11)}

実際に今週やったのは基本的にはLookupに変更しただけみたいなもので、

69までしかダイエットできませんでした。

{=SUM((ROW(8:17)>=D8*24)*(ROW(8:17)<E8*24)*LOOKUP(ROW(8:17)/24,A:B))}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん）

*************************************************************************************************

本当は決して良い事では無いでしょうが、、、でも致し方ない

好き、と言う訳では無いけど多用してしまう関数が出来てしまう

反対に無意識か否か、殆んど使用しない使いたくない関数もまたある

今回の問題、、、

正にその両巨頭が偶然にも握手をしてしまった

そのありえない場面を見てしまった、、、複雑な心境

{=SUM(LOOKUP(ROW(INDIRECT(D8*24&":"&E8*24-1))/24,A:B))}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

******************************************************************************************

回答忘れないうちに現時点の分を職場から送付します。

 65　{=SUM(LOOKUP(ROW(INDIRECT(D8*24&":"&E8*24-1)),A5:A11*24,B5:B11))}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（いちぎょうさん）

******************************************************************************************

何にも送らないのもちょっとさびしいので一応やったということで送ります。

 最初にやった式87

=SUMPRODUCT(FREQUENCY((D8<ROW(1:24)/24)*(E8>=ROW(1:24)/24)*ROW(1:24)/24,A5:A10),B4:B10)

ちょっと整理77

=SUMPRODUCT(FREQUENCY((E8>=D8+ROW(1:24)/24)*(D8+ROW(1:24)*4%),A5:A10),B4:B10)

単純に考えて94

{=ROUND(SUM(IF(A5:A10>=D8:E8,,IF(A6:A11>D8:E8,D8:E8-A5:A10,A6:A11-A5:A10))*B5:B10*{-24,24}),)}

これもちょっと整理83

{=SUM(YEN((A5:A10<D8:E8)*(IF(A6:A11>D8:E8,D8:E8,A6:A11)-A5:A10)*B5:B10*24)*{-1,1})}

みなさんの解答楽しみです。　　　　　　　　　　　　　　　　　　　　　　　　　　（ minさん）

*********************************************************************************************

くまぷーさんこんにちは ｎｉです。

 1文字短くなったので、修正 第98回解答をお送りします。

 ５８　{=SUM(LOOKUP(ROW(OFFSET(A1,D8*24-1,,(E8-D8)*24))/24,A:B))}

VLOOKUPだとうまくいかなかったので、LOOKUPにしてみました。

結果、VLOOKUPより短くなりました。 以下、短縮の道乗りようやくできた

７３{=SUM(LOOKUP(ROW(8:17)/24,A:A,B:B)*(ROW(8:17)/24>=D8)*(ROW(8:17)/24<E8))}

 次の６９　{=SUM(LOOKUP(ROW(8:17)/24,A:B)*(ROW(8:17)/24>=D8)*(ROW(8:17)/24<E8))}

６２になって{=SUM(LOOKUP((ROW(1:9)-1)/24+D8,A:B)*((ROW(1:9)-1)/24+D8<E8))}

それからこれ５９　を送ろうとして、F9を何回か押してみると、失敗することがある。

{=SUM(LOOKUP((ROW(1:9)-1)/24+D8,A:B)*(ROW(1:9)/24<=E8-D8))}

最初に送った５９{=SUM(LOOKUP((ROW(1:9)-1)/24+D8,A:B)*(ROW(1:9)/24+D8<=E8))}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（niさん）

****************************************************************************************************

はじめVLOOKUPとＳＵＭでできるかと思ったのですが上手くいかず、、

LOOKUPに切り替えてたらできました。

６４文字{=SUM(LOOKUP(D8+(ROW(OFFSET(A1,,,HOUR(E8-D8)))-1&":"),A:A,B:B))}

あとは検索する時間帯を配列にする式の短縮作業で

59{=SUM(LOOKUP(ROW(INDIRECT(D8*24&":"&E8*24-1))/24,A:A,B:B))}

からくちさんの５８や５５はどうやってるのか楽しみです。

 因みに検索する時間帯いろいろやってみたのですが・・・ｗｗ

ROW(INDEX(A:A,D8*24):INDEX(A:A,E8*24-1))/24ROW(OFFSET(A1,D8*24-1,,(E8-D8)*24))/24ROW(OFFSET(INDEX(A:A,D8*24),,,(E8-D8)*24))/24

最後に一番長かった式です

{=SUM(CHOOSE(MATCH(ROW(INDIRECT(D8*24&":"&E8*24-1))/24,A5:A10),B5,B6,B7,B8,B9,B10))}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ む印さん）

****************************************************************************************

ぜんぜん、ひらめかなかった。・・・・・
ぜんぜん、、進歩がなかった。
７８のまま、、、

{=SUM(LOOKUP((D8*24+ROW(1:9)-1),A5:A11*24,B5:B11)*((ROW(1:9)-1)<E8*24-D8*24))}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん） 

 

 

第９８回 給与計算

これは先日EWのからくちさんの日記で言及されたMougの質問に回答し、
そのついでにもう一つ回答した質問のパクリです。
http://moug.net/faq/viewtopic.php?t=57689

質問ではテーブルが等間隔ではなかったので、テーブルを等間隔に
してやればなんとかなりますよーーで済ませました。
その時、多分不等間隔でも何とかなると思いましたが、もちろんそんな
ものを回答にしても混乱するので、パクって問題にしちゃいました。www

 

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん出題）

 解答用参考ファイル：Q98_2011をダウンロード

**********************************************************************************

尚、解答締め切りは０５／２８（土）の午後８時の予定です。（状況によっては

変更される可能性があります）締め切りまでに私までメールで解答をお知らせ下さい。

解答発表までは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

********************************************************************************

優秀者発表 第９７回 幾つコピーしたか

☆賞品について

金賞
銀賞
銅賞
それらに、皆さんから,評価して頂けるなら、、うれしいです。
 
＆
副賞の品物があるならまた、嬉しいです。
 
 
て、ことで、
提案です。
長く続けるため、、
 
銅賞、銀賞、金賞の品物は、各賞一度だけとしたい。
 
つまり、
一度目の銅賞には、、副賞があるが、、、
2度目、3度目の銅賞には、副賞がない。
・・・・・・・
銀賞、金賞も、以下おなじ、、、
 
つまり、、副賞は、いくら多くても、３回までとなる。
 
予算からは、あと、１１～12回チャンスがあります。

*************************************************************************************

さて、今回の結果ですが・・・

みなさんの、採点から、、＆、、調整（自分の評価がないので）
 
銅賞のみ　　　　　からくちさん、minmaxさん、ジョー3の3名となりました。

（で、、、副賞なしとさせていただきました）

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん）

第９７回 幾つコピーしたか 解答例

偶に見かける質問
・この関数はどう言う時に使うのですか？
・この関数の使い道は？
それに対して回答者はヘルプの写しのような返答

何故、決めつけたがるのか
何故、限定したがるのか

そこから生まれるものは殆んど無い
何をどう使おうが勝手、、、が自分流

＜出題者解答例＞

A1：=COUNTA(OFFSET(A1,1,,65535))

65536では無く1つ少なく65535とするところがポイント

COUNTAを１文字減らしてCOUNTにすると、コピー先は１では無く０になる
０の集計では当然の様にCOUNTが第一候補になってしまう可能性大
しかしこれが１なら真っ先に頭に浮かぶのはSUMかも
勿論ですがそれに追い打ちをかけるようにSUMは使用禁止に
これなら頭の中はSUMになり混乱を来す素に

１文字増やしてもこの方が解き難くなるのでは
問題作りにそこまで考えるとは実にズルイ策略

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

**********************************************************************************************

今回の問題は、難しかった。

Ｃを使わない手法は思いつきませんでした。 一応A1の式を別のセルにコピーした後に

その式をA1に再度コピーしても大丈夫なものを送ります。

25=COUNTA((A2 A$2):A$65536)

40=ABS(COUNT(A2:A$65536,)*ISREF(A2 A$2)-1)

27=COUNTA(OFFSET(A2,,,4^8-1))27=COUNTA(OFFSET(A2,,,65535))

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（minさん）

*************************************************************************************************

53 =(TYPE(OFFSET(A1,65535,0))=1)*(COUNT(A2:A$65536)-1)+1

40 =(COUNT(A2:A65536)-1)*(TYPE(A65536)=1)+1

コピーしたときに、エラーになるようにして、さらにエラー判定で１を表示させる・・・

 =COUNT(A2:A65536)だと、コピーした値が１にならない・・・

そこの工夫がわかりませんでした。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（niさん）

**************************************************************************************************

１９文字
=COUNTA(A$2:A65536)
 
１８文字（＄なし）は、不具合が、あるので、、
 
＞A1に式を入れてください
＞この時点では０と表示させてください（理由はまだコピーが０なので）
＞このA1の数式をコピーして、Ａ列にその数式を貼り付けてください
＞その貼り付けた数をA1に表示させてください

＞例えば、、、
＞A2・A5・A6・A7・A15の５つに貼り付けた場合、A1は5と表示させてください
＞また、、、
＞A2・A5・A6・A7・A15の5つのセルにはどれも1と表示させてください

 

＞A2・A5・A6・A7・A15　　に1セルずつだと良いが・・・

A5・A6を2セル同時貼り付けだと、循環になるため、、

それで、

１８でなく　　「　=COUNTA(A2:A65536)　」
１９で応募　「　=COUNTA(A$2:A65536)　」です。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん） 

****************************************************************************************************

制限なし32です。制限なくてもこれが精一杯でした^^
=COUNT(A2:A65536,)-ISREF(A$1 A1)

Count,65536なし版はとにかくできただけで良しと言うレベルで56です。
=(FREQUENCY(A2:OFFSET(A$1,2^16-1,),1)-1)*ISREF(A$1 A1)+1

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん） 

***********************************************************************************************************

 

第９７回 幾つコピーしたか

＜問題：幾つコピーしたか＞

A1に式を入れてください
この時点では０と表示させてください（理由はまだコピーが０なので）
このA1の数式をコピーして、Ａ列にその数式を貼り付けてください
その貼り付けた数をA1に表示させてください

例えば、、、
A2・A5・A6・A7・A15の５つに貼り付けた場合、A1は5と表示させてください
また、、、
A2・A5・A6・A7・A15の5つのセルにはどれも1と表示させてください

ただし、これだけでは簡単過ぎてしまうと思いますので
条件を付けさせていただきます

＜条件１＞
A列以外の使用禁止
B列～IV列の参照等をすること
A列のみ使用で

＜条件２＞
使用禁止関数を設けます
：IF 関数
：ROW 関数
：ROWS 関数
：COLUMN 関数
：COLUMNS 関数
：SUM 関数
：SUMPRODUCT 関数
：CELL 関数

勿論ですが、何時もと同様に反復計算等は禁止とさせていただきます

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん出題）

**********************************************************************************

尚、解答締め切りは０５／２１（土）の午後８時の予定です。（状況によっては

変更される可能性があります）締め切りまでに私までメールで解答をお知らせ下さい。

解答発表までは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************************************

優秀者発表 第９６回 文字つなげ問題

審査担当の皆様の評価、ありがとうございました。
 
その評価点を、元に採点しました。
 
さらに、みなさんの、驚愕の度合いで、、調整しました。
 
 
結果、
minmaxさんが、また銅賞になりました。（もう少しで銀賞）
りすさんは、、惜しかった、、、もう少しで銅賞でした。
 
それで、
 
minmaxさんには、以前の成績もありますので、、、
桃川大吟醸を加えて、お送りいたしました。
 
-----------------------
今後の賞品計画。
 
賞品はやはりあったほうが良い。
豪華でなくても、長続きが良い。
（今回レベル？）
 
を、計画しております。
 
詳細は、２，３日中にくまぷーさんにご提案、ご相談いたします。

ジョー3さん、ありがとうございます！！

　先程、ジョー3さんよりステキな賞品を頂きました。

お酒を頂けるとのことだったのですが

な、なんと４本も！！

本当にありがとうございます。

この場を借りて御礼申し上げます。m(__)m

 

 

第９６回 文字つなげ問題 解答例

653文字
これを、、うまくまとめられない、、、はずかしさ、、
 
=LEFT("○",OR(
(MID(H2,2,1)=B$2)*COUNTIF(A$1:C$3,RIGHT(H2))*COUNTIF(A$1:C$3,LEFT(H2)),
(MID(H2,2,1)=C$2)*COUNTIF(B$1:D$3,RIGHT(H2))*COUNTIF(B$1:D$3,LEFT(H2)),
(MID(H2,2,1)=D$2)*COUNTIF(C$1:E$3,RIGHT(H2))*COUNTIF(C$1:E$3,LEFT(H2)),
(MID(H2,2,1)=B$3)*COUNTIF(A$2:C$4,RIGHT(H2))*COUNTIF(A$2:C$4,LEFT(H2)),
(MID(H2,2,1)=C$3)*COUNTIF(B$2:D$4,RIGHT(H2))*COUNTIF(B$2:D$4,LEFT(H2)),
(MID(H2,2,1)=D$3)*COUNTIF(C$2:E$4,RIGHT(H2))*COUNTIF(C$2:E$4,LEFT(H2)),
(MID(H2,2,1)=B$4)*COUNTIF(A$3:C$5,RIGHT(H2))*COUNTIF(A$3:C$5,LEFT(H2)),
(MID(H2,2,1)=C$4)*COUNTIF(B$3:D$5,RIGHT(H2))*COUNTIF(B$3:D$5,LEFT(H2)),
(MID(H2,2,1)=D$4)*COUNTIF(C$3:E$5,RIGHT(H2))*COUNTIF(C$3:E$5,LEFT(H2))))

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん）
******************************************************************************************************

今回の問題は配列のお勉強問題と思いました。
結構面白い問題でした。

最初にやった２３３文字
223{=LEFT("○",COUNT((FIND(MID(H2,1,1),A$1:C$3&A$2:C$4&A$3:C$5&B$1:D$3&B$2:D$4&B$3:D$5&C$1:E$3&C$2:E$4&C$3:E$5)+FIND(MID(H2,3,1),A$1:C$3&A$2:C$4&A$3:C$5&B$1:D$3&B$2:D$4&B$3:D$5&C$1:E$3&C$2:E$4&C$3:E$5))/(MID(H2,2,1)=B$2:D$4)))}

まとめたもの。
141{=LEFT("○",COUNT(SEARCH(REPLACE(H2,2,1,"*"),REPT(A$1:C$3&A$2:C$4&A$3:C$5&B$1:D$3&B$3:D$5&C$1:E$3&C$2:E$4&C$3:E$5,2))/(MID(H2,2,1)=B$2:D$4)))}

配列のお勉強応用編
126{=LEFT("○",COUNT(SEARCH(REPLACE(H2,2,1,"*"),REPT($1:3&$2:4&$3:5&B$1:D3&B$3:D5&C$1:E3&C$2:E4&C$3:E5,2))/(MID(H2,2,1)=B$2:D4)))}

番外編２００７以上互換性モードで（PCによってはリソース不足になるから実験しないほうがいいと思う）
119{=LEFT("○",COUNT(SEARCH(REPLACE(H2,2,1,"*"),REPT(A:C&$2:4&$3:5&B:D&B$3:D5&C:E&C$2:E4&C$3:E5,2))/(MID(H2,2,1)=B$2:D4)))}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（minさん）

****************************************************************************************************

くまぷーさん、こんにちは ９６回の回答をお送りします。

 最初につくった改行込みの526文字

{=LEFT("○",(MID(H2,2,1)=C$3)+(MID(H2,2,1)=B$2)*OR(B$2:C$3=LEFT(H2))*OR(B$2:C$3=RIGHT(H2))+(MID(H2,2,1)=B$3)*OR(B$2:C$4=LEFT(H2))*OR(B$2:C$4=RIGHT(H2))+(MID(H2,2,1)=B$4)*OR(B$3:C$4=LEFT(H2))*OR(B$3:C$4=RIGHT(H2))+(MID(H2,2,1)=C$2)*OR(B$2:D$3=LEFT(H2))*OR(B$2:D$3=RIGHT(H2))+(MID(H2,2,1)=C$4)*OR(B$3:D$4=LEFT(H2))*OR(B$3:D$4=RIGHT(H2))+(MID(H2,2,1)=D$2)*OR(C$2:D$3=LEFT(H2))*OR(C$2:D$3=RIGHT(H2))+(MID(H2,2,1)=D$3)*OR(C$2:D$4=LEFT(H2))*OR(C$2:D$4=RIGHT(H2))+(MID(H2,2,1)=D$4)*OR(C$3:D$4=LEFT(H2))*OR(C$3:D$4=RIGHT(H2)))}

 個々の判定に配列を使用しているので、さらに配列でまとめようとすると、配列の配列が必要？ 

 精一杯の１７４文字{=LEFT("○",OR((LEN(SUBSTITUTE(SUBSTITUTE(LEFT(A$1:C$3&B$1:D$3&C$1:E$3&A$2:C$4&C$2:E$4&A$3:C$5&B$3:D$5&C$3:E$5&10000,8),LEFT(H2),,1),RIGHT(H2),,1))=6)*(B$2:D$4=MID(H2,2,1))))}

真ん中文字を判定、前後の文字を文字列から削除して文字数をチェック。

これはもう削れない？

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（niさん）

***************************************************************************************************

146です
{=LEFT("○",MAX((B2:D4=MID(H2,2,1))*LEN(SUBSTITUTE(SUBSTITUTE(A1:C3&B1:D3&C1:E3&A2:C4&C2:E4&A3:C5&B3:D5&C3:E5,LEFT(H2),5^9),RIGHT(H2),5^9,1))/15))}

ただし、前提として、最初の文字が重複しないということがあります。
もし、いちご、ゆりね、りんご　のように最初の文字（り　が2回）ということになると、最初のSubstituteに　,1　を加える必要があり、2文字増えます。

考え方としては、二番目の文字の位置決めをし、その周囲に先頭と末尾の文字が両方そろっているというのを〇の条件にしています。
なお、この方法だと、ココアには対応できますが、トマト（最初と最後が同じ）には対応できません。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（sakudaさん） 

*****************************************************************************************************

りすです。とりあえず、解答を送ります。
 
もっと短縮できそうだけど、技術がなく、動くものが作れませんでした。
 
１６９{=LEFT("○",SUM((COUNTIF(OFFSET(B$2,{0,1,2},{0;1;2}),MID(H2,2,1)))*COUNTIF(OFFSET(A$1,{0,1,2},{0;1;2},3,3),LEFT(H2))*COUNTIF(OFFSET(A$1,{0,1,2},{0;1;2},3,3),RIGHT(H2))))}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（りすさん）

******************************************************************************************************

今回の問題は、、、ジョー３さん、並びに皆さんに完敗です

最短式の前後１０％以内なら、それなりに競ってはいる
最短式の前後２０％以内なら、他を圧倒した式なら競ったかな
最短式の２０％越えでは、、、論外

今回は残念ながら、、、論外
ここの主旨は最短式であって、数勝負では無い

わたしの考え方ではそのどれも重複回避に文字数を費やしてしまう
いろいろ書いたとは言えその束縛から逃げ出すことは出来なかった

全く別角度からのアプローチが必要なのでしょうが
果たしてそれで上手く遂行してくれるのか、、、
弄らないで、、、頭の中で否定してしまっている
最悪の、、、パターン

一番やってはいけないこと
常日頃一番否定していること

自身がやっているとは、、、情けない

＜わたしの代表的な考え方＞
３文字なので２番目（真ん中）の文字の位置を探し
それに隣接する範囲内に前後の文字があれば条件に適合

探し方はいろいろ、、、ジョー３さんの様に
縦に1・2～もよし、横に1・2～もまたよし

範囲の取り方も
直接 B2：D4 と入れる方法
位置を数値に変えてしまう方法
INDEX等で取得する方法
その他いろいろ

一例：数値にする場合
245,13456,256,12578,12346789,23589,458,45679,568等でそのまま範囲に、、、
124578235689123456789等でMIDなりで範囲に、、、などなど

検索はCOUNTIF・FIND・OR・・・これこそ色々

良さは、、、想定外無し（今の日本政府とは違う）
欠点は、、、文字の重複回避に文字数を費やしてしまう

わたしは、、、エクセルは第一に弄る事と思っていました
最近これを怠っていたが故、、、論外になってしまった（反省）
ジョー３さん、、、ありがとう

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

**********************************************************************************************

３文字限定とのことで、多分これで大丈夫と思うのですが、はっきり言って自信はありません、、、

264文字{=LEFT("○",(COUNTIF(OFFSET(INDIRECT("R"&SUBSTITUTE(MIN(IF(MID(H2,2,1)=$B$2:$D$4,{1;2;3}/1%+{1,2,3})),0,"C"),),,,3,3),MID(H2,{1,3},1))=1)+(COUNTIF(OFFSET(INDIRECT("R"&SUBSTITUTE(MAX((MID(H2,2,1)=$B$2:$D$4)*({1;2;3}/1%+{1,2,3})),0,"C"),),,,3,3),MID(H2,{1,3},1))=1))}

とりあえず今回も参加できてよかった、、--

 　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　(む印さん）

 

 

第９６回 文字つなげ問題



 
 

解答用参考ファイル：Q96_2011をダウンロード

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん出題）

**********************************************************************************

尚、解答締め切りは０５／０７（土）の午後８時の予定です。（状況によっては

変更される可能性があります）締め切りまでに私までメールで解答をお知らせ下さい。

解答発表までは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

***********************************************************************************************

当選者発表 第９５回 数字の分解

１）点数をまとめましたーーー
２）ジョー3の勝手な基準で、、、その点数を、当てはめたら、,,,
ｍｉｎｍａｘさんと、、、
からくちさんが、、、、
銅賞に該当しましたーーーー
全員驚愕の評価、、、も、、、、なく、、、、（＝金賞なし～）
ダントツの評価、、、、、も、、、なかったので（＝銀賞も、なし）
・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・
厳しいと言えば厳しい、、、
トップだからといって、,,金賞とは限らないのだから・・・・・・・
・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・
さてさて、、、次はどんな問題かなーーーー、、、９６，９７，９８，９９，１００・・・・・・
・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・
一つ考えなくっちゃ、,,,

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん談）

第９５回 数字の分解 解答発表

95回　数字の分解　
ジョー3回答案です
 
188文字
12桁対応版です。
あと、セルD4のこの式を右にドラッグで、二位、三位と出てきます（該当がある場合）
 
{=SMALL(SUBSTITUTE($B4/(IF((ROW(A:A)+65536*{0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17})>$B4^0.5,1,ROW(A:A)+65536*{0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17})),".",10^10)*1,COLUMN(A1))}
 
さてさて、皆さんの解答が楽しみです。
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん）

***************************************************************************************************

この問題、あまり深い意味はなく、素数計算の延長線で思いついたものです。
問題作って見た時の解は↓の83でした。
{=MAX((MOD(B4,ROW(INDIRECT("1:"&INT(B4^0.5))))=0)*ROW(INDIRECT("1:"&INT(B4^0.5))))}
83

アッと言う間に50台がでてきたので、あわててネジまきましたが、ありきたりの54しか思いつきませんでした。
{=MAX((MOD(B4,ROW(A:A))=0)*ROW(A:A)*(ROW(A:A)^2<=B4))}
54
毎度の事で、出題者完敗ムードですが、別発想の回答がありそうなので、
楽しみにしてます。
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（sakudaさん）

******************************************************************************************************

数学的なのは至って苦手です、、、適当にやってみたら、一応なんとかできてるみたい、、、

５６　{=INT(B4^0.5+1-MATCH(,MOD(B4,INT(B4^0.5-ROW(A:A)+1)),))}

 MODを使わないというだけで、根本的には５６と代わり映えしませんが、

５９　{=INT(B4^0.5+1)-MATCH(1,-1^(B4/INT(B4^0.5-ROW(A:A)+1))^2,)}

 とにかく参加できてよかったです＾＾ 　　　　　　　　　　　　　　（む印さん）

**********************************************************************************************

こんにちは　ｎｉです。 1４桁対応版、間違い修正と文字数ダイエットしたので再送します。

 {=IF(TYPE(D4)<>1,-ROUNDUP(SQRT(B4),0),IF((B4/D4=INT(B4/D4))*(D4>0),D4,IF(D4<0,IF(MAX((B4/(MAX(-(D4+4^8),0)+ROW(A:A))=INT(B4/(MAX(-(D4+4^8),0)+ROW(A:A))))*(MAX(-(D4+4^8),0)+ROW(A:A)))=0,MIN(1,D4+4^8),MAX((B4/(MAX(-(D4+4^8),0)+ROW(A:A))=INT(B4/(MAX(-(D4+4^8),0)+ROW(A:A))))*(MAX(-(D4+4^8),0)+ROW(A:A)<SQRT(B4))*(MAX(-(D4+4^8),0)+ROW(A:A)))),-ROUNDUP(SQRT(B4),0))))}

 循環参照＆配列数式です。３６３文字

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（niさん）

**************************************************************************************************

＜第９５回 数字の分解 回答＞

途中経過を見る限り、今回は色々な回答が出そうで楽しみです
関数式って、それなりになった人達（ここの人達も）には
その人なりの特徴（個性？）が現れるようで、それが面白い

５０ ： {=MATCH(SQRT(B4),IF(MOD(B4,ROW(A:A))=0,ROW(A:A)))}

ただし文字数は１文字増えますが（MATCH ５文字・LOOKUP ６文字）
同様の書き方でも、考え方としては下記の方が好みです

５１ ： {=LOOKUP(SQRT(B4),IF(MOD(B4,ROW(A:A))=0,ROW(A:A)))}

SQRT(B4）を B4^(1/2) に変えても文字数は変わらない
（マイクロソフトはそこまで考えていたのか ← そんな訳無い）
５１ ： {=LOOKUP(B4^(1/2),IF(MOD(B4,ROW(A:A))=0,ROW(A:A)))}

＞大きい方 － 小さい方 ＝ 差
＞字数はともかく是非見たいですね。
差 ： {=MIN(IF(MOD(B4,ROW(A:A))=0,ABS(ROW(A:A)-B4/ROW(A:A))))}

＞大きい方を先に見つける手段があればそれも是非見たいですね。
この問題、文字数を気にせずにそのまま書いたなら
下記のどちらかを書くのでは、、、

小さい方 ： {=MAX(IF(ROW(A:A)<=SQRT(B4),IF(MOD(B4,ROW(A:A))=0,ROW(A:A))))}
大きい方 ： {=MIN(IF(ROW(A:A)>=SQRT(B4),IF(MOD(B4,ROW(A:A))=0,ROW(A:A))))}

 　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

****************************************************************************************************

今晩は、いつもお世話になっております。遅ればせながら解答を送付いたします。

 実行環境は、エクセル2007で互換モードでやりました。 今回は、ほぼ初日でおわりました。

初日にやったなんにも考えずにやったもの。

100{=LARGE(IF(MOD(B4/ROW(A:A),1)=0,ROW(A:A)*{0,1}+B4*{1,0}/ROW(A:A)),COUNT(IF(MOD(B4/ROW(A:A),1)=0,)))}

そのあとすぐに単純に考えたなおしたもの。

46{=MATCH(B4,IF(MOD(B4,ROW(A:A))=0,ROW(A:A)^2))}

46{=MATCH(B4,IF(MOD(B4,ROW(A:A)),余,ROW(A:A)^2))}

で初日終わり。 後は、ほとんどＰＣ使わず頭の中で考えていましたが、全くいい方法が思いつかず。

niさんの52に刺激されてちょっとだけ短縮したもの。

44{=MATCH(B4,ROW(A:A)^2/(MOD(B4,ROW(A:A))=0))}

今日（土曜）作ったものこれは完全にだめですが、

{=MATCH(,MOD(B4,ROW(A:A)+INT(B4^0.5)),)+INT(B4^0.5)}

 特別気に入ったものはなく、結局あっているのか評価される式なのかよくわかりませんでした。

 桁数の多いものもちょっとやりましたが、できませんでした。みなさんの解答を楽しみにしております。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ minさん）

 

 

当選者発表



縦横問題を出したときに、、
からくちさん、、、、
この種の問題は簡単に解けるとおっしゃった。
で、、phoneticを思いついたとき、、、
からくちさんに、勝てるかもと、思った。
 
結局同じ手法・・・・・
この回答案が、,からくちさんだけだったら、、、
からくちさんが、、、金賞！！
だがなーーー、、、私を含めて、４名とは、
 
金賞はあり得ない。
 
sakudaさん、さすがーーー、、何かの賞！！、、でも、、
minmaxさんも、、、この回答・・・・・
 
くまぷーさんは・・・・・
・・・・・・・・・・・・
実は、監視３は、いかに監視場所をランダムに・・・・・
てな、問題を、、、予定していた。
くまぷーさんは、、、そこまで読んでた？・・・・
何かの賞を。・・・・・
 
・・・・・
それにしても、、、
niさん、、、、爆発・・・・・・
だれよりも、、、、先に賞、！！！
 
 
て、ことで、・・・・
やはり、全員、、銅賞！！ 
 
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（スポンサーのジョー3さん談）

第９５回 数字の分解

【問題】

B4の数字を２つの因数に分解する時
その差の絶対値がもっとも小さくなる
組み合わせを求めて下さい。
ただし、表示するのは２つの因数の
どちらか一方で十分です。

例えば２４は次のように分解できます。

２４×１
１２×２
８×３
６×４

この場合ペアの差が小さいのは６×４ですから
６または４が答となります。

大きな数字　11111111 はいろいろ分解できるでしょうが
7373×1507が一番差が小さいですから、7373または1507が
答となります。

なお、分解対象は2010では12桁、2007以下では8桁とします。
（この限度を超える式のアイディアは当然大歓迎です）

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（sakudaさん出題）

解答用参考ファイル：Q95_2011をダウンロード　（解答チェック機能付き）

 

**********************************************************************************

尚、解答発表は０４／２３（土）の午後８時の予定です。（状況によっては

変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************

第９４回 監視Ⅱ （賞品付き） 解答例

73文字でした。
=LEFT("×",PHONETIC((A4:G4,D1:D7,A1,B2,C3,E5,F6,G7,A7,B6,C5,E3,F2,G1))>"")
６７と言われ、、、ようやく分かったが、、、（６５まで）・・・それは、niさんにゆずって、、、、、・・・・・・
 
最初問題を作ったときは、phoneticは全然念頭になかった。だから、、解こうとしても、簡単解法の名案が浮かばなかった。
それで、仕方がないから、、縦横監視とした。
 
d4～f6に式？・・・これは全くの偶然で、・・・・監視区域、監視人の通路、自由区域（逃げる）を想定。
だが、、、
 
セルa1にまると入力、で、変換・・・（○）・・・ついで、
=phonetic(a1)    の結果が、　　まる　　とふりがなが出るのでなく、　　ふりがなまで、、○　　　　と、遊んでいたら、、、
思考の延長・・・・セルd4に  =phonetic(c3:e3)　　・・・・ぎょ、、、循環にならない！！自分を含んでるのに、、これは、、新発見？！！
（それにしても、自分のふりがながじぶんにふくまれるから（あくまでも雰囲気）・・・ありえない・・・と、思いつつ）
・・・・・・・・・と、いうことで、、、監視２を、出題することにしたわけで、、、、最初は、、
からくちさんと、、、同じ路線とは、、、、、思わなかった。
で、確認に、王問題を出題。。。　　
 
作意は、、=LEFT("×",PHONETIC(C3:E5)>"")　　　の29手、、、、、
うっ、、、、、即座に、からくちさん、、、29文字！！・・・・・・・これは、、、、、これは、、、、、、
 
：：：：：：過去問を見てみると、phonetic・・・循環しない・・・・・：：：：：：：：
そんな、コメントを見つけたり、、、、、
・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・・あはーー・・・・・・・・きおくにないじょー・・・・・・・
なんか、、自信をなくしてしまう。
 
しかし、からくちさんに感謝。。
監視で、この手法を残して下さったので、、、、、
監視2を、出題して、,,遊べましたーーーー。ほんと、、感謝、感謝・・・・・

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん）

********************************************************************************************************

 くまぷーさん　こんにちは ｎｉ　です。 q94_2011の回答を添付します。

 お楽しみの　関数７種類３０個２７９文字　も入っています。 もうこれ以上はムリ＾＾

Q94_ni_Hotmailをダウンロード

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（niさん）

********************************************************************************************************

=LEFT("×",COUNTA(($3:$3,$7:$7,$C:$C,$G:$G) (C3,B2,A1,E5,F6,G7,E3,F2,G1,C5,B6,A7,D:D,4:4)))

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん）

********************************************************************************************************

=LEFT("×",(D$3&D$7&$C4&$G4>"")+(ROW()=4)*LEN(C3&E3&A7&G7)+(ROW()=5)*LEN(B2&F2&B6&F6)+(ROW()=6)*LEN(C5&E5&A1&G1)+(COLUMN()=4)*LEN(C3&C5)+(COLUMN()=5)*LEN(B2&B6&F2&F6)+(COLUMN()=6)*LEN(E3&E5))

１９０文字です。

監視人をＦ９で移動させるとPhoneticが使えなくなるんで、

今回はジョー3さんの「解答用参考ファイル」を

勝手に改造せずにそのままにしました。

前回は出題者の意図に気づかず勝手に変えてごめんなさい。m(__)m

上のは、芸が無くて恥ずかしいんですがF9監視人移動バージョンでも大丈夫です　(^^ゞ

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（くまぷー）

*********************************************************************************************************

＜監視 Ⅱ 回答＞

以前の事ですが、、、
A1＆A2＆A3・・・を
PHONETIC(A:A) と提示した事がある
（勿論ですが同じと言う事ではありません）
今では普通に使われているようですが

複数の範囲設定も出来るし
範囲内に自セルが入っても循環にならない
それ以外にもPHONETIC関数の特性がこの問題にはありがたい
＜回答式＞
=REPT("X",PHONETIC((D:D,4:4,C3:E5,A1,B2,F2,G1,B6,A7,F6,G7))>"")

と、、、殆んど考えずに出来てしまった、、、式

若しわたしに関数の組み方(考え方）を教えて欲しいと頼まれたなら
上記の式より、先ずこんな考え方を習得して欲しいと思います

=REPT("Ｘ",CHOOSE(ROW()*3+COLUMN()-15,C3&D3&E3&C4&C5&G4&D7&G7,C3&D3&E3&B6&F6&D7,
 C3&D3&E3&E4&E5&A4&D7&A7,C3&C4&C5&D2&D6&F2&F6&G4,B2&D2&F2&B4&F4&B6&D6&F6,
 E3&E4&E5&D2&D6&B2&B6&A4,C3&C4&C5&D5&E5&D1&G4&G1,C5&D5&E5&B4&F4&B2&F2&D1,
 E3&E4&E5&D5&C5&A4&D1&A1)>"")

=LEFT("Ｘ",COUNTA(CHOOSE(ROW()*3+COLUMN()-15,(C3:E3,C4:C5,D7,G7,G4),(C3:E3,B4,F4,B6,F6,D7),
 (C3:E3,E4:E5,A4,D7,A7),(C3:C5,D2,D6,F2,F6,G4),(B2,D2,F2,B4,F4,B6,D6,F6),(E3:E5,D2,D6,B2,B6,A4),
 (C3:C5,D5:E5,D1,G4,G1),(C5:E5,B4,F4,B2,F2,D1),(E3:E5,C5:D5,A4,D1,A1))))

勿論ですが、わたし好みと言う事ではありません
好み、ではありますが

先ずは考え方を習得して欲しいから
関数式は、、、知恵で作るものであって知識で作るものではない
常に新規です。。。記憶・記録では写すのみ、創造していません

それでは誰も作らない（式・考え方）わたし好みを１つ
反復計算使用と言う違反？行為を使う代わりに
ちょっと見た目では何が何だか分からない様な、、、誰とも被らない、式を

{=LEFT("Ｘ",COUNT(FIND(CHAR(LARGE(IF($C$3:$G$7="◯",ROW($C$3:$G$7)&COLUMN($C$3:$G$7)+2)*1,{1,2})),
CHOOSE(ROW()*3+COLUMN()-15,"#$%-71LO","$%&-1AEM","%&'1;-KN","-7A$L&N;","#%'7;KMO",
"1;E&N$L7","7AKLM$'E","LMNAE-1%",";EONMA&#"))))}

そこで一句
『遊び式  これもエクセル  禅問答』

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

*********************************************************************************************************

お世話になっております。解答はメールとのことですので一応送ります。

90=LEFT("×",COUNTA((C3,B2,A1,E3,F2,G1,C5,B6,A7,E5,F6,G7,D:D,4:4)($3:$3,$C:$C,$7:$7,$G:$G)))

86=LEFT("×",COUNTA((C3,B2,A1,E3,F2,G1,C5,B6,A7,E5,F6,G7,D:D,4:4)(1:$3,A:$C,$7:7,$G:G)))

65=LEFT("×",PHONETIC((C3:E5,B2,A1,F2,G1,B6,A7,F6,G7,D:D,A4:G4))>"")

73=LEFT("×",PHONETIC((C3:E5,B2,A1,F2,G1,B6,A7,F6,G7,D:D,4:4)$C$3:$G$7)>"")

よろしくお願いします。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（minさん）

 

 

 

 

第９４回 監視Ⅱ （賞品付き）

********************************　重　****************　要　*********************************************

審査員で点数をつけて、優秀者に賞品があります。
（点数によるので、最高点でも該当するとは限らない）
厳しい審査を受けて賞を頂けるのはどなたでしょう？
（かなりきびしい？＝驚きの作品でないと該当しないでしょう）
銅賞 お米Aかお酒A
銀賞 お米Bかお酒B
金賞 パソコンか（お米Cとお酒C）
予算は10万です 
予算が消化されないと、次回に持ちこしです。
予算が少なくなると金賞はなくなります。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（スポンサーのジョー3さんより）

応募の手順

１）作品が出来たら、期限（０４／０９）まで（土曜までくまぷーに回答をメール）
２）日か、月に作品を発表する
３）木まで、審査員はメールで点数（５段階評価）をくまぷーに送る
４）次の土曜頃（０４／１６）結果発表

尚、審査員は以下の５名とする。

ジョー3さん、y sakudaさん、　minmaxさん、　からくちさん、くまぷー　（審査員はスポンサーのご指名です）

尚、総合評価は各審査員の評価を平均する。審査員は自分の作品を評価することはできない。

***********************************************************************************************************

監視が、物足りなかった方は今回は、楽しめると思います。

色々なとき方を期待しております。

文字数は、あまり気にしていません。

手法に関心があります。

【問題】

監視人がパワーアップしました。

縦横に加えて、斜め監視も出来ます。

つまりチェスのR（飛車）から、Q（女王）の性能なのだ。

で、二人で監視することになりました。

監視人の位置は○で表示されます。監視人は縦横斜めを

八方向をにらんでますので、×印のところでは悪いことが出来ません。

緑の任意の位置の二人の監視人に対して

監視されてる位置に×印をつけて欲しい。

式の入力はセルＤ４のみ、、

その後、残りの黄色いセルにその式をコピーすること

黄色＝監視されてる区域

薄い緑＝監視人の通路区

青い部分＝自由区域部分

 

解答用参考ファイル：Q94_2011をダウンロード

**********************************************************************************

尚、解答発表は０４／０９（土）の午後８時の予定です。（状況によっては

変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************

 

 

第９３回 【 関数のお勉強 応用編 】 解答例

全く理解出来ない、東京電力
大変な状況なのは分かります
被災地区の事を思えば協力は惜しみません

しかし「計画停電」と言う名の
「無計画停電」・「不公平停電」
ネット等を見ていると東京電力の対応に不満の声
こう言った声が大きくなり、長期化すると
やがて不満先がボヤケて来る
被災地・被災者に責任はありません

早急に対応の改善を・・・

＜関数のお勉強 応用編 出題者解答例＞

Ａ列にある数値の種類数を求める場合
=COUNT(0/FREQUENCY(A:A,A:A))
で求めることが可能
しかしその範囲が複数列で規則性も無い場合（A・C・F列の様に）
その範囲をどの様に指定するか
エラーになってしまう様なこの書き方、幾つかの関数では可能なようで
=COUNT(0/FREQUENCY((A:A,C:C,F:F),(A:A,C:C,F:F)))
で求められる

今回はこのFREQUENCY()とこの書き方を解答例で使いたかったので・・・

：=COUNT(0/FREQUENCY((A:A,C:C,F:F),B1+ROW(1:50)-2))-1

を出題者解答例とさせて戴きます

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん談）

第９３回 【 関数のお勉強 応用編 】

【問題】

B1以上大きな数値の種類数をB5に求めてください

求める範囲はA1～A100・C1～C100・F1～F100とします

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん出題）

 
 

解答用参考ファイル：Q93_2011をダウンロード

**********************************************************************************

尚、解答発表は０３／２６（土）の午後８時の予定です。（状況によっては

変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************

第９２回 【 関数のお勉強 基礎編 】 解答例

簡単に義援金を送るには、、、そうだコンビニに行こう
いまコンビニで買いたいものが無いけど、、、
受け取ったお釣りをそのまま全て義援金箱に
うう～ん、、、中にはお札も入っている
自分のセコさが、、、恥ずかしい

【 関数のお勉強 基礎編 出題者解答例 】

1 =LOG(A1)
2 =LEN(A1)
3 =WEEKDAY(A1)
4 =TYPE(OR(A1))
5 =INT(SQRTPI(A1))
6 =FACT(SQRT(A1))
7 =HOUR(LN(A1))
8 =OCT2DEC(A1)
9 =WEEKNUM(COSH(A1))
10 =N(A1)

上記以外では
（1）
=ERF(A1)
=ROW(A1)
=MONTH(A1)
（2）
=BIN2DEC(A1)
=INT(LN(A1))
=MONTH(COSH(A1))
（3）
=INT(SQRT(A1))
=DAY(SQRT(A1))
=WEEKNUM(LEN(LN(A1)))
（4）
=MONTH(EXP(A1))
=SQRT(LEN(LN(A1)))
=WEEKDAY(HEX2BIN(A1))
（5）
=HOUR(COSH(A1))
=HOUR(SINH(A1))
=MONTH(HEX2BIN(A1))
（6）
=DAY(DEC2BIN(A1))
=FACT(WEEKDAY(A1))
=DAY(FACTDOUBLE(A1))
（7）
=LEN(FACT(A1))
=SQRT(CODE(A1))
=WEEKDAY(TAN(A1))
（8）
=OCT2HEX(A1)
=INT(RIGHT(SQRT(A1)))
=MINUTE(ABS(COS(A1)))
（9）
=WEEKNUM(SINH(A1))
=MONTH(OCT2BIN(A1))
=WEEKNUM(MINUTE(ASINH(A1)))
などなど、、、他多数

これ以外にも多くの式を作りました
どれが良い式と言う事ではありませんので
一例のみとさせていただきます

この問題は沢山の式・考え方を作る事が可能です
色々な式（皆さんの式）を見るのが楽しみです

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん談）

第９２回 【 関数のお勉強 基礎編 】

A1に数値10が入っています
このA1を使って、数値 1 ～ 10 を作ってください

ただし条件があります

＜条件＞
：必ずA1を１回使うこと ただし2回以上は禁止
：必ず１つ以上の関数を使うこと
：同じ関数を２回以上使うことは禁止
：関数名・（ ）・A1 以外の使用は禁止
 （数字・数値・アルファベット・,・％・"" 等々の使用禁止）

  =関数(A1)
  =関数(関数(A1))
  =関数(関数(関数(A1)))

《例》
11=SECOND(ATAN(A1)%) ・・・これは%を使っている為、ＮＧと言うことで
11=HOUR(ATAN(A1)) ・・・を採用したとします

12=--DEC2OCT(A1) ・・・これは数値にする為マイナスを使っている為、ＮＧ

13=MEDIAN(SECOND(ASINH(A1)),) ・・・これは「,」を使っている為、ＮＧ
13=HOUR(ABS(SIN(A1))) ・・・これは11で使ったHOUR関数を使っている為、ＮＧ

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん出題）

**********************************************************************************

尚、解答発表は０３／１９（土）の午後８時の予定です。（状況によっては

変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************

第９１回 監視 解答例

かぶりにくいのを、、、、
１個だけお送りいたします。
CC３５文字です
 
=CHAR(CODE(D$3&D$7&$C4&$G4&"<")-28)
 
２９、３６はきっと同じでしょう。
 
監視Ⅱも、作りました。
監視の皆さんの回答次第では、、
出題いたします。
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん談）

第９１回 監視

"最近私の会社で、セコムの監視に
ネズミがかかった・・・・・大変だったなーーー"
"入試の不正・・・監視には、、かからなかった
ある意味スゴイのね、、"
"で、、、青いところに監視人が３人います（＝○）
黄色のところに犯人？が、います。
監視人から縦、横が、、監視できます。"
"縦、横に監視人がいるとその黄色い場所では
何も出来ません（だから、、＝×）"

"で、問題・・・・・・
任意の場所の３個の○に対して、
条件にあった場合×を表示して欲しい。"
"セルD4に式を書いて
それを他の黄色いセルに
コピーして完成してほしいのだ"

　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー３さん出題）

 

解答用参考ファイル：Q91_2011をダウンロード

**********************************************************************************

尚、解答発表は０３／１２（土）の午後８時の予定です。（状況によっては

変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************

 

第９０回 πの計算（その２） 解答例

どうもこの問題すべっちゃったみたいですね。
金曜日のこの時間まで誰も乗ってこない＾＾；

この問題で問題になるのは、
(1*3*5)/(2*4*6) のところをどうするかと言う一点です。
関数を良くご存じのかたなら、FactDoubleの　奇数/偶数　と分かると思います。
ところが、これはAddIn関数らしく、2003まででは配列数式の中ではつかえません。

で、まず2007以降バージョンです
定義どおりに式にした95です
{=6*SUM(FACTDOUBLE(ROW(1:15)*2-3)/FACTDOUBLE(ROW(1:15)*2-2)/(ROW(1:15)*2-1)/2^(ROW(1:15)*2-1))}
整理してみても90どまりでした。
{=12*SUM(FACTDOUBLE(ROW(1:15)*2-3)/FACTDOUBLE(ROW(1:15)*2-2)/(ROW(1:15)*2-1)/4^ROW(1:15))}

問題は2003以前のバージョンでできるかということなんですが、できました。
FactDoubleの偶数は　=FACT(ROW(1:16)-1)*2^(ROW(1:16)-1)　で表現できます
また奇数は　=FACT((ROW(1:16)-1)*2)/FACT(ROW(1:16)-1)/2^(ROW(1:16)-1)
で表現可能でした。
これらを使って定義通り書いたのが103です。
{=SUM(6*FACT((ROW(1:16)-1)*2)/(FACT(ROW(1:16)-1)*2^(ROW(1:16)-1))^2/(ROW(1:16)*2-1)/2^(ROW(1:16)*2-1))}

これをダイエットしたら、なんと2007以降版より短縮でき、79でした。
{=SUM(48*FACT(ROW(1:16)*2-2)/FACT(ROW(1:16)-1)^2/(ROW(1:16)*2-1)/16^ROW(1:16))}

                                                                                               （y sakydaさん談）

第９０回 πの計算（その２）

【問題】ニュートンの公式で式一つでπを計算してください。

π=6*(1/2+1/(3*2*2^3)+(1*3)/(5*2*4*2^5)+(1*3*5)/(7*2*4*6*2^7)・・・・・・・）

 

解答用参考ファイル：Q90_2011をダウンロード

**********************************************************************************

尚、解答発表は０３／０５（土）の午後８時の予定です。（状況によっては

変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************

 

 

第８９回 πの計算 解答例

マチンの公式をそのままExcelにしたもので81
{=SUM((16/5^(2*ROW(1:15)-1)-4/239^(2*ROW(1:15)-1))/(ROW(1:15)*2-1)*-1^ROW(2:16))}

これを変形してダイエットして63でした。
{=SUM((956/-57121^ROW(1:15)-80/-25^ROW(1:15))/(ROW(1:15)*2-1))}

63はともかく、みなさん秒殺で70ちょいくらいまで行っちゃうと思ったんですけどねーー

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん談）

第８９回 πの計算

【問題】

マチンの公式で式一つでπを計算してください。

マチンの公式：π=16*(1/5-1/(3*5^3)+1/(5*5^5)-1/(7*5^7)・・・・・・・)-4*(1/239-1/(3*239^3)+1/(5*239^5)-1/(7*239^7)・・・・・・)

 
解答用参考ファイル：Q89_2011.をダウンロード

**********************************************************************************

尚、解答発表は０２／２６（土）の午後８時の予定です。（状況によっては

変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************

 

第８８回 何進数ですか？ 解答例

71 から何も思いつかないので、一応出題者解答は71で送りました。
まだ、明日粘ってみますがｗ
=MATCH(B3,MMULT(C1:J1+1,MID(D3,ROW(1:8),1)*COLUMN(B:J)^(8-ROW(1:8))))+1

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん　２月１８日談）

第８８回 何進数ですか？

B3に１～255を入れるとD3に2進数～10進数のいずれかに
変換されます。

それが何進数か判別してF3に表示してください。
1など、複数のNが該当する数字の場合は該当するNのいずれかを
表示してください。（１の場合、２でも３でも10でもOK)

なお、テストしやすいように、B3を変更しなくても、F9でD3は
再計算されるようにしています。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん出題）

 

解答用参考ファイル：Q88_2011をダウンロード

**********************************************************************************

尚、解答発表は０２／１９（土）の午後８時の予定です。（状況によっては

変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************

第８７回 N進数 解答例

配列で60台にしたが、
かなわないので、、
１９２だけ、、
 
=INT(MOD(B$1,A2^8)/A2^7)
&INT(MOD(B$1,A2^7)/A2^6)
&INT(MOD(B$1,A2^6)/A2^5)
&INT(MOD(B$1,A2^5)/A2^4)
&INT(MOD(B$1,A2^4)/A2^3)
&INT(MOD(B$1,A2^3)/A2^2)
&INT(MOD(B$1,A2^2)/A2^1)
&INT(MOD(B$1,A2^1)/A2^0)
 
無駄が、，，，，，ははは、、、
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん談）

******************************************************************************************

くまぷーのファイル：

１０進数→２進数から２９進数へKuma_Q87_2011をダウンロード

第８７回 N進数

【問題】セルＢ１に１０進法で数字を書きます。
それは１から２５５です。（それ以外は無視）

セルA2からA9まで、2から9が入力されてます
それは、？進法を意味します。

では、
セルB2の式を考えて下さい。
条件：B3からB9はセルB2の式をコピーできるようにね！！
それだけです。

ちょっと難しいかなーーって、思ったら、簡単でした。
でもねーーー，，威張れない。ながいから、、ね、、、
192文字なのだ。・・・・・・短くなりそうではあるけど、、
192文字以下を考えて、、出題者に対して、優越感に浸って下さいな！！
あ、、、セルB2からB9は、、表示形式で0を表示してもかまいません。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん出題）

 

**********************************************************************************

尚、解答発表は０２／１２（土）の午後８時の予定です。（状況によっては

変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************

第８６回 破れかぶれ 解答例

下はジョー3さんから頂いた解答例です。

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1,CHOOSE(RIGHT(10^8+NOW()),1,2,3,4,5,1,2,3,4,5),"")&CHOOSE(RIGHT(10^8+NOW()),1,2,3,4,5,1,2,3,4,5),CHOOSE(RIGHT(10^7+NOW()),1,2,3,4,5,1,2,3,4,5),"")&CHOOSE(RIGHT(10^7+NOW()),1,2,3,4,5,1,2,3,4,5),CHOOSE(RIGHT(10^6+NOW()),1,2,3,4,5,1,2,3,4,5),"")&CHOOSE(RIGHT(10^6+NOW()),1,2,3,4,5,1,2,3,4,5),CHOOSE(RIGHT(10^5+NOW()),1,2,3,4,5,1,2,3,4,5),"")&CHOOSE(RIGHT(10^5+NOW()),1,2,3,4,5,1,2,3,4,5),CHOOSE(RIGHT(NOW()),1,2,3,4,5,1,2,3,4,5),"")&CHOOSE(RIGHT(NOW()),1,2,3,4,5,1,2,3,4,5)

（528文字）

****************************************************************************

くまぷーのファイル：Kuma_Q86_2011をダウンロード

第８６回 破れかぶれ

セルa1には、12345が入ってます。（またまた、固定） 
 
 
で、問題 
 
セルA2に 
 
12345 の入れ替えた数値１２０種類が出現する式を
 書いて欲しいのだ。(f9で）
 
21334 は、、、３が2個あって、5がないからだめ、、、
 
＊１ 出現率が同じ？？？・・・＝凄すぎ
＊２ 全部出る？？？・・・・＝ｽｺﾞｲ
＊３ でないのもあるけど・・・・・ごまかし？？？＝それでもいいかも、、、

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん出題）

**********************************************************************************

尚、解答発表は０２／０５（土）の午後８時の予定です。（状況によっては

変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************

第８５回 何手で復元？ 解答例

今回は大変、ご迷惑をおかけいたしました。
自分の出題に自分で苦しんで、、
ぎっくり腰で、、いたたた、、、で、
皆さんの短い数字で、、、うえーーーーー
で、、
最初に考えた超長手数＆整理無しを、、
出します。
１４８
{=INT(SUM((MID(C3,ROW(1:5),1)*1＜＞ROW(1:5))*1)/5*4)-(SUM((MID(C3,ROW(1:5),1)*1＜＞ROW(1:5))*1)＞3)*(SUM((MID(C3,MID(C3,ROW(1:5),1),1)*1=ROW(1:5))*1)＞1)}

こんなだったと思う・・・・・

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん談）

第８５回 何手で復元？

先回の１２３４５の問題の、、類作です。
 
こんどは、複数回入れ替えで、でも５文字ですから、、簡単？？
 
例えば、
２１３５４は、、何回の交換で、、、１２３４５に戻せるか？
勿論２回ですよね、、、人間にはすぐ分かる。
さて、エクセル君は・・・・・
 
色々なケースを考えると、、、
回答は、、、
０，１，２，３，４の５種類のどれかですよね、、・・・・
さてさて、、、
こんかいも、、、
思いがけなくも、、超シンプルな回答がどなたからか、、、
出てくるような気がするのだが・・・・・・・

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん出題）

 

解答用参考ファイル：Q85_2011をダウンロード

**********************************************************************************

尚、解答発表は０１／２２（土）０１／２９（土）の午後８時の予定です。

（出題者ジョー3さんの回復具合によっては変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************

 

第８４回 並べ替え 解答例

重複ありでも30台？
全く見当もつきません。また出題者完敗の巻ですねーーｗ
私はこれが精いっぱいでした
重複あり　56　
{=MAX(IF(RANK(A$2:A$11,A:A,1)=ROW(A1),A$2:A$11),B$1:B1)}

重複なし　49
{=MAX(IF(RANK(A$2:A$11,A:A,1)=ROW(A1),A$2:A$11))}

どんな回答が飛び出すのか楽しみにまってます^^

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（sakudaさん談）

第８４回 並べ替え

でっち上げ問題です。単純なソートではここの問題にならないので、

SMALLとLARGEを禁止にしました。

重複が発生しなければそれ程難しいわけではないですが、

重複をどう処理するかがちょっと問題になるのではないかと思っています。

私も重複なしの式は作成してみましたが、重複の処理についてはまだ考えてませんｗ

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん出題）

 

解答用参考ファイル：Q84_2011をダウンロード

**********************************************************************************

尚、解答発表は０１／１５（土）の午後８時の予定です。（状況によっては

変更される可能性があります）

それまでは直接数式を書き込むこと・ポイントとなる関数名を

書き込むことはご遠慮ください。

**********************************************************************************