Excel Maniacs

関数で出来ますか～？ 第60回 挟み将棋

骨休みになるのか？

挟み将棋もどき

加藤一二三んさんと挟み将棋ならもしかしたら勝てるかも。

L12からN14まですべてのセルにあらかじめ歩が置かれているとする。

その周りに「と」を2個だけ置くことができるとして、

縦横斜めに挟まれた場合は歩が取られ

挟まれた部分に歩はなくなる。

セルL12の数式をL12からN14までコピーして、

挟まれていないセルは「歩」、

挟まれているセルは空白

を表示するようにしてほしい。

L12に入れる数式は？？

本来挟み将棋は縦横で斜めはなしですがそれでは面白くないので斜めも追加してます。

なお、"原則として"循環参照なしです。　（minさん）

解答用参考ファイル： 20190617をダウンロード

***********************************************************************

解答発表は06/22（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

関数で出来ますか～？ 第59回 数は使用禁止 解答例

出題者解答例

今回は文字数を少なくと言う主旨は無いのですが
しかしここでは皆さん凄い方達なので、、、
と言う事で出題者解答例をどうしようか迷いました
・より短い式
・より長い式
・より被り難い式
などなど、、、
いろいろと迷った結果です

15=EVEN(ODD(C:C))

=FIND(,)
=COUNT(,)
=INT(PI())
=MATCH(,C:C)
=ERROR.TYPE(#REF!)
=COLUMN(C:C)
=CELL("col",B:B)
=LEN("c")
=TEXT(,"b")
=CODE("a")

　　　　　　　　　　　　　　　（からくちさん）

関数で出来ますか～？ 第59回 数は使用禁止

【問】C３の数値が奇数ならC3+1を
C３の数値が偶数ならC3+2をF3に
ただし式に数字は一切使用禁止です
（=C3は３が違反です）
これだけでは余りにもなので、、、
式に数字の使用禁止は同じで
１以上の整数（自然数）を
１０式（F3～F14）作ってください
RAND()は１以下
AVERAGEは少数点が出る場合も
MIN・MINAの様な関数は１個のみ使用可
１関数１回のみ使用可
同じ関数の複数回使用禁止

　　　　　　　　　　　　　　　　　　　　　（からくちさん）

解答用参考ファイル： 20190609をダウンロード

***********************************************************************

解答発表は06/15（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

関数で出来ますか～？ 第58回 この関数が無かったら 解答例

今回の出題は未成熟さが拭えない問題ですみません。

やはりジョー3さんも問題は成熟されているなと改めて思います。

いろいろ式を書いてしまった為どれを解答例にしようか迷いました。

１９ =FREQUENCY(C:C,C:C)

２２ ={COUNT(0/C:C=200))}

１３ =NPV(,C:C)&""

２７ ={=COUNT(0/(C*C/2-INT(C:C/2)))}

 

文字数だけでならもっと短いのもいろいろありますが

次の問題のこともあるのでここではまだ、、、

と言う事で計８１文字です。

SUMを使ったり他の関数を使うと少々短くはなりますが、、、

　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

関数で出来ますか～？ 第58回 この関数が無かったら

おそらく問題が無いのではと思い作りました。
同じ様な発想ですが、、、
よろしくお願い致します。

(からくちさん）

＜問　題＞

・H列の数値と全く同じ数値（表示）をF列に出してください

・ただし書式はそのままで

・H列に使用している式はI列に出ています

・ここに使われている関数は当然使用禁止です

解答用参考ファイル： 20190604をダウンロード

***********************************************************************

解答発表は06/08（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

関数で出来ますか～？ 第57回 文字の種類 解答例

解答例

{=COUNT(0/FREQUENCY(IF(C4:C200>99,-C4:C200),-ROW(1:99)))}

今回は出題をしていながら実に不思議な事だらけでした
この式、、、合っているか否か
　　　（からくちさん）

関数で出来ますか～？ 第57回 文字の種類

問題
C列には数値と数字が入っています
範囲（C4：C200）
その中で数字の種類数をÈ４に

＜例＞
2
2
22
77
64
64
64
77
2
2

この場合は数字は２・６４・６４・２の４個ですが
２・６４の２種類なので答えは「２」です
７７等数値は無視です。

　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

解答用参考ファイル： 20190528をダウンロード

解答用参考ファイル（sakudaさん提供　マクロ入り）： 20190528-2をダウンロード

***********************************************************************

解答発表は06/01（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

関数で出来ますか～？ 第56回 名前最頻値 解答例

◆よろしくお願いします

--------------------------------------------------

◆配列数式：88
{=INDEX(B:B,MOD(MAX(FREQUENCY(MATCH(B5:B1004,B:B,),ROW(5:1004))/1%%+ROW(5:1005)),10^4))
 
}
◆でもこれでもいいように思います

配列数式：86{=INDEX(B:B,MOD(MAX(FREQUENCY(MATCH(B5:B1004,B:B,),ROW(1:998))/1%%+ROW(1:999)),10^4))}

 （maronさん）

関数で出来ますか～？ 第55回 Mode紛い 解答例

解答例

この問題は若しこの関数が無かったら、、、
と言う発想を昔考えた事がありました
従いましてどんな関数でもその関数が無かったらにすると
問題になってしまう安易な発想です

=INDEX(B:B,MATCH(MAX(FREQUENCY(B:B,B:B)),
FREQUENCY(B:B,B:B),)+4)

わたしとしては結構好きな度数分布を使いました

因みにもう１つの好きな関数LOOKUPだと
=LOOKUP(,0/(MAX(FREQUENCY(B:B,B:B))=FREQUENCY(B:B,B:B)),
B5:B1004)

MODE紛いの「紛い」をどう解釈するか
（１）違う関数で同じ値を返すと捉える
（２）違う関数で同等の値を返せればと捉える
上記ではINDEXが（１）LOOKUPは（２）です

　　　　　　　　　　　　　（からくちさん）

関数で出来ますか～？ 第55回 Mode紛い

【問】

B列（B5:B1004）に０～９９までの数値が入っています。
この中で１番多い数値はMODEを使えば出ます。
MODEとCOUNTIF禁止でMODEと同じ値をE９に。

　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

解答用参考ファイル： 20190514をダウンロード

 ***********************************************************************

解答発表は05/18（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

 

関数で出来ますか～？ 第54回 魔方陣Ⅱ 解答例

からくちさんから出題者解答例が送られてこないので・・・

【解答例】

循環参照です。

まず・・・

「ファイル」→「オプション」→「数式」と辿り、「反復計算を行う」にチェックを入れ、「最大反復回数」を最大にしてください。

そしてD５に・・・

=IF(COUNT($D$5:D5)=4,5,IF(AND(COUNTIF($D$5:$F$7,D5)<2,$D$5+$E$6+$F$7=15,$F$5+$E$6+$D$7=15,D$5+D$6+D$7=15,$D5+$E5+$F5=15),D5,IF(ROW()=5,15-D6-D7,IF(COLUMN()=4,15-E5-F5,INT(RAND()*9)+1))))

・・・と入力してF7までコピペ（187文字）

実は・・・この式はminさんが、以前作ったものを完全にパクったものです。m(__)m

minさんは凄すぎ！！

第58回 魔方陣 解答例

　魔方陣を作るってのは、以前問題が尽きかけた時、できるかどうか分からない問題で
良ければと言うことでくまぷーさんに提案していたものです。
式一種類では全く歯が立たないのですが、ワークエリアを使っての循環参照による繰り返し
計算ならなんとかなりそうだというので出題をお願いしました。

最初作った時は、３×３の場合、B2:C3の４セルの数字を変えて魔方陣ができるまで繰り返計算させていたのですが、その場合約3000回の反復計算が必要でした。
後になって、3セル指定されれば後は自動的に決まってしまうのに気が付き反復計算を大幅にダイエットしたのが33Aです。
この時点では、反復回数をどうこうするというより、文字数のダイエットに集中してました。
しかし、これは何ぼ何でも無駄なサーチをやっているので、その辺りを整理したのが３３Bで
反復回数は劇的に減少しました。
なお、３３B、４４A、４４Bは続行可能で、次々魔方陣を作って行けます。

3×3の魔方陣はいずれにしろ大した反復は必要ないのですが、4×4になるとちょっとやそっとでは収束しません。
で、いろんな工夫をたたきこんで、１万回以下の反復でなんとか最初の魔方陣が見つかるようにしたのが４４Aです。
(33B以降は式のダイエットはほとんど考慮してませんので、冗長な式が結構あります）

５０回程続行してみたのですが、最短は反復５回、長い場合で9000回くらいの反復で次の
魔法陣が見つかります。（平均3000位だと思います）

44Bは4分割した4セルの合計がいずれも34になる特殊形だけを早く見つける工夫をしたものです。
（4×4の魔方陣ではこのタイプが相当数あります）
これは300回くらいの反復で次々みつかります。

なんか、今回は私一人で楽しんじゃったみたいですみませんm(＿＿)m

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん談）

★sakudaさんのファイル：Q58_2010_sakuda_san.lzhをダウンロード

★くまぷーのファイル：Q58_2010_kuma_pooh.lzhをダウンロード

関数で出来ますか～？ 第54回 魔方陣Ⅱ

【問】

式をD５に入れそれをF7までコピペとします。
右側（K5:M7）に数値が１つ出ています。
その数値を左側（D5:F7)の同じ位置に入れてください。
当然ですがそのセルは式が消えその数値になります。
それで魔方陣を完成させてください。　（からくちさん）

 

訂正 こんにちは 先の問題は若しかしますとあのままでは出来ないかも、、、です。 改めてお送り致します。 毎度ご面倒をお掛け致します。 訂正は左に式か数値を入れると 右は全て空白になるようにしました。 宜しくお願いします。 からくち

★魔方陣とは縦横斜めの合計が同数（この場合１５）になる。
また同じ数値は無し（１～９の数値全て使用する）

解答用参考ファイル： 20190430をダウンロード

解答用参考ファイル（差し替え）： 20190502をダウンロード

★既出問題　魔方陣（2010年4月27日）

 ***********************************************************************

解答発表は05/11（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

関数で出来ますか～？ 第53回 15パズル 解答例

90です。ご覧のとおり、１～15、0の配列を作って比較しているだけです。

{=IF(AND(MOD(IF(C4=2,ROW(1:4)*4+COLUMN(A:D),ROW(1:4)+COLUMN(A:D)*4)-4,16)=B4:E7),"O","X")}

（sakudaさん）

関数で出来ますか～？ 第53回 15パズル

くまぷーさんが三四郎か何かのマクロで作っておられた
昔ながらの１５パズルです。
表示された、パターンが正解状態か否かをH4に○×で
答えてください。
なお空のセルは0で表示されています。
正解とする並び順は縦でも横でもOKとします。
（要するに並んでいて右下隅に0がある）
もちろん、カラクリシートを参照したりするズルはダメですｗ

　　　　　　　　　　　　　　　　　　　　　　　　　　　　（sakudaさん）

解答用参考ファイル： 20190422をダウンロード

 ***********************************************************************

解答発表は04/27（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

 

関数で出来ますか～？ 第52回 元号問題--令和元年-- 解答例

からくちさんの解答例です。

=TEXT(C3,"[>43585]令和;ggg")&TEXT(C3,"e")-(C3*1>43585)*30&"年"

関数で出来ますか～？ 第52回 元号問題--令和元年--

【問】

C列は文字で日付が入っています

これをD列の様に元号年にしてください

ただしIF関数は使用禁止とします

また使用できる関数は１種のみ

ただし何回使用しても構いません

解答用参考ファイル： 20190416をダウンロード

 ***********************************************************************

解答発表は04/20（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

 

関数で出来ますか～？ 第51回 AAさん 解答例

7時になってから、ジョー3さんの「解答例、よろしく！！」の無茶振り・・・

 

実は前回は、久しぶりの「関数で出来ますか~？」ということもあり

ジョー3さんが解答例送付を忘れることもあるのでは、と思い

解答例の原稿を用意していました。しかし、前回、ちゃんと送付されたこともあり

今回は、全然用意していませんでした。

1.縦タイプ(単独）
2.横タイプ(単独）
3.縦+横(合計）
4.縦・横（1式）

【解答例】

では、3.縦+横(合計）を・・・

縦：44文字

=MID(ADDRESS(1,ROW()-1),2,2-(ROW()<28))&"さん"

横：23文字

=INDIRECT("A"&COLUMN())

合計：67文字

関数で出来ますか～？ 第51回 AAさん

3問セットにしようと思ってました。
 
問題を忘れて、
1問だけ出しました
 
 
思い出しました。
 
 
問題
（これは、ある会社からの依頼）
 
Ａさん、Ｂさん、Ｃさん、Ｄさん
・・・・
・・・・・・・・
というリストを作りたい。
それだけ、・・・・・
 
 
で、お尋ねした。
１）ＡからＺぐらいで、いいのですか?　　　　　　Ｚの次はＡＡです。
２）ＡＺぐらいまで?　　　　　　　　　　　　　　　　　ＡＺの次はＢＡです。
３）結局は何人分?　　　　　　　　　　　　　　　　　100人分ぐらいあればいいです。
 
 
どんな式が・・・良いだろうかね、、、
 　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん）

素材提供と、いうことで、、、くまぷーさんに、おまかせ、、、

解答用参考ファイル： 20190409をダウンロード

 ***********************************************************************

解答発表は04/13（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

関数で出来ますか～？ 第50回 何人で遊ぶ? 解答例

書くまでもない問題だった。
 
=MID(B2&2,8,1)
 
解答例の半分ぐらいの文字数。
でも、ここにおいでの皆さんには、、、物足りない
 
つぎのもんだいだって、、、
ごめんなさ・・・
となりそう。
 
まあ、どっちも、、、他の方の問題、、、
そのまんま                （ジョー3さん）

関数で出来ますか～？ 第50回 何人で遊ぶ?

【問】

これは、あるところに出ていた問題です
（簡単なね、、）
 
この記号は、セルB2から・・・ずっと入ってます
遊具を表す記号だそうです。
 
何人で遊ぶ?
最後の数字がその人数だそうです。
 
最後の、数字をC列に（右に）表示してほしいそうです
 
数字の無い所は、、、
２
だそうです　　　　　（ジョー3さん）

1.データの右側の数字が人数を示す。

2.データの右側が数字でない場合、人数は2である。

解答用参考ファイル： 20190403をダウンロード

 ***********************************************************************

解答発表は04/06（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

 

 

第49回 透明人間

じょー3さんの出題です。

内容は解答用参考ファイルを御覧ください。m(__)m

尚、解答用参考ファイルにはマクロが含まれています。

 

解答用参考ファイル： 20181006をダウンロード

sakudaさん提供解答用参考ファイル： 20181006改をダウンロード

答用参考ファイルの拡張子zipをxlsmにしてお使いください。 

 ***********************************************************************

解答の締め切りは10/13（土）の２０：００です。

***********************************************************************

第48回 香水と蠅

昔好きだったことわざに
香油を蠅が臭くする
という諺があります
香油は「かおりあぶら」と読みます
今だと、１瓶100万円の香水、、、というところ

意味
「1匹の死んだ蝿が香油をくさくする」（記憶では）
どんなに立派な行いの方でも1度の恥ずべき行いが
それまでの名声を台無しにするという意味です
わたしは、10回以上・・・あるある、、とほほ、、

 

で、問題  お試し：新ルールを含みます。 
   
100万円の香油に蠅が入ったら、泣きたい気分ですよね   
   
1万円のワイン（コップ）に蠅が入っても、同じ   
では、ルール   
その行に[香],[油],[蠅]　があったら、[泣]、それ以外は空白   
を、表示していただきたい。(青いセル)：(順番はどうでも良いです)   
   
特別追加ルール   （お試し：新ルール）
１） 自信があったら、即、、式を入力をしてよい  
２） いつでも結構、です。  
３） 2問目：=find(・・・）てな感じ  
４） その後他の方が、式を入力  
５）  最初の方は、もう発言権がありません 
６）  その他の方は、どんどん、式を書いていいです 
７）  だが、最初の方には、ハンディ　5.5文字 
８）  5文字差で勝利となるのだ。（囲碁みたい） 
９）  ある意味、1週間待ちはつらいことがあるから 

　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん出題）

 

解答用参考ファイル： 20181001をダウンロード

答用参考ファイルの拡張子zipをxlsxにしてお使いください。 

 ***********************************************************************

解答の締め切りは10/06（土）の２０：００です。

***********************************************************************

第47回 何曜日に生まれましたか？ 解答例

出題者案です

１：３８　最初の案

=IF(COUNT(MODE(MOD(B6:B9,7))),G6,G11)

B6:B8

を

B6:B9

にすることを、

思いつきました

 

私には珍しい・・・回答ありき・・・的な問題でした。

 

詰将棋作成にも、こんなのがあります。

 

 

２：５８　これも最初の案

{=IF(LEN(PRODUCT(MOD(B19:B28,7)+13)/253955520)>4,"×","〇")}

数字の組み合わせで、ダメな場合がありそうな気もしました

きっちりとは、確認してません。

 

みなさんの、回答と重複してなかったら、、回答者ジョー3のも出します。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん）

関数で出来ますか~？ 第47回 何曜日に生まれましたか？

【問1】

B6、B7、B8に３人分の生年月日が表示されます。（F9を押下すると生年月日が変わります）

以下の条件を満たす場合はD6に〇を、満たさない場合は×を表示させてください。

《条件》

土曜生まれがいる、または、同じ曜日に生まれたものがいる。

 

【問2】

B19からB28に10人分の生年月日が表示されます。。（F9を押下すると生年月日が変わります）

以下の1~7の条件を同時に満たす場合はD20に〇を、そうでない場合は×を表示させてください。

《条件》

1. 少なくとも一人、月に生まれたものがいる。
2. 少なくとも一人、火に生まれたものがいる。
3. 少なくとも一人、水に生まれたものがいる。
4. 少なくとも一人、木に生まれたものがいる。
5. 少なくとも一人、金に生まれたものがいる。
6. 少なくとも一人、土に生まれたものがいる。
7. 少なくとも一人、日に生まれたものがいる。

                                                                                 （ジョー3さん出題）

解答用参考ファイル： 20180924_2をダウンロード

答用参考ファイルの拡張子zipをxlsxにしてお使いください。 

 ***********************************************************************

解答発表は09/29（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

 

関数で出来ますか~？ 第46回 ナンバー

＜　問題　＞    
Ｂ３とD３に０００～９９９までの数字が入ります    
B3とD3に同じ数字が何個あるかＦ３に求めて下さい    
最大は３ですが順番も同じなら４として下さい    
この問題は文字数が長くても良いのであれば式を書くまでも無く超簡単    
故に　皆さんのとてつもなく凄い短縮技等を使いより短い式に    
わたしはより短くは超々苦手故傍観者に徹したいな  

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん出題）

解答用参考ファイル： 20180910をダウンロード

答用参考ファイルの拡張子zipをxlsxにしてお使いください。 

 ***********************************************************************

解答発表は09/22（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第45回 巡回セールスマン 解答例

56{=SUM(N(OFFSET(F$4:J$8,CODE(L3:O3)-65,CODE(M3:P3)-65)))}

 

なんだかよくわかりませんが、N()を使わないと合計してくれませんでした。
そしてまた、Nでくくってやるとなぜだか合計を計算してくれました。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　(niさん)

第45回 巡回セールスマン

巡回セールスマン問題

Aから出発して最短経路で全ての町を回りたい。

L列からP列には候補となる経路が書かれています。

Q列にこの経路を通った時の距離を求める式を求めてください。（Q3に式を入れて下にコピー）

D4:E8には、各点の座標(x,y)が書かれています。

F4:J8には、各点間の距離が書かれています。

各経路の距離が求まると、E13:E17にその経路が表示されます。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（niさん）

解答用参考ファイル： 20180522をダウンロード

答用参考ファイルの拡張子zipをxlsxにしてお使いください。 

 ***********************************************************************

解答発表は05/26（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第44回 三角形の形 解答例

出題後全く進展しませんでした。情けない・・・・

正三角形　86
=IF(AND(SIN(INT(MMULT(B3:D3,{60,60,0;-11,1,12;0,-12,-12})/12)/60*PI())^2=3/4),"O","X")
つまるところ、中心角と辺が作る三角形の面積をチェックしてます。

直角三角形　80
=IF(SUM(N(ABS(INT(MMULT(B3:D3,{60,60,0;-11,1,12;0,-12,-12})/12))=30))=1,"O","X")
中心角が180度になる場合が一つあればと言う判定です。

二等辺三角形は結局辺が重なり直線だけになっちゃうケースの排除が上手くできず
136どまりでした
{=IF(OR(MAX(FREQUENCY(ABS(ABS(INT(MMULT(B3:D3,{60,60,0;-11,1,12;0,-12,-12})/12))-30),ROW(1:30)-1)*IF(ROW(1:31)=31,9,1))={2,3}),"O","X")}

　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん）

第43回 心・技・体 解答例

46：　=COUNTIF(OFFSET($A:$A,,$B$1*3+2+ROW(A3)/3),B3)

★基本方針

各選手の心・技・体の得点5,3,1の個数をcountif関数で求める。

1. =Countif(範囲、検索条件）の範囲は可変であるのでOffset関数で範囲を求める。
2. 検索条件はB3を参照すればよい。
3. よって=Countif(offset()、B3）となる。
4. また=Offset(基準、行数、列数)なので
5. =OFFSET($A$3:$A$12,0,$B$1*3+2+ROW(A3)/3)とすればよい。
6. よってまとめれば、=Countif(OFFSET($A$3:$A$12,0,$B$1*3+2+ROW(A3)/3), B3） となり
7. さらに減量すれば・・・
   
   =COUNTIF(OFFSET($A:$A,,$B$1*3+2+ROW(A3)/3),B3)
   
   ・・・となる。(^^ゞ

 

第43回 心・技・体

【問】

審査員1~10が選手1~15の心・技・体の得点（5点、3点、1点）を表に入力した。

B2に選手番号を入力した時、心・技・体の得点（5点、3点、1点）の票数が知りたい。

B4（心-5点）の式をC4,D4、B7~D7、B10~D10にコピーして表を作る時

B4の式はどうなりますか？

 解答用参考ファイルA： 201840300をダウンロード

解答用参考ファイルB： 20180501をダウンロード(5/1追加）

 

答用参考ファイルの拡張子zipをxlsxにしてお使いください。 

 ***********************************************************************

解答発表は05/05（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第40回 時計の針2 解答例

今回の問題、、、出題者なのに面白い式を最後まで書けなかった

{=LOOKUP(OR(ABS(B3*5+INT(C3/12)-C3:D3)=30)+(ABS(C3-D3)=30),{0,1},{"X","O"})}

文字数は多少多めですがおそらく皆さんとは被っていないと思う式を解答案としました
そして式の構成もまた１番分かり易く説明も要らない式と思いましたので

 

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

第39回 時計の針 解答例

今回も、、、、回答・・・の・・・・例があるだけ、、、、

 

最初のは、、、こんなだった気がします

=IF(MAX(MAX(B3+C3/60+D3/3600,C3+D3/60,D3/5)-MEDIAN(B3+C3/60+D3/3600,C3+D3/60,D3/5),MEDIAN(B3+C3/60+D3/3600,C3+D3/60,D3/5)-MIN(B3+C3/60+D3/3600,C3+D3/60,D3/5),MIN(B3+C3/60+D3/3600,C3+D3/60,D3/5)+60-MAX(B3+C3/60+D3/3600,C3+D3/60,D3/5))>30,"x","o")

 

時計の円の中に3点を置いて、、、、

その、それぞれの間隔が（3個のうちひとつ）

 

180度（以上？）あるか、、どうかで判定できる

 

まるは　おー

ばつは　エックスで

書いてるかも、、、

 

これが、、、最初の

手数を（文字数）

考えない思ったこと、そのまんまでした。

 

次にやりたかったことは、、、・・・きっとどなたかがされてるでしょうねーーー

 

ってことで、、、またまた、、、書くかも・・・

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（じょー3さん）

 

--------------------------------------------------------------------------------------------------------------

--------------------------------------------------------------------------------------------------------------

私のはすべて、針を結ぶ線に中心点が乗ったのは囲われていないということで×にしています。

まず、最終形の74ですが次のとおりです。
=IF(MDETERM(N(MOD(TIME(B3,C3,D3)*({4;48;2880}-{4,48,2880}),2)>1)),"○","×")

これは、次の判定法（No4)です。

①各辺の作る三角形が中心を囲んでいない場合、円を半円に分けた場合、3点とも半円の一方に集まる。
②ただし、どこで半円に分けるかが大問題なので、時計を回し、各針が0時を指すようにして、そのいずれかで、3点はが右半分に集まれば×、どの場合も集まらなければ〇と判定する。
これで、できたのが85です。
=IF(AND(MMULT(N(MOD(TIME(B3,C3,D3)*({4;48;2880}-{4,48,2880}),2)>1),{1;1;1})),"○","×")

このMMULT前の配列をなんとなく眺めていたら、×の場合明らかに逆行列が作れないが、〇の場合が逆行列があるような気がした。
それが当たって、MINVERSEとISERRで82
でも、考えて見たら、逆行列ができるかできないかは行列式が0になるかどうかで決まるのでMDETERMで判定できる。
これが一挙に短縮した74です。
これ本当に偶然で、配列の１，０が逆だったらどのケースも逆行列が作れるんで気が付かなかったはず。

参考までに他に考えた判定法を書いておきます。

判定No1
三角形のいずれかの2辺が円内で、中心点を挟む
（VBAはこの方法です）
ワークセルを使えばちゃんと判定できましたが、とても一つの式に纏める気力は起きなかった。
判定No2
三角形の頂点から中心線に引いた直線のいずれかが、円内で他の一辺とクロスする
これも断念

注．両方共、」「円内」ってのが重要
　　また、両方共、辺の直線の式を計算してるため、6:0:0とか0:0:0とかは計算式がエラーになります。

判定No3
これが初めて式にできた方法
①各針の指す点と中心点を結ぶと、円グラフのように、円を三分割する角度が三つできる
②いずれかの角度が180度を超えていたら×、三つ共180度未満なら〇

ただ、この方法は0:0:0に対する処理が必要で短くならず105どまりでした。
=IF(OR(B3:D3)*AND(MOD(MMULT({1,-1},LARGE(MOD(TIME(B3,C3,D3)*{4;48;2880},2),{1,2,3;2,3,1})),2)<1),"○","×")

長々と失礼いたしました。

                                                                                              (y sakudaさん)

 

第39回 時計の針

上の黄色の所（時分秒）がランダムに変わります      
0:00:00 ～ 11:59:59 まで 43200 パターン出現？ 
黄色の時,分、秒の時間になるように図の針の位置を      
調整したときに・・・・・      
針の先端が（赤く点をつけた所）どうなっているかの問題です      
      
赤い点を3つ結んだときに      
その中に時計の中心が      
 あったら、緑のセルに　　〇　を     
 無かったら、緑のセルに　×　を表示してほしい     
      
火～木  関数を何種何個使ったかのみ、    
金  文字数発表　も　ＯＫ    
      
きっといろいろな手があると思います      
その発掘のためにも文字数は金まで控えます      
文字数より手法がより興味深いから・・・特にこの問題      

　　　　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん）

★sakudaさん提供

解答用参考ファイル： 20180321VBA_V3をダウンロード　（3/27更新）

ファイルの拡張子zipをxlsmにしてお使いください。 

 

解答用参考ファイル： 20180321をダウンロード

答用参考ファイルの拡張子zipをxlsxにしてお使いください。 

 ***********************************************************************

解答発表は03/31（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

 

第３８回 ある試験 解答例

    出題者解答例ですが

最初の、やつを探しました
 
合計で１８３でした。
 
真ん中から攻めました
６２
=IF(RANK(LARGE(I$8:I$20,B8),I$8:I$20)>3,"",LARGE(I$8:I$20,B8))
 
左
３３
=IF(D24="","",RANK(D24,I$8:I$20))
 
で右
８８
{=IF(D24="","",INDEX(C$8:C$20,MATCH(LARGE(I$8:I$20+B$8:B$20%,B8),I$8:I$20+B$8:B$20%,)))}
 
その後、少しは短くしましたが、
皆さんの工夫には至りません
・・・ようですので・・・
最初の、何の工夫もないやつを出します。
 
からくちさんの、、140台にまず、、、ショック
で、、続々・・・・
＆
やはり、、、120台もあるんですねーーー
 
って、感じ。

　　　　　　　　　　　　　　　　　　　　（じょー3さん）

第37回 1の連続数は？ 解答例

◆「1の連続数は？」の解答例です
102{=NPV(9,MMULT(SMALL((MID(0&B3&0,ROW(1:20),2)={"10","01"})*ROW(1:20),ROW(1:20)*2-{1,0}),{-1;1}))*10^20}

　　　　　　　　　　　（maronさん）

第37回 1の連続数は？

◆相変わらず、長い式になりました。
◆皆さんの助けを借りて、短い解答になりますように。

　　　　　　　　　　　　　　　　　　　　　　　　　　（maronさん）

解答用参考ファイル： 20180306をダウンロード

答用参考ファイルの拡張子zipをxlsxにしてお使いください。 

 

・sakudaさん提供

解答用参考ファイル： Sofu20180306VBAをダウンロード

ファイルの拡張子zipをxlsmにしてお使いください。 

 ***********************************************************************

解答発表は03/10（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第36回 1~4位は何回でしょうか？ 解答例

--------------------------------------------------------
C10は、
56=SUM(N(MMULT(-(C$5:C$9<$C$5:$F$9),{1;1;1;1})=1-ROW(A1)))
★右と下にコピー

 

◆禁止条件をつける必要が無かったですね。
　（maronさん）
--------------------------------------------------------

第36回 1~4位は何回でしょうか？

◆今回の問題は、からくちさんの「Q&Aで見つけた問題」から、思いついた問題です
◆しかし、簡単なので、禁止条件を追加したいと思います。

◆使用する関数の数には制限はありませんが、使用する関数の頭文字のアルファベットは重複しないこと。
◆例えば、MINとMAXや、IFとINTは共に頭文字のアルファベットが同じで、重複するのでダメです。
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（maronさん）

解答用参考ファイル： 20180227をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。 

 ***********************************************************************

解答発表は03/03（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第35回 Q&Aで見つけた問題 その2 解答例

この問題、、、ズルい問題です
そのズルに気付くか否か

Ｑ＆Ａの質問はこれに似ているのが多い
それに気付くかそれとも質問以上に気遣いしているか、、、
そんな質問をそのまま問題に頂きました
従いましてあくまでこの表のみの式、、、他では使えない
それは式を解釈すれば一目瞭然

「同じ特産品を・・・」と言う問題文なのに
特産品の列を参照していない
静岡県のみ３回・後は各１回なら問題にはならないけど
長崎県が２回使われその為に福井県が使われていない
そこに気が付くと、、、
早く言えば「インチキ・ズル」の解答式
偶にはこう言うお巫山戯も入れないと
余りに真面目一辺倒では、、、
それがわたしのお遊びエクセルなので、、、
と言う事でこの解答案で、、、ごめんなさい

=LOOKUP(,0/(COUNTIF(C:C,F$1:F23)=LEN(E5)-2),F:F)

　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

 

第35回 Q&Aで見つけた問題 その2

【問　題】
表は前回と全く同じものです
前回解答の値が記されています
※今回は産地の中で使われていない
　　道府県が1つあります
※また同じ特産品が２度使われている
　　特産品も１つあります
その道府県をＨ５・H11に出してください
ただし式はＨ5に書いてください
H11はH5の式をコピペしてください。

　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

解答用参考ファイル： 20180220をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。 

 ***********************************************************************

解答発表は02/24（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第34回 Q&Aで見つけた問題 解答例

Ｑ＆Ａに出ていた質問をそのままでは失礼かなと思い
それをヒントに問題を作りました
しかし問題のストックが決して溢れていると言う訳では無いので
どうせならその問題作りも合わせて問題にしてしまおうと言う発想の問題に
お付き合い頂きありがとうございます
それにしても皆様方には易し過ぎましたね
大変失礼致しました
本題であるその２もこの問題同様易しいですが
この問題との違いは多分ですが解答式が幾つかあるのではと期待しています

それにしてもアッと言う間に３２文字とは余りにも皆さん凄過ぎです

=LOOKUP(,-FIND(E$1:E$23,B4),F:F)

今度文字数は全く無視してください
その代わりに他の誰とも被らない式をお願い、、、
こんな問題を考えて見ようかな

　　　　　　　　　　　　　　　　（からくちさん）

第34回 Q&Aで見つけた問題

【問　題】

B列のコメントの中に
E列の特産品が含まれています
その特産品からF列の産地を
C列に表示してください
C4をC23までコピー

簡単過ぎでごめんなさい
またコメントは問題用で
可笑しな日本語ですみません

　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

解答用参考ファイル： 20180213をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。 

 ***********************************************************************

解答発表は02/17（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第33回 時分秒中学入試 解答例

37=INT((C12*60+D12+1)/(C11*60+D11)*2)/2

 

今回の問題、、、学校で算数を教えてる先生、

塾の先生方はどのように教えてるのか、、、

 

という点で興味深く、安易に問題にした。

 

秒は考慮しないほうが解きやすいと思った。

 

1	39	8
9	5	14

 

なら、

545分÷99分・・・５．５

 

1	9	32
7	31	58

 

なら

451÷69・・・６．５

 

 

では、これをエクセルでどうする・・・

 

てことで、最初の答えは

 

３７

=INT((C12*60+D12+1)/(C11*60+D11)*2)/2

 

だが、、、3人の方が・・・

そろって、３２・・・と言われると、、、

参りました。と、言うしかない。

 

timeを（３６）、、、無理やり正解が出るように変形したのもあるが、、

誰からも出なかったら、、、そのうち、、

 

　　　　　　　　　　　　　　　　　　　　　　　　　（ジョー3さん）

第33回 時分秒中学入試

難関中学の受験問題を見ていたら（算数）
時間の問題がありました。げっ・・・
で、問題にした。整数倍なら簡単そうですが　2.5倍、3.5倍何てのもあるようでした。
さすがに、2.8倍、3.2倍・・・なんてのはないようです。
さて、さて、、エクセルなら簡単?・・・でも、短くとなると・・・私も苦手、、

　　　　　　　　　　　　　　　　　　　　　　　　　（じょー3さん）

解答用参考ファイル： 20180206をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。 

 ***********************************************************************

解答発表は02/10（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第32回 一回りⅡ 解答例

自分の問題ながら、出題前から結局何も進みませんでした。
最初に作った奴のダイエット版の90止まりでした＾＾
{=MAX(14-LEN(SUBSTITUTE(REPT(C3&D3&E3&F3&G3&H3&I3,2),REPT(COLUMN(A:J)-1,ROW(1:7)),"",1)))}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん）

第32回 一回りⅡ

①C3~I3に0~9の数字が出ます。

②同じ数字が最大何文字連続しているかL8に答えてください。連続している文字が無ければ１となります。

③ただし、C3とI3は繋がっているものとします。

　つまり、C3が１、I3が１であれば連続文字列と

　して数えます。

④私は2016は持ってませんので、2016の新規関数は使用禁止とします。

⑤一応シートの保護はかけてありますが、事故防止以上の意味はありません。

　　　　　　　　　　　　　　　　（sakudaさん出題）

解答用参考ファイル： 20180131をダウンロード(改訂版）

 

***********************************************************************

解答発表は02/03（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

 

第３１回 ぐるりと連番 PART3

【問　題】
maronさん問題のPART２です
・C3には0～9が表示されます 
・C3を基準にして±1で0～9を 
・C3が偶数ならC3～H8方向が同数に 
・C3が奇数ならC8～H3方向が同数に 
・D3に式を入れC3以外にコピペ 

（からくちさん）

解答用参考ファイル： 20180122をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。 

***********************************************************************

解答発表は01/27（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

 

 

第30回 ぐるりと連番 解答例

◆RAND関数を使った解答案

95=RIGHT(IF(B3=0,IF(A4=0,INT(RAND()*10),A4+1),IF(C4=0,B3+1,IF(ROW()=9,C4+1,IF(B$2=0,"■",B3+9)))))

 

◆NOW関数を使った解答案

91=RIGHT(IF(B3=0,IF(A4=0,NOW()/1%^5,A4+1),IF(C4=0,B3+1,IF(ROW()=9,C4+1,IF(B$2=0,"■",B3+9)))))

 

（maronさん）

第30回 ぐるりと連番

【問】

１）B4に入力した式を、

２）G9まで、右と下にコピーして、

３）周囲を0～9の連番になり、

４）真ん中は ■ になるような、

５）B4の式をお答えください

６）ただし、「F9」を押すたびに、

８）B4の数字が、0～9の数字で変更します

（maronさん）

解答用参考ファイル： 20180116をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。 

***********************************************************************

解答発表は01/20（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************