Excel Maniacs

第29回 一回り 解答例

今回の順不同ってのは私は全然できませんでした。
からくちさんのヒントから多数の方が17ってのに到達したみたいですが、私としては
「17??何にもできないじゃん」
ってのが正直なところです。

数字順も37なんてのは丸で思いつかない。

出題者解答は次のとおりです。
左回り　39
=IF(A$4,IF(B8,21-B8,IF(B5,B5,A4)),B3)+1
右回り　40
=IF($B3,IF(F$4,21-F4,IF(B3,B3,C4)),A4)+1

右回りが長くなったのは、2番目のIFの　F$4の　$　が原因です。
理由はJ5　J6のゴミがちょうどまずいところに在ったせいで、I列以降であれば短くなったってところです。

方法的には循環参照に気を付けながら、前の数字に＋１していっているだけです。

今日はちょっと遅くなると思いますが、皆さんの回答楽しみにしてます。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　（y sakudaさん）

第29回 一回り

【問】B4に入れた式を青く色を付けたセルにコピーして１~16の数字を表示してください。

                                                             (y sakudaさん出題）

解答用参考ファイル： 20180108 V2をダウンロード

※このファイルはxlsにしてありますが、2007以降の拡張子にする場合は、xlsm　にしてください。

***********************************************************************

解答発表は01/13（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第28回 いくつあってますか~？ 解答例

【解答例】56文字

 

{=SUM(N(LEN(C2&C3)=LEN(SUBSTITUTE(C3&C2,ROW(1:9),))+2))}

 

配列数式を使っています。解答例を試すためには中括弧を除いた部分、

=SUM(N(LEN(C2&C3)=LEN(SUBSTITUTE(C3&C2,ROW(1:9),))+2))　を入力して

shift、Ctrl、Enterを同時押ししてください。

 

【解説】

一番重要な部分は･･･

LEN(C2&C3)=LEN(SUBSTITUTE(C3&C2,ROW(1:9),))+2

・・・です。

式の右辺は・・・

LEN(SUBSTITUTE(C3&C2,ROW(1:9),""))+2

・・・と同じです。

 

1）もしも　模範解答に1、　生徒解答に1があればC3&C2には

　1が2個含まれているはずなので・・・

=SUBSTITUTE(C3&C2,1,"")とやれば結果の文字数はC3&C2よりも2少なくなるはずです。

 

従って･･･

LEN(C2&C3)=LEN(SUBSTITUTE(C3&C2,ROW(1:9),))+2　は正答数の分だけTRUEになるはずです。

これをN関数で数値化して、SUM関数で和をだせば正答数が求められます。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（くまぷー）

 

 

 

 

 

新・関数で出来ますか~ 第28回 いくつあってますか~？

　戯れで再開した「新・関数で出来ますか~」も今回で第28回、

皆様のお陰で年を越すことができました。

本年もよろしくお願い申し上げます。m(__)m

　　　　　　　　　　2018年1月2日　くまぷー

 

【問】下記3例の様に「模範解答」欄にはCSV形式で

1から9までの数字が1~9個表示される。そして「生徒解答」欄にも

同様に数字が表示される。

　F9を押下すると「模範解答」欄と「生徒解答」欄が変化するので

それに応じた正答数を求める数式を示して欲しい。

　但し、C2,C3以外の参照は不可とする。

 

解答用参考ファイル： 20180102をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

 

解答用参考ファイル(VBA版　sakudaさん提供）： 20180102VBAをダウンロード

※解答用参考ファイルの拡張子zipをxlsにしてお使いください。

 

***********************************************************************

解答発表は01/06（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

新・関数で出来ますか~ 第27回 解答例

◆出題時考えていた、上から詰めて数字を表示させる解答案です、
89{=TEXT(SMALL(COUNTIF(B:B,ROW($1:15))*99+ROW($1:15),ROW()+MIN(B:B)-3),"[<"&MAX(B:B)&"];")}

 

◆からくちさんのコメントをヒントに、作成した解答案です、
71=IF(OR(ROW()<=MIN(B:B),ROW()>MAX(B:B),COUNTIF(B:B,ROW()-1)),"",ROW()-1)

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（maronさん）

新・関数で出来ますか~ 第27回

【問】

1)B列に1-15と空白がランダムに表示されます。
2)B列の最大値から最小値の間で
3)B列に無い数値を
4)C3の式を下にコピーして
5)表示させる、C3の式を答えてください。

（maronさん出題）

解答用参考ファイル： 20171226をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

解答用参考ファイル(VBA版　sakudaさん提供）： 20171226VBAをダウンロード

※解答用参考ファイルの拡張子zipをxlsmにしてお使いください。

***********************************************************************

解答発表は12/31（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

新・関数で出来ますか~ 第26回 ねいきおおきいね 解答例

24：B3=IF(A3,6-A3,B4+1-B8+B10)
B12まで下にコピーとみぎにコピー
　　　　　　　　　　　　　　（maronさん）

新・関数で出来ますか~ 第26回 ねいきおおきいね

【問】

（１）B3に式を入力して、
（２）右と下にコピーして左の様に
（３）1～5、5～1のように、
（４）表示されるB3の式を、
（５）答えてください

（maronさん出題）

解答用参考ファイル： 20191219をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は12/24（日）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

 

 

新・関数で出来ますか~ 第25回

明仁天皇の生前退位が2019年4月30日と決定し、

次の元号が気になるところですが、それに伴う

Excelの表示形式での和暦の更新が、どのように

進められるのかにも興味をかきたてられるのですが

皆さんはいかがでしょうか？

 

そこで、和暦に因んだ問題を思いつきました、、

 

問題：

B2に式を入れ、その式を下方にコピーするとB2の「明治33年（年号と年）」をはじめとし、

B3は「明治34年」B4は「明治35年」・・・と年号と年のリストが出来るようにしてください。

「平成31年」はB124 位に表示されると思います。

 

解答用の参考ファイルは用意してませんので

各自 暇つぶしに考えてみてください。

 　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（む印さん出題）

***********************************************************************

解答発表は12/17（日）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

新・関数で出来ますか~？ 第24回 3数問題 解答例

金、土、日　と、だいぶ忙しくなりそうですので・・・・
 
回答例、送っておきます
 
１の位、１０の位の加算、、、としましたが、、、
 
なんかねーーー
 
もう９５％同じ所に・・・行ってる感じですね。
 
 
ほとんど、ばればれ、、、、
 
くまぷーさんの、おっしゃるとおり
 
 
３すうの癖が・・・分かれば、、、終わりですからね、、、
 
 
１問：９：２７：=(MAX(N2:N4)-MIN(N2:N4))*99
 
２問：７：７：=D5/1.1
 
３問：５：３２：=MEDIAN(N2:N4)*189+SUM(N2:N4)*11
 
４問：６：１５：=SUM(N2:N4)*222
 
１問目と２問目のおもしろさで、、、
安易に出題決定
３問と、４問は
１，２では簡単すぎだから、ちょっと、おまけ的に付け足し。

　　　　　　　　　　　　　　　　　　　　　(ジョー3さん）

新・関数で出来ますか~？ 第24回 3数問題

1）最大値　マイナス　最小値は？

2）2番目　マイナス　5番目は？

3)3番目プラス　4番目はは？

4)6種類の数値の和は？

　　　　　　　　　　　　　　　　　　　（ジョー3さん出題）

解答用参考ファイル： 20171204をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

解答用参考ファイル（追加　Excel2003以前）： 20171204_xlsをダウンロード

***********************************************************************

解答発表は12/10（日）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

 

【問】3数字の組み合わせで6種類の数字が出来ますね

新・関数で出来ますか~？ 第23回 解答例

 

問１：{=NPV(9,MID(C3,10-ROW(1:9),1)*10^9)}

問３：{=MID(NPV(9,IFERROR(FIND(MID(C3,ROW(1:9),1),13579)*2-1,"")),3,9)}

問２：{=COUNT(FIND(5,MID(C3,ROW(1:9),1)/2))}

 

幾ら間つなぎ問題とは言えこの問題は面白味に欠ける
面白い解答案も全く出ない
本当に申し訳ございませんでした
わたしは出題能力が無い様ですね

　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

新・関数で出来ますか~？ 第23回

問１：数字の並びを反対に

問２：MOD関数禁止で奇数の文字数を

問３：奇数のみ表示

　　　　　　　　　　　　　　　　　　　　　　　　(からくちさん）

解答用参考ファイル： 20171128をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は12/03（日）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

新・関数で出来ますか~？ 第22回 解答例

◆出題時解答案
68{=LOOKUP(10,MATCH(15-ROW(A:A),LEN(SUBSTITUTE(C3,ROW(1:10)-1,)),)-1)}
◆何とか短くした案
61{=RIGHT(MAX(-(1&SUBSTITUTE(C3,ROW(1:10)-1,)&(ROW(1:10)-1))))}

 

◆MODE関数使用
37=MODE(MID(REPT(C3,99),ROW(1:99),1)*1)

 

★今回も出題時よりも、少ない解答ができました。
★みなさんありがとうございました。
　（maronさん）

新・関数で出来ますか~？ 第22回

【問題】

C3に表示されている数の中で
最頻値の数字をC7に出してください
0～9の値です、、、C3の文字数は可変
最頻値が複数の場合、そのどれでもよい
また、最頻値数が1の場合どれでもよい
条　件
mode関数は使用禁止

解答用参考ファイル： 20171121をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は11/26（日）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

 

第21回 エクセルでビンゴ 解答例

◆出題時の解答案
154{=IF(COLUMN()/ROW()=4/5,"Free",LARGE((COUNTIF($B$2:$F2,ROW($1:$75))+COUNTIF($A3:A3,ROW($1:$75))=0)*ROW($1:$75),RANDBETWEEN(1,75-COUNT($B$2:$F2,$A3:A3))))}

 ◆必死に考えた解答案
121{=IF(COUNT($A1:B2)=6,"Free",SMALL(ISNA(RANK(ROW($1:75),($2:2,$A3:A3)))*ROW($1:75),RANDBETWEEN(COUNT($2:2,$A3:A3)+1,75)))}

 ◆皆さんの解答を見せていただくのが、とても楽しみです。

　　　　　　　　　　　　　　　　　　　　　　　　　　（maronさん）

第21回 エクセルでビンゴ

◆真ん中が「Free」のランダムのビンゴカードの作成
◆B3の式を右と下にコピー（数字は1～75）

解答用参考ファイル： 20171113をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は11/19（日）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

新・関数で出来ますか~？ 第20回 解答例

◆出題当初の解答案
94{=SUM(SMALL(ISNUMBER(FIND(ROW(1:9),C3))*ROW(1:9),ROW(1:9))*10^(9-ROW(1:9)+COUNT(FIND(0,C3))))}

 ◆必死に考えた案
82{=MID(NPV(9,IFERROR((FIND(ROW(1:9),C3)>0)*ROW(1:9),"")),3,9)*10^COUNT(FIND(0,C3))}

 ◆皆さんの解答を見せていただくのが、楽しみです。
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（maronさん）

新・関数で出来ますか~？ 第20回

【問】C3に表示されている数字を
小さい順に重複なしでC7に並べてください。
ただし、0がある場合は0は最後に表示してください。

　　　　　　　　　　　　　　　　　　　　（maronさん出題）

解答用参考ファイル： 20171106をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は11/12日）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第19回 将棋道jyo3 その2

	来た時間	帰った時間	練習時間
増田	8.5	14.0	5.5
佐々木	11.5	17.0	5.5
藤井	10.0	16.0	6.0

【問】F９を押すと3人の「来た時間」「帰った時間」「練習時間」が変化します。

下の1から4の条件を判定する数式をD12からD15に入れてください。

	（対局可能時間＝0.5時間単位）	時間
1問	若者が3人揃った時間数
2問	若者が2人揃った時間数
3問	若者が1人だけの時間数
4問	若者が誰もいなかった時間数

 

ルール１    
 揃ったとは、一瞬ではだめ（増田が10時に来て藤井が10時に帰った時は揃ってない）   
ルール２    
 出来た答えを他の問題に利用可（参照）   
ルール３    
 式のコピーでも良い。 

　１コピー 20点 
  ２コピー 60点 ↑*3
  ３コピー 180点 ↑*3

 

解答用参考ファイル： 20171030をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

 

★sakudaさん提供解答用参考ファイル（マクロ入り）： 20171030.V2をダウンロード

※解答用参考ファイルの拡張子zipをxlsmにしてお使いください。

 

***********************************************************************

解答発表は11/05日）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第18回 将棋道jyo3 解答例 第2~4問

3問目ですが、

短くしようと、工夫したつもりが・・・欠陥

 

配列数式は、込み入ってくると分からなくなります。

 

だから、4問目だけ・・・配列使用

1問目：３２：=IF(MAX(D4:D6)<MIN(E:E),"○","×")

2問目：２０：IF(D12=D14,"○","×")

 

ここまで皆同じでしょうね

 

3問目

５１（基本形）

=IF((D4*D5*D6=960)*(E4*E5*E6/MAX(E:E)=120),"○","×")

これを、うまくまとめたら・・・４１・・・だめでした、、

４３，４５，４８，・・・・その他、、、まとめに読み抜けの欠陥品ばかり

4問目

４８

{=IF(SUM(--(E4:E6<TRANSPOSE(D4:D6)))=2,"×","○")}

これだって、工夫すれば、、、少し減ると思ったが、、、

 

3問目で疲れました。

簡単そうで、、、うまくシンプルに出来ず、、疲れました。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（じょー3さん）

新・関数で出来ますか~？ 第18回 将棋道jyo3 解答例

 コピーボーナスは、、、使いません、、、ていうか

使うとかなりオーバー・・・

 

1問目

３２

=IF(MAX(D4:D6)<MIN(E:E),"○","×")

 

皆同じくらいか、、、なーーーコピーボーナスが今回無、、意味ではねーｰｰ

（じょー3さん）

 

 

 

 

新・関数で出来ますか~？ 第18回 将棋道jyo3

【問】F９を押すと3人の「来た時間」「帰った時間」「練習時間」が変化します。

下の1から4の条件を判定する数式をD12からD15に入れてください。

1問	3人そろった時間があった
2問	3人は×で2人だけ揃ったことならあった
3問	3人×、2人×で1人だけのときばかり
4問	途切れることなくいつも誰かいた （↑最初に来た方の時間から最後に帰った方の時間）

ルール１     
 揃ったとは、一瞬ではだめ（増田が10時に来て藤井が10時に帰った時は揃ってない）    
ルール２     
 出来た答えを他の問題に利用可（参照）    
ルール３     
 式のコピーでも良い。その時は1コピーにつき　10文字分減数    
  ｛最大30点（3コピー）＝30文字分減数となるのだ｝   
     
答え合わせルール     
1週目 1問目の答え合わせ（布石）    
2週目 その他の問題の答え合わせ（本戦）    
 （ただし、自分の1問目の答えを変更はだめ）    
1問目の最短は全体の最短でないかも知れない、しかし1問目の他の方の式を使って、

2から4問目を組み立てようとしても、、、後の祭りなのだ。自分の1問目の式はもう変えられないのだ（覆水盆・・・）     
     
     
＊＊＊常連さん以外は・・・1週目不参加で、、、2週目参加も良いことにしましょうね、、     

解答用参考ファイル： 20171016をダウンロード

★sakudaさん提供解答用参考ファイル： 20171016V2をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

★sakudaさん提供解答用参考ファイル（マクロ入り）： 20171016V4をダウンロード(改訂版）

※解答用参考ファイルの拡張子zipをxlsmにしてお使いください。

***********************************************************************

解答発表は10/22日）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

新・関数で出来ますか~？ 第17回 タケヤブヤケタ 解答例

◆皆さんがたどり着いた、13ができないので、

◆解答案をいくつかをお送りします

 

◆めちゃくちゃ素直な式は、25でした。

　=MID(123454321,ROW(A1),1)
◆それを一ひねりしたのが、23。

　=MID(11111^2,ROW(A1),1)

◆枠外を使って、19。

　=IF(B8>0,B4-1,B4+1)
◆それを工夫して、15、14。

　=B4+IF(B8,-1,1)

　=B4-1+(B8=0)*2

◆他の列も使って、14。

　=6-LEFT(G1&B7)

 

◆最短が出来なかったので、解答案の数でカバーしました。

　　　　　　　　　　　　　　　　　　　　　　　　　（maronさん）

新・関数で出来ますか~？ 第17回 タケヤブヤケタ

【問】

１）B3に式を入力して、
２）下にコピーして、左のように
３）1・2・3・4・5・4・3・2・1と
４）表示されるB3の式を、
５）答えてください

　　　　　　　　　　　　　　　　　　　　　　　　（maronさん出題）

解答用参考ファイル： 20171010をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は10/15（日）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

新・関数で出来ますか~？ 第16回 解答例

からくちさんからは、例によってファイルのの形で

解答例を頂きました。細工が施してあるので

お手数ですがダウンロードして確認してください。

20171008をダウンロード

新・関数で出来ますか~？ 第16回

Q＆Aに出ていた質問そのままですが
回答が情けな過ぎたので問題に頂きました。

＜＜　問題　＞＞
B3～D3が同じ値なら「◯」それ以外は「✕」を
ただし空白が1個の時は他の2つが同じなら「◯」
空白が2個以上は「✕」をF3に表示させてください。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん出題）

解答用参考ファイル： 20171003をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は10/08（日）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

 

新・関数で出来ますか~？ 第15回 解答例

青い駒がmaronの駒です。
maronの王は、一段目の1・3・5・7・9筋に移動します
五段にある、黒のあなたの駒で次の一手で王手がかかる駒の数を
L1に入力してください。
もちろんあなたの駒が、一段から三段に入れば、成ることができます。
次の一手で王手がかかる駒のセルが、赤くなります。

《解答案》      

91　{=SUM(N(B7:J7=MID("000角角角桂香角香桂角角角",AC8+9-B2:J2,1)),N(7:7&5:5&3:3={"飛";"飛歩王";"桂歩王";"香歩王"}))}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（maronさん）

******************************************

maronさんから、細工入りのファイルを頂いております。

ダウンロードしてご覧ください。

20171001をダウンロード

 

 

　　　　　　　　　　　　　　　（くまぷー）

新・関数で出来ますか~？ 第14回「羅王」に王手！！ 解答例

【問】青い駒がmaronの駒です。       
五段にある、黒のあなたの駒で次の一手で王手がかかる駒の数を       
L1に入力してください。       
もちろんあなたの駒が、一段から三段に入れば、成ることができます。       
次の一手で王手がかかる駒のセルが、赤くなります。       
       
《解答案》       
78 {=SUM(N(RIGHT(CODE(B7:J7))=MID({785888587;171999171},B2:J2,1)),F7="角",F7="桂")} 

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（maronさん）

******************************************

maronさんから、細工入りのファイルを頂いております。

ダウンロードしてご覧ください。

＞次の一手で王手がかかる駒のセルが、赤くなります。 

20170923をダウンロード

　尚、今回は私のミスでご迷惑をおかけしたことを

お詫びします。m(__)m

　　　　　　　　　　　　　　　（くまぷー）

新・関数で出来ますか~？ 第13回 解答例

からくちさんからは、例によってファイルのの形で

解答例を頂きました。細工が施してあるので

お手数ですがダウンロードして確認してください。

20170916をダウンロード

新・関数で出来ますか~？ 第13回 ダブっているのはなんですか？

【問】　Ｌ８が◯のとき、ダブっている駒は何ですか。

　　　　　　　　（からくちさん出題）

 

解答用参考ファイル： 20170911をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は9/16（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

新・関数で出来ますか~？ 第12回 解答例

からくちさんからは、例によってファイルのの形で

解答例を頂きました。細工が施してあるので

お手数ですがダウンロードして確認してください。

 

20170909をダウンロード

 

 

 

新・関数で出来ますか~？ 第12回 いくつ離れていますか？

【問０】　第11回の式をL8に入れて◯✕を表示して下さい。

【問】L8が〇なら、ダブっている駒の間のマス目はいくでしょうか？（例：B8とJ8なら間は7）

　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん出題）

解答用参考ファイル： 20170905をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は9/09（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

新・関数で出来ますか~？ 第11回 解答例

出題者のジョー3の代打で解答例を提示します。

=IF(PRODUCT(COUNTIF(B8:J8,{"王","金","銀","桂","香","飛","角","歩"})),"〇","×")

70文字です。

 

★考え方

　B8:J8の九つのセルにに8種の将棋の駒が表示されます。

　従って全種類の駒が表示されているとき、COUNTIF関数で返される値は1以上になるはず、つまり0になることはないはずです。また、PRODUCT関数は引数の積を返すので、全種の駒が表示されてないとき（COUNTIF関数で返される値に一つでも0がある時）はPRODUCT関数は0を返します。IF関数の第1引数（条件判定）は0のときFALSEなので上のような式ができます。

 

新・関数で出来ますか~？ 第10回 解答例

　出題者のジョー3さんから解答例が送られてこないので

代打で解答例を提示します。

=CHAR(MODE(CODE(B7:J7)))

24文字です。

 

★考え方

1.　同じ種類の駒を探すことになるので、最頻値を求めるMODE関数が頭に浮かびます。

 

2.将棋の駒は王、金、銀、桂、香、飛、角、歩の8種類ですから、B7~J7の９セルに表示させた場合は

　必ず重複する駒があるのでMODE関数がエラーになる事はありません。

 

3.  ところが、MODE関数は文字列を引数にとることできません。数値のみです。そこでB7~J7の

文字をCODE関数でいったん数値にしてMODE関数で扱えるようにします。

 

4.　3で取り出した数値（文字コード）をCHAR関数で再変換すれば答えが出ます。

 

 

 

新・関数で出来ますか~？ 第10回

【問題】

うちの孫が将棋盤に9個駒を並べました。同じ駒があるのは何ですか？       
２種類以上の場合は、どちらでもいいです。       

解答用参考ファイル： 20170821をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は8/26（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

　尚、状況によっては第11回の問題を8/26（土）の前に出題します。m(__)m

***********************************************************************

 

新・関数で出来ますか~？ 第8回 第9回 解答例

★第8回　「王手飛車」解答例

=IF(OR(AND((INT(AB19/9)-INT(AB20/9))^2=(MOD(AB19,9)-MOD(AB20,9))^2,(INT(AB19/9)-INT(AB20/9))*(INT(AB18/9)-INT(AB20/9))+(MOD(AB19,9)-MOD(AB20,9))*(MOD(AB18,9)-MOD(AB20,9))=0),AND((INT(AB20/9)-INT(AB19/9))^2=(MOD(AB20,9)-MOD(AB19,9))^2,(INT(AB18/9)-INT(AB20/9))*(MOD(AB19,9)-MOD(AB20,9))=(INT(AB19/9)-INT(AB20/9))*(MOD(AB18,9)-MOD(AB20,9)),MOD(AB20,9)<MAX(MOD(AB18,9),MOD(AB19,9)),MOD(AB20,9)>MIN(MOD(AB18,9),MOD(AB19,9)),INT(AB20/9)<MAX(INT(AB18/9),INT(AB19/9)),INT(AB20/9)>MIN(INT(AB18/9),INT(AB19/9)))),"王手飛車！","")　　515

　盤面の駒はAA18：AD98の表、特にAB列の数値により表示されます。

そこでAB列の数値を参照して数式を作ります。例えばAB18の

数値を見れば、王の表示位置がわかります。

 

王の表示列：=MOD(AB18,9)+1　（盤面左からの列数）

王の表示行：=INT(AB18/9)-1　（ワークシートの行数）

 

飛車・角の位置も同様です。

 

飛車の表示列：=MOD(AB19,9)+1　（盤面左からの列数）

飛車の表示行：=INT(AB19/9)-1　（ワークシートの行数）

角の表示列：=MOD(AB20,9)+1　（盤面左からの列数）

角の表示行：=INT(AB20/9)-1　（ワークシートの行数）

 

　王手飛車になるケースを２つに分けて考えます。

（1）　王、飛、角が一直線に並ぶ場合。この場合は角が王と飛に挟まれる場合のみ「王手飛車」です。ただし一直線に並んでも、角の利き筋に王・飛が位置していなければなりません。

　　1.　王、飛、角が一直線に並ぶ条件（共通の１点、　傾きが同じ）

　　　　　(INT(AB18/9)-INT(AB20/9))*(MOD(AB19,9)-MOD(AB20,9))=(INT(AB19/9)-INT(AB20/9))*(MOD(AB18,9)-MOD(AB20,9))

　　2.　角が王と飛に挟まれる条件（下の４式が同時に成立）

　　　　　角の行位置　＜　Max(王の行位置 , 飛の行位置)

　　　　　角の列位置　＜　Max(王の列位置 , 飛の列位置)

　　　　　角の行位置　＞　Min(王の行位置 , 飛の行位置)

　　　　　角の列位置　＞　Min(王の列位置 , 飛の列位置)

      3.  角の利き筋に王・飛が位置する条件

　　　　　(INT(AB20/9)-INT(AB19/9))^2=(MOD(AB20,9)-MOD(AB19,9))^2

　よって・・・

　　　=AND((INT(AB20/9)-INT(AB19/9))^2=(MOD(AB20,9)-MOD(AB19,9))^2,(INT(AB18/9)-INT(AB20/9))*(MOD(AB19,9)-MOD(AB20,9))=(INT(AB19/9)-INT(AB20/9))*(MOD(AB18,9)-MOD(AB20,9)),MOD(AB20,9)<MAX(MOD(AB18,9),MOD(AB19,9)),MOD(AB20,9)>MIN(MOD(AB18,9),MOD(AB19,9)),INT(AB20/9)<MAX(INT(AB18/9),INT(AB19/9)),INT(AB20/9)>MIN(INT(AB18/9),INT(AB19/9)))

(2)  角・王・飛が一直線に並ばない場合。

　　1.　角→王　、角→飛のなす角が直角

　　　　(INT(AB18/9)-INT(AB20/9))*(MOD(AB19,9)-MOD(AB20,9))=(INT(AB19/9)-INT(AB20/9))*(MOD(AB18,9)-MOD(AB20,9))

　　2.　角の利き筋に王・飛が位置する条件

　　　　(INT(AB20/9)-INT(AB19/9))^2=(MOD(AB20,9)-MOD(AB19,9))^2

 

よって「王手飛車！」は(1)　または（2)が成立すればよいので、答えは最初に示した解答例のようになる。　　（くまぷー）

★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★

★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★

★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★★

★第9回　「王手オリジナル」解答例

 

自分を含めて、回答まで行かなかったら、どうしましょ、、
（忙しくて、時間が取れない）
 
と、少し思いましたが、、
 
皆さんから、時間をいただきまして、有難うございました。
 
さて、
 
出題者回答ですが、、、
飛竜部分は
1行目
2行目
3行目
・・・
9行目
 
と切り取って、、、＆でくっつけて
飛王、王飛、竜王、王竜・・・を探して・・・あるかで、決まり
 
角馬部分は
1行目
〇2行目
〇〇3行目
・・・・・・
9行目
 
とずらしてから・・・探しに行くという・・・
 
簡単な作戦、、、
 
だが、これを短縮となると、、、、
 
つかれますーーー・・・技術がない私は、、、、
 
で、、、
 
５５７？
{=IF(COUNT(FIND({"王飛";"飛王";"王竜";"竜王"},I9:Q9&I10:Q10&I11:Q11&I12:Q12&I13:Q13&I14:Q14&I15:Q15&I16:Q16&I17:Q17))
+COUNT(FIND({"王飛","飛王","王竜","竜王"},I9:I17&J9:J17&K9:K17&L9:L17&M9:M17&N9:N17&O9:O17&P9:P17&Q9:Q17))
+COUNT(FIND({"角王";"王角";"馬王";"王馬"},A9:Q9&B10:R10&C11:S11&D12:T12&E13:U13&F14:V14&G15:W15&H16:X16&I17:Y17))
+COUNT(FIND({"角王";"王角";"馬王";"王馬"},I9:Y9&H10:X10&G11:W11&F12:V12&E13:U13&D14:T14&C15:S15&B16:R16&A17:Q17))
+SUM(((I9:Q17="王")*((J8:R16="竜")+(H10:P18="竜")+(H8:P16="竜")+(J10:R18="竜")+(I8:Q16="馬")+(I10:Q18="馬")+(H9:P17="馬")+(J9:R17="馬")))),"王手！","")}
 
ちょっとだけ角をまとめて、
５２４
{=IF(COUNT(FIND({"王飛";"飛王";"王竜";"竜王"},I9:Q9&I10:Q10&I11:Q11&I12:Q12&I13:Q13&I14:Q14&I15:Q15&I16:Q16&I17:Q17))
+COUNT(FIND({"王飛","飛王","王竜","竜王"},I9:I17&J9:J17&K9:K17&L9:L17&M9:M17&N9:N17&O9:O17&P9:P17&Q9:Q17))
+COUNT(FIND({"角王";"王角";"馬王";"王馬"},A9:Q9&B10:R10&C11:S11&D12:T12&E13:U13&F14:V14&G15:W15&H16:X16&I17:Y17
&9&
I9:Y9&H10:X10&G11:W11&F12:V12&E13:U13&D14:T14&C15:S15&B16:R16&A17:Q17))
+SUM(((I9:Q17="王")*((J8:R16="竜")+(H10:P18="竜")+(H8:P16="竜")+(J10:R18="竜")+(I8:Q16="馬")+(I10:Q18="馬")+(H9:P17="馬")+(J9:R17="馬")))),"王手！","")}
 
＋技術でうまくまとめれば、
400台、300台と、思ったが・・・・・わたしには、、、・・・根気と、技術がない・・・・　　　　（ジョー3さん）
 

新・関数で出来ますか~？ 第9回 王手！（オリジナル）

【問題】　王(青色)はjyo3の王。

残りの4枚はあなたの駒。F9を押してください。

５枚の駒の位置が変わります。飛・角・竜・馬が「王手」の位置に

来たら、セルZ9に「王手！」と表示させてください。

　　　　　　　　　　　　　　　　　　　（ジョー3さん出題）

解答用参考ファイル： 20170813をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は　8/19(土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

*******************************************************************

 

★sakudaさんからチエック用のファイルを頂きました。

お使いください。

20170813-1VBA2をダウンロード

新・関数で出来ますか~？ 第6回 第7回 解答例

★考え方

　盤面の駒はAA18：AD98の表、特にAB列の数値により表示されます。

そこでAB列の数値を参照して数式を作ります。例えばAB18の

数値を見れば、王の表示位置がわかります。

 

王の表示列：=MOD(AB18,9)+1　（盤面左からの列数）

王の表示行：=INT(AB18/9)-1　（ワークシートの行数）

 

飛車・角の位置も同様です。

 

飛車1の表示列：=MOD(AB19,9)+1　（盤面左からの列数）

飛車1の表示行：=INT(AB19/9)-1　（ワークシートの行数）

飛車2の表示列：=MOD(AB20,9)+1　（盤面左からの列数）

飛車2の表示行：=INT(AB20/9)-1　（ワークシートの行数）

角1の表示列：=MOD(AB21,9)+1　（盤面左からの列数）

角1の表示行：=INT(AB21/9)-1　（ワークシートの行数）

角2の表示列：=MOD(AB22,9)+1　（盤面左からの列数）

角2の表示行：=INT(22/9)-1　（ワークシートの行数）

 

【第６回の解答例】

王手となるのは・・・

「王」と「飛車1」の列位置が等しい

「王」と「飛車1」の行位置が等しい

「王」と「飛車2」の列位置が等しい

「王」と「飛車2」の行位置が等しい

・・・上の4条件の少なくとも一つが成り立てばよいから・・・

=OR(MOD(AB18,9)+1=MOD(AB19,9)+1, MOD(AB18,9)+1=MOD(AB20,9)+1, INT(AB18/9)-1 =INT(AB19/9)-1,INT(AB18/9)-1=INT(AB20/9)-1)

整理すると

=OR(MOD(AB18,9)=MOD(AB19,9), MOD(AB18,9)=MOD(AB20,9), INT(AB18/9) =INT(AB19/9),INT(AB18/9)=INT(AB20/9))

よって

=IF(OR(MOD(AB18,9)=MOD(AB19,9),MOD(AB18,9)=MOD(AB20,9),INT(AB18/9)=INT(AB19/9),INT(AB18/9)=INT(AB20/9)),"王手！","")

 

【第7回の解答例】

角で王手の場合は、角と王を結ぶ直線と盤面の横線のなす角（θ）が４５度の時である。

すなわちtanθ=±1の時である。

よってtanθ^2= 1

　なんだかんだで整理して・・・(^^ゞ　　　←学生なら減点間違いなし　m(__)m

=IF(OR((MOD(AB18,9)-MOD(AB21,9))^2=(INT(AB18/9)-INT(AB21/9))^2,(MOD(AB18,9)-MOD(AB22,9))^2=(INT(AB18/9)-INT(AB22/9))^2),"王手！","")

 

新・関数で出来ますか~？ 第8回 王手飛車！

【問題】　王・飛車(青色)はくまぷーの駒。

黒い角はあなたの駒。F9を押してください。

３枚の駒の位置が変わります。角が「王手飛車取り」の位置に

来たら、セルZ9に「王手飛車！」と表示させてください。

ただし、下図の場合は飛車取りではあるが王手ではないので除外する。

また下図の場合は王手ではあるが飛車取りではないので除外する。

解答用参考ファイル： 20170811をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は8/12（土）8/14(月）　8/19(土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

*********************************************************************

★sakudaさんからチエック用のファイルを頂きました。

お使いください。

20170811VBAをダウンロード

マクロ入り回答シートの使用法  
  
 １．問題シートコピーボタン 
  ボタンを押すと、ブックの最後に新しい問題シートが追加されます。
  この際、現在のシートをそのままコピーしますので、回答欄の式やその他に入れたゴミもそのままになります
  従って、不要なものは手動で消してください。
  
 2．実行開始ボタン 
  チェックを開始します。
  ①チェック回数はループ回数欄で指定できます。
  ②上限は特にありませんが、空欄のままだと1000とみなします。
  　（画面の更新を殺してありませんので、1000回ですと1分くらいかかります）
  ③「王手飛車で停止」にチェックが入っていると、王手飛車のところでコードの実行を終了します。
  ④「誤判定無視」にチェックが入っていると、誤判定が起こってもそのまま継続します。
  　（チェックがない場合、ダイアローグが出て、続行と終了を選択できます。）
  ⑤チェック対象はZ9セルのみです。またチェックの際何か文字が入っていれば、王手飛車！とみなします。
  　（！が漢字でもアスキーでも良いようにしたためです。　極端な話、X一文字でも王手飛車！入っているとみなします）

 



　　　　　　　　　　　　　　　　　　　

新・関数で出来ますか~？ 第7回 角で王手！

【問題】　王(青色)はjyo3の王。

２枚の角はあなたの駒。F9を押してください。

３枚の駒の位置が変わります。角が「王手」の位置に

来たら、セルZ9に「王手！」と表示させてください。

　　　　　　　　　　　　　　　　　　　（ジョー3さん出題）

解答用参考ファイル： 20170808をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は8/12（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

　尚、状況によっては第8回の問題を8/12（土）の前に出題します。m(__)m

***********************************************************************

 

 

 

新・関数で出来ますか~？ 第6回 飛車で王手！

【問題】　王(青色)はjyo3の王。

２枚の飛車はあなたの駒。F9を押してください。

３枚の駒の位置が変わります。飛車が「王手」の位置に

来たら、セルZ9に「王手！」と表示させてください。

　　　　　　　　　　　　　　　　　　　（ジョー3さん出題）

解答用参考ファイル： 20170806をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

解答発表は8/12（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

　尚、状況によっては第7回の問題を8/12（土）の前に出題します。m(__)m

***********************************************************************

 

新・関数で出来ますか~？ 第5回 解答例

{=IF(SUM((OFFSET(A5:E5,,MATCH("王",C3:K3,)-1)={"角","桂","飛","桂","角"})*1),"王手！","")}
 
最初、まとめたのが、、
偶然９×９のマス目の数　　８１　で、うれしかったです。   （ジョー3さん）

新・関数で出来ますか~？ 第5回 王手！

駒落ち将棋（2枚落ち）
プロ4段藤井　対　アマ2段浄法寺
特殊ルール
藤井4段は王手の時は必ず王手！と言うこと
うっかり言わないと即負けとなります
緑セルから声を出してください
(だいぶ不利な浄法寺は王手ルールの禁じ手でしか勝つチャンスがないのだ）

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（じょー3さん出題）

 /////////////////////////////////////////////////////////////////////

sakudaさんから解答用参考ファイルを頂きました。見やすいです。

みなさん、お使いください。

*******************************************************************

皆さん要らないでしょうけど、今の問題のVBA入りブックです。

相手の王の位置と王手になっている駒に色がつきます。

 

 

 

 

20170730_sakuda をダウンロード

 

 

 

 

 

*****************************************************************

 

/////////////////////////////////////////////////////////////////////////////////////

解答用参考ファイル： 20170730をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

尚、解答発表は8/05（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

新・関数で出来ますか~？ 第4回 解答例

　最大◯◯連勝・連勝ストップは何戦目解答案　何方も正確には正しい式ではありません。
それは確率的には非常に小さい数値ですが
例えば１２５戦全勝等と言う場合38文字では正しい値を返せず43文字となってしまい
お詫び致します。

100％正しい式をと考え40台の文字数を考えて居られた方々には大変失礼致しました。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（からくちさん）

/////////////////////////////////////////////////////////

からくちさんからは解答例をファイルで頂いております。

お手数ですが、ダウンロードしてご確認ください。

からくちさんのファイル： 20170729をダウンロード

※ファイルの拡張子zipをxlsxにしてお使いください。

/////////////////////////////////////////////////////////

新・関数で出来ますか~ 第3回 解答例

朝から、夜まで・・・出かけてるので、、、出題者案・・・
 
最初作ったのはこれです。
３７
=IF(MODE(MOD(C4:C7,7),9,9)=9,"×","〇")
少し短くなる・・・予想で、
 
あとで、回答者として・・・残念、、、
短くならない。

 

/////////////////////////////////////////////////////////

//誰でもわかる良い子の解答例　（ｂｙ　くまぷー）

=IF(ISNA(MODE(MOD(C4:C7,7))),"×","〇")

★考え方

1. 　C4：C7には日付を表すシリアル値が格納されています。　だから同じ曜日であれば、７で割ってやれば余りが同じ値になるはずです。　そこで剰余関数MODでその剰余を求めます。　　=MOD(C4:C7,7)
2. 　次にMODE関数を用いてC4:C7に重複値があるか調べます。（重複値があれば　同じ曜日の誕生日が存在するということです）　MODE関数は本来は最頻値を求めるものなのですが、全て値がバラバラの時は　エラー(NA)になります。　=MODE(MOD(C4:C7,7))
3. ISNA関数は引数がNAならば真、そうでなければ偽になります。=ISNA(MODE(MOD(C4:C7,7)))
4. 上式とIF関数を組み合わせて・・・=IF(ISNA(MODE(MOD(C4:C7,7))),"×","〇")・・・となります。

新・関数で出来ますか~？ 第3回 何曜日に生まれました？

友達４人の生まれた曜日、

同じ曜日に生まれた人がいたら〇を、バラバラなら×を

セルE5に表示させて下さい。　　（じょー3さん出題）

解答用参考ファイル： 20170717をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

尚、解答発表は7/22（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

 

新・関数で出来ますか~ 第2回

祝・藤井4段28連勝 PART2

問　題
C3に表示されている数の中で
最大値をC7に出してください
0～9の値です、、、C3の文字数は可変
条  件
Shift Ctrl Enter で確定は禁止
また次の関数は使用禁止とします
MAX・LARGE・MIN・SMALL
MID・LEFT・RIGHT
INDEX・SUMPRODUCT・MMULT

（からくちさん出題）

解答用参考ファイル： 20170710をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

尚、解答発表は7/15（土）の２０：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

新・関数で出来ますか~ 第1回 祝・藤井4段28連勝

藤井4段28連勝の時作りましたので28連勝記念。

文字数は禁止です。1桁目と2桁目の合計数だけで
また、刺激しあいたいと、思います。
心配なのは、以前に似たのがあったかどうか？
私の案は　　加算値が　　５　と　１０

（じょー3さん出題）

【問題】

 

解答用参考ファイル： 20170629をダウンロード

※解答用参考ファイルの拡張子zipをxlsxにしてお使いください。

***********************************************************************

尚、解答発表は7/8（土）の８：００です。それまでは直接数式を

書き込むこと・ポイントとなる関数名を書き込むことはご遠慮ください。

***********************************************************************

第241回 関数でできますか~？（解答編）

◆だれも見られていないようですが、とりあえず解答案を送ります

　　　　　　　　　　　　　　　　　　　　　　　　（maronさん）

 

130{=MOD(MAX(MID(RAND()&RAND()*10^9,ROW($3:$18),9)*(COUNTIF($B$2:$E2,ROW($1:$16))+COUNTIF($A3:A3,ROW($1:$16))=0)/1%+ROW($1:$16)),20)}

 

***************************************************************************

チェック用のVBSファイルをアップします。

ランダムに1から16の数字がセルB3：E6に重複なしで

表示されるかを10000回チェックします。

 

式を入力したワークシートをアクティブにして

VBSファイルをダブルクリックしてください。

 

チェック用VBSファイル： Checker2016_11_5をダウンロード