関数で出来ますか～？ 第１６問 地震 解答例

なんか、変な問題になってしまいましたね。
普通にやるだけなら簡単なんですけどね。

以下全て式のみ（書式変更なし）
〔minmax系あり〕
３５文字
=IF(MAX(J10:L12),MAX(J10:L12)-1,"")

〔minmax系なし〕
=omakasesimasu(yattenai,dekinakatta,tanosimi)

〔循環なし（若干ずる）〕
（ツール→オプション→反復計算にチェックあり）
１１５文字
式内に「セル番地が書いてない」から
どこのセルでもいいからこの数式をいれて、
ほかにコピー
=IF(ASC(CELL("contents"))>"0",TEXT(CELL("contents")-MAX(ABS(CELL("row")-ROW()),ABS(CELL("col")-COLUMN())),"0;"),"")
循環なし若干ずる版は数式を入力した時点では循環参照となり
ます。震源地に数値を入力した段階で、循環が無くなります。
（下のステータスバーの再計算の表示が無くなりますね）
この若干ずるは有罪かな～？？

〔循環なし（若干ずる）でminmax系なし〕
１６３文字
=IF(ASC(CELL("contents"))>"0",TEXT(CELL("contents")-IF(ABS(CELL("row")-ROW())>ABS(CELL("col")-COLUMN()),ABS(CELL("row")-ROW()),ABS(CELL("col")-COLUMN())),"0;"),"")


〔循環なし（ほぼずる無し）〕
（ツール→オプション→反復計算にチェック無し）
１５２文字
=IF(CELL("address")=CELL("address",K11),"",IF(CELL("contents")<"",TEXT(CELL("contents")-MAX(ABS(CELL("row")-ROW()),ABS(CELL("col")-COLUMN())),"0;"),""))


〔参考～循環なし（若干ずるの没の１つ）〕
=IF(CELL("contents")<"",TEXT(CELL("contents")-MAX(ABS(CELL("row")-ROW()),ABS(CELL("col")-COLUMN())),"0;"),"")


この程度で許してください。。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　（minさん談）

Comments

[投稿情報: くまぷー]

minmaxさんの

＞〔minmax系あり〕
＞３５文字
＞=IF(MAX(J10:L12),MAX(J10:L12)-1,"")

３５文字と同じです。
今回はこれひとつです(^^ゞ

[投稿情報: minmax]

あれ、まだくまぷーさんしかいないのかな。

>３５文字と同じです。
これが、基本ですよね。
問題作った直後はこれしか手持ちが無かった。

[投稿情報: minmax]

そうだ、
循環なし（若干ずる）はもう２文字くらい短くなりますが、今回は文字数はあまり気にしなかったかし、この方が良いと思って縮めなかった。

[投稿情報: くまぷー]

>あれ、まだくまぷーさんしかいないのかな。

sakudaさんは出かけるので
遅くなると言っていました。

[投稿情報: ジョー3]

さて、・・・・・・

どれから行きましょうかねーーーー

関数なし、修正版：＝長くてごめん
=((J10>6)+(K10>6)+(L10>6)+(L11>6)+(L12>6)+(K12>6)+(J12>6)+(J11>6)>0)+((J10>5)+(K10>5)+(L10>5)+(L11>5)+(L12>5)+(K12>5)+(J12>5)+(J11>5)>0)+((J10>4)+(K10>4)+(L10>4)+(L11>4)+(L12>4)+(K12>4)+(J12>4)+(J11>4)>0)+((J10>3)+(K10>3)+(L10>3)+(L11>3)+(L12>3)+(K12>3)+(J12>3)+(J11>3)>0)+((J10>2)+(K10>2)+(L10>2)+(L11>2)+(L12>2)+(K12>2)+(J12>2)+(J11>2)>0)+((J10>1)+(K10>1)+(L10>1)+(L11>1)+(L12>1)+(K12>1)+(J12>1)+(J11>1)>0)-(J10<=0)*(J11<=0)*(J12<=0)*(K10<=0)*(K12<=0)*(L10<=0)*(L11<=0)*(L12<=0)*0.1

[投稿情報: jyo-3]

関数なし・・・・だが、

表示形式で、、苦労したのだ。
条件付書式を使わないってことで・・・・・

それにしても、長くなったなーーー

[投稿情報: くまぷー]

ジョー３さんの・・・・

どういう構成になっているのか
よくわかりませんが、試してみたら
動いた！！

とにかく凄い！！

[投稿情報: くまぷー]

＞どういう構成になっているのか
＞よくわかりませんが

あ、なるほど・・・
なんとなくわかった・・・

[投稿情報: ジョー3]

んで、
・・・・
つぎ、、

1関数：
わざと、不完全なほうを出してみます。

=(COUNTIF(J10:L12,">6")>0)+(COUNTIF(J10:L12,">5")>0)+(COUNTIF(J10:L12,">4")>0)+(COUNTIF(J10:L12,">3")>0)+(COUNTIF(J10:L12,">2")>AD212)+(COUNTIF(J10:L12,">1")>0)

あ、、１かんすうの160文字
だめだこりゃーーーバージョンです。

何が、駄目なのかなーーー

[投稿情報: minmax]

ジョー３さんの１つ目
なかなか、面白いですね。
よく考えてあるなあ。

とりあえず風呂だな。
その後２つ目以降をみます。楽しみにしてます。

[投稿情報: む印]

一風変わった一筆書きで、堪能させて戴きましたd^^

【循環：MINMAX系なし】
＜表示形式なし＞
６６文字
{=CHOOSE(MATCH(,SUMIF(J10:L12,">="&ROW($1:$8)),),"",,1,2,3,4,5,6)}

＜表示形式(0;)使用＞ ４４文字
{MATCH(,SUMIF(J10:L12,">="&ROW($1:$8)),)-2}

【一応非循環】
minmaxさんと同じなんですが･･･
＜書式変更なし＞ 82文字
=TEXT(CELL("contents")-MAX(ABS(ROW()-CELL("row"))
　,ABS(COLUMN()-CELL("col"))),"0;")

＜表示形式（0；）使用＞ 71文字
は上の式からＴＥＸＴ関数を外した
=CELL("contents")-MAX(ABS(ROW()-CELL("row"))
　,ABS(COLUMN()-CELL("col")))

循環、非循環ともにアイデアのバリエーションが他に出てきませんでした、、、

[投稿情報: ジョー3]

あと、、、

配列数式でない、
＆　minmaxなし・・・・・

（皆さん、配列数式が多いから)

=IF(SUM(J10:L12),IF(COUNTIF(J10:L12,">"&K11+1),N(K11)+1,N(K11)),"")

67文字だったかなーーー

まあ、今回は、文字数はいいけど・・・

[投稿情報: ジョー3]

あ、、、
考え方の変わってる点として、

1個づつ（０から）増やしてみました。
・・・・・・・・

でも、なんか、作った後で、、
・・・・・・わからなくなりそうだった。。

[投稿情報: む印]

ジョー３さんの関数なしも６７文字の式もホントにすごいですねぇー

改めて敬意を表しますm(__)m

[投稿情報: ジョー3]

＞ジョー３さんの関数なしも６７文字の式もホントにすごいですねぇー

あ、あ、、、、、

あああああ、、、

あんたにそういわれたら、・・・・

てれるべーーー

[投稿情報: ジョー3]

あれーーーー・・・・

あと、、、

averageをつかった、、、

花火みたいなのが・・・・・

・・・・・・・・
6回ぐらい爆発して収まる。

・・・・・・
あーーーー消してしまったみたいだねーーー

あ、、、きちんと、1個おきになってないから捨てたみたいですーーー

[投稿情報: ジョー3]

ｃｅｌｌ・・・・ですかーーーーー

じつは、、嗜好しました・・・罰・・・×

思考、施行，試行・・・・

試行しましたが・・・
すぐ捨てました。
へーーーーー

すごいこった。

[投稿情報: supermab]

>改めて敬意を表しますm(__)m

ｘ２

[投稿情報: y sakuda]

今帰ってきたところで、皆さんのまだ見てません。
かぶってるかもしれませんが、普通のやつ以外を全部出してから鑑賞します＾＾
非Max、配列数式、書式81
{=SUM(IF(SUMIF(J10:L12,ROW($1:$7)),(RANK(ROW($1:$7),J10:L12)=1)*ROW($1:$7),0))-1}
非Max、配列数式、書式56
{=LEN(SUM(COUNTIF(J10:L12,ROW($1:$7))*10^ROW($1:$7)))-2}
非Max、配列数式76
{=IF(SUM(J10:L12),LEN(SUM(COUNTIF(J10:L12,ROW($1:$7))*10^ROW($1:$7)))-2,"")}
非Max164　単純明快ｗ
=IF(SUMIF(J10:L12,7),6,IF(SUMIF(J10:L12,6),5,IF(SUMIF(J10:L12,5),4,IF(SUMIF(J10:L12,4),3,IF(SUMIF(J10:L12,3),2,IF(SUMIF(J10:L12,2),1,IF(SUMIF(J10:L12,1),0,"")))))))
非Max147
=IF(SUM(J10:L12),LEN(1*(COUNTIF(J10:L12,7)&COUNTIF(J10:L12,6)&COUNTIF(J10:L12,5)&COUNTIF(J10:L12,4)&COUNTIF(J10:L12,3)&COUNTIF(J10:L12,2)&0))-1,"")
非Max書式64
=LEN(SUM(COUNTIF(J10:L12,{1,2,3,4,5,6,7})*10^{1,2,3,4,5,6,7}))-2
非Max８０
=LEN(SUM(COUNTIF(J10:L12,{1,2,3,4,5,6,7})*10^{1,2,3,4,5,6,7}))-2
おまけで最初に作った発想の違う分で
配列数式書式181
{=IF(MAX($K$11:$AA$27)=0,"",MAX($K$11:$AA$27)-MAX(ABS(ROW()-SUM(($K$11:$AA$27=MAX($K$11:$AA$27))*ROW($11:$27))),ABS(COLUMN()-SUM(($K$11:$AA$27=MAX($K$11:$AA$27))*COLUMN($K:$AA)))))}

[投稿情報:]

＞　ｘ２

ん、、、、
これって・・・・再掲↓

＞=IF(SUM(J10:L12),IF(COUNTIF(J10:L12,">"&K11+1),N(K11)+1,N(K11)),"")

これって、あんたごのみでねーのかい。
・・・・・・

[投稿情報: ジョー3]

どど、、、どどど、、、、、って、、、

だれだ、、こりゃーー・・・・

sakuda先生でしたか？

からくち　さんかとおもった。
（度々ーーんと出てきたからであって、
内容ではない)・・・・・・

・・・・・すげーーなーーー

[投稿情報: かず]

＞=IF(MAX(J10:L12),MAX(J10:L12)-1,"")

で、一歩も動けませんでしたｗ

[投稿情報: くまぷー]

sakudaさんもminmaxさん同様
いろいろ出してきましたね～

私はかずさん同様

＞＞=IF(MAX(J10:L12),MAX(J10:L12)-1,"")

＞で、一歩も動けませんでしたｗ　×２

[投稿情報: y sakuda]

今、皆さんの見てましたが、さっぱり理解できてないです・・・・・
非循環のは全く想像の埒外・・・・・
ジョー３の関数なしも、67もカラクリが良く分からない・・・・・
む印さんの配列数式のはやられたって感じですねーー。
私は少なく共Row一つではダメだと思い込んでました。
その段階でダイエット勝負は負けですねーー
そう言えば何方も15は出してないのかな？
35と同じだから出してもしょうがないですけど・・・・

[投稿情報: からくち]

今回は違反だらけですので
あくまで参考出品
（文字数・書式・条件付き書式・minmax系などなど無視）

みなさんと被らなそうな式だけを

基本形？？？
自セルの周りは８セル
そうです、、ベスト８が出揃ったのです
後はトーナメントで優勝セルを・・・
=IF(IF(IF(J10>K10,J10,K10)>IF(L10>L11,L10,L11),IF(J10>K10,J10,K10),
IF(L10>L11,L10,L11))>IF(IF(L12>K12,L12,K12)>IF(J12>J11,J12,J11),
IF(L12>K12,L12,K12),IF(J12>J11,J12,J11)),IF(IF(J10>K10,J10,K10)>
IF(L10>L11,L10,L11),IF(J10>K10,J10,K10),IF(L10>L11,L10,L11)),
IF(IF(L12>K12,L12,K12)>IF(J12>J11,J12,J11),IF(L12>K12,L12,K12),
IF(J12>J11,J12,J11)))-1

文字数を短くとするなら間違っても出ない考え方
{=COUNT(FIND(REPT(0,ROW($1:$24)),REPT(0,J38+16)&1&REPT(0,K38+16)&1&
REPT(0,L38+16)&1&REPT(0,L39+16)&1&REPT(0,L40+16)&1&REPT(0,K40+16)&1&
REPT(0,J40+16)&1&REPT(0,J39+16)))-17}

１つくらいは短めを
{=MATCH(1,0/COUNTIF(J10:L12,ROW($1:$8)-1))-2}

比較的多用するＬＯＯＫＵＰで
=LOOKUP(9,FIND(ROW($1:$24)17,N(AM10)&N(AN10)&N(AO10)&N(AO11)
&N(AO12)&N(AN12)&N(AM12)&N(AM11)),ROW($1:$24)-18)

=LOOKUP(1,0/COUNTIF(J10:L12,">"&(ROW($1:$23)-17)),(ROW($1:$23)-17))

***イチャモン式***
セルの書式 ： [>0.2]0;
条件付き書式 ：
条件１・・数式が・・=K11=0・・パターンで色なし
条件２・・数式が・・=K11=MAX($K$11:$AA$27)・・パターンで赤・罫線で周りを囲む

=IF(LEN(RAND())<16,MIN(J10:L12)-1,MAX(K10+K12,J11+L11)/(RAND()*0.1+2))

任意のセルに震度を
その後「元に戻す」ボタンを

*これが入試問題なら浪人*

[投稿情報: ジョー3]

あ、、すまん、、のんで、

ごやってたら、、、

ネテしまったり・・・・

おやすみーーーーー

[投稿情報: minmax]

いっぱい出てきたから分けて感想・・

ジョー３さん
＞１かんすうの160文字
＞何が、駄目なのかなーーー
０がだめ？

む印さん
＞=CHOOSE(MATCH(,SUMIF(O18:Q20,"＞="&ROW($1:$8)),),"",,1,2,3,4,5,6)
参った。こんなの思いつかない。。
＞=TEXT(CELL("contents")-MAX(ABS(ROW()-CELL("row")),ABS(COLUMN()-CELL("col"))),"0;")
考え方一緒でしたね。うれしいです。
でも、私の環境では式を入れたときに０となったり、エラーになったりする？？

＞ジョー３さんの関数なしも６７文字の式もホントにすごいですねぇー
ほんとだー

[投稿情報: y sakuda]

からくちさんのも今見始めましたが、よー分からんです。
こうやって見ると、σ（＾＾）が常識人だってこといやと言うほど思い知る＾＾；

[投稿情報: minmax]

y sakudaさん
RANKは禁止すべきか迷った関数ですね、でも、使えないだろうと思っていました。
LENと＾を使った式いいですね。
＞配列数式書式181
じっくりみないとよくわからん？？

からくちさんのはこれからみます。

[投稿情報: y sakuda]

＞配列数式書式181
最初37のが思いつかず、全体の最大値の行番号と列番号を取得し、そこから離れる毎に１づつ引いて行くというとんでもない代物ですｗ

[投稿情報: minmax]

からくちさん
＞後はトーナメントで優勝セルを・・・
目が痛くなりそうでした。

で、中間の式は後でじっくりみるとして、
イチャモン式を先に見ます
おー結構面白い動き、、式の中身はちょっと飲まない時でないと解読出来なそう。

[投稿情報: minmax]

ちょっと数式みるのに疲れちゃったから、、、
休憩。。。
今回の問題、、minmax系なしは、やんなかったけど、結構満足。
なにがって、みなさんが色々式を考えてくれたこと。
それと、自分的には、
ツール→オプション→反復計算にチェック無し
で自分のルールに沿った解答が出来たこと。（結構お気に入り）
なんと言っても、くまぷーさんがこの場所を提供してくれているからこそですが、、

[投稿情報: y sakuda]

>今回の問題、、minmax系なしは、
Min、Max（Aを含む）だけの禁止なら兎も角、あんなに全部禁止されちゃったら不可能としか思えなかったです＾＾；
でも、あれやこれや試して、フラストレーションは溜まりましたが結構面白かったです。
私の場合、初日になにかアイデアがないとそれっきりになる傾向があるのですが、今回は二日なにもできず、それから色々思いついたと言う非常に珍しいケースでしたね。

[投稿情報: minmax]

＞今回は二日なにもできず、・・・
そうでしたよね。
そこから突っ走りましたよね。
私は、頑張ってやればminmax系なしも出来たのかもしれませんが、何となく気力が出なかった。
そして、途中から自分で答えを出さない方が楽しいんじゃないかとも思うくらいだった。

[投稿情報: y sakuda]

しかし・・・・・
これほど難解な回答のオンパレードってのも初めてじゃないですかね？
あれやこれやいじくり回してポイントは分かってるはずなのに、一見しただけじゃカラクリが理解できないｗ
確かに循環参照を使い慣れているという前提では、max使用の35は初心者向けと言えなくもないですが。
しかし、循環参照使い慣れてる初心者なんているんかしらｗ

[投稿情報: minmax]

＞しかし、循環参照使い慣れてる初心者なんているんかしらｗ
確かにそうなんですが、、
IFとMAXというエクセルについては初歩的な関数を知っていれば、
IF（MAX(…),MAX(…)-1…)
という式を組みたくなりますよね。
その際、「数式を計算できません」みたいなメッセージがあがって、ヘルプをみますよね。
で、ヘルプをみれば、
[ツール] メニューの [オプション] をクリックし、[計算方法] タブをクリックします。
[反復計算] チェック ボックスをオンにします。
って書いてあるから、初めての方でも分かると思った次第です。。

[投稿情報: minmax]

訂正、思いつく式は、このような式かな
IF（MAX(…)＞0,MAX(…)-1,"")

[投稿情報: minmax]

ところで、kirさんの登場は明日かなあ～
では、お休みなさい。

[投稿情報: くまぷー]

お早うございます。

＞これほど難解な回答のオンパレードってのも初めてじゃないですかね？

確かにそうですね。
私のレベルでは、見るだけで体力を
消耗してしまう式のオンパレードです　(^^ゞ

それはそれとしてイチャモン式は
面白い動きですね。中身はよくわからんけど・・・(^^ゞ

[投稿情報: ジョー3]

風邪がちょっと、・・・・
咳が苦しい・・・・
で、皆さんの式をじっくりとは見てません

＞全体の最大値の行番号と列番号を取得し、そこから離れる毎に１づつ引いて行くという・・・・・・

私もそれを最初にやりかけました。
＆挫折しました

あーーーー
からくちさん　rand　面白いーーー
rand・・・やりかけて挫折
トーナメント・・・・
遊び心・・・いっぱーつ
・・・・また、ねる・・・・

[投稿情報: supermab]

おはようございまーす。

お気に入りの
イチャモン式です

=(SUM(J10:L12)-K11)/8

今回の皆さんの関数・・・
難解なものが多いですね。

おつむの弱い私には
ちっとこたえます　＾＾；

[投稿情報: kir]

>ところで、kirさんの登場は明日かなあ～
>2009年5月 3日 (日) 午前 12時10分
３日の明日・・・あれ？今日は４日・・・？
目が覚めました。おはようございます。

締め切り後に作ってますのでアレですが
32：{=TEXT(MAX((0&J10:L12)-1),"0;")}
36：{=TEXT(LARGE((0&J10:L12)-1,1),"0;")}

[投稿情報: y sakuda]

なるほど、kirさんのようにTextを使えば、式だけで35を切れますねーー
気が付かなかったな^^;

[投稿情報:]

>今回の皆さんの関数・・・難解なものが多いですね。

＞これほど難解な回答のオンパレードってのも初めてじゃないですかね？

>確かにそうですね。
>私のレベルでは、見るだけで体力を
消耗してしまう式のオンパレードです　(^^ゞ

ほんとにそうですねーーー
と、私ジョー3も、そう思います。
でも、・・・・
わたしの、67文字は、単純でしょ！！
＞=IF(SUM(J10:L12),IF(COUNTIF(J10:L12,">"&K11+1),N(K11)+1,N(K11)),"")

の、ここ、、
IF(COUNTIF(J10:L12,">"&K11+1),N(K11)+1,N(K11)),"")
１）私はｋ１１にいる（わたしは最初りんご持っていない）
２）私の周りの方を見回して何個りんご持っている？
３）見回したとき2個以上りんご多いなら(私よりどなたかが）
４）私もりんご1個頂く
次:１）～４）を繰り返す
５）最終的に私よりりんごを、1個だけ多く
持っている
そんな場面になる。
で、結局・・・・
一番多いところから、1個おきになる。

でもねーーーー
みんな、自分のは単純で、
考えなかった手法に出くわすと
難しくみえるってことかなーーー

[投稿情報: からくち]

この問題の面白さを何処に感じるか、、、
わたしは先にも書きましたように
数値をどんな方法で減らしていくか・・・
と思いました

Q&Aの質問でよくこんな場面を見かけます
質問者：１０以下なら・・・１０以上なら・・・
回答者：１０はどっちですか

回答者なら誰でもが分かりきっている事です
もちろん質問者さんも分かっている事と思います

">=" と ">" では違いがあると言う事を

でも不思議とこれが式に応用されない

＞=LOOKUP(1,0/COUNTIF(J10:L12,">"&(ROW($1:$23)-17)),(ROW($1:$23)-17))
(ROW($1:$23)-17) と (ROW($1:$23)-17)
難しく考えることは無い
双方まったく同じでいい
まことに単純

[投稿情報: minmax]

>自分のは単純で
わたしも結果的にＣＥＬＬ(特に核の部分)が一番単純だと思っている。

[投稿情報: y sakuda]

>考えなかった手法に出くわすと難しくみえるってことかなーーー
それはそうなんですが、今までのは大体見れば、「あっ！なるほど」と言うのが多かったわけですが、今回のはそうは行かないみたいですね＾＾;

[投稿情報: ジョー3]

＞まことに単純
（ドキッ)ジョー3の心
そういわれてもねーーー
・・・・・
じっくり見ないとわからないのが多い
じょー・・・・・・・

[投稿情報:]

＞わたしも結果的にＣＥＬＬ(特に核の部分)が一番単純だと思っている。
ギョッ　２・・・・・
CELL　ほとんど、使ったことないシーーー

[投稿情報: ジョー3]

ジョー3↑

＞今回のはそうは行かないみたいですね＾＾;
や、やっとお仲間ーーー・・・・

[投稿情報: む印]

今回のジョー３さんの式にはどれも唸りました！
特に↓これ
＞=IF(SUM(J10:L12),IF(COUNTIF(J10:L12,">"&K11+1),N(K11)+1,N(K11)),"")
（もう少し短縮するなら・・・＞N(K11)+1　→　K11+1　で３文字稼げますが・・・）

何れにせよ、循環を利用する思考として、とても勉強になりました。m(__)m

[投稿情報: ジョー3]

＞もう少し短縮するなら・・・
うっ・・・・
N(K11)),"")
につけて、
何気なく、ついでにつけてた。
おはじかしい。

さて、では皆さんの式を・・・
きちんと見てみます。

・・・・・・・

[投稿情報:]

minmaxさん
＞　=IF(MAX(J10:L12),MAX(J10:L12)-1,"")
まあ、みんなここに落ち着いたようですけど
最初：ジョー3
=IF(MAX(J10:L12)=0,"",MAX(J10:L12)-1)
2文字多かった。でも、、、
kir　さん、、短縮は・・・あなたにかなわんかった、今回も・・・
＞：{=TEXT(MAX((0&J10:L12)-1),"0;")}
へーーーへーーー・・・・・

[投稿情報: ジョー3]

＞　　=LOOKUP(1,0/COUNTIF(J10:L12,">"&(ROW($1:$23)-17)),(ROW($1:$23)-17))
私にとって、lookup関数のこのような使い方は神秘的
見たときはわかったような気がするが、
適した場所で使えるようにひらめかない。
・・・・
１）ぱっと見、なんで0を割るだろう・・・・
２）０/０だけ、答えが１ね、
３）で答えが、０，０，０，１，１，１，０となると
４）３番目の１が該当となるのね、
lookupのこのような使い方は、
からくちさんが、本家なんですか、
それとも、昔から使われてるんですか？
＝結論：私にとって使いこなすのは難しい

[投稿情報: ジョー３]

＞=IF(CELL("address")=CELL("address",K11),"",IF(CELL("contents")<"",TEXT(CELL("contents")-MAX(ABS(CELL("row")-ROW()),ABS(CELL("col")-COLUMN())),"0;"),""))
へーーー、、ようやくわかりました。
でも、
CELL("address")
が、
何を意味するか正確に知らなかった。
たとえば、C3で　
CELL("address")　ｊなら、$C$3
C5に移動してｆ２（ファンクション)→エンターで、$C$5
・・・・こういうことがわかってなかった。
第一　CELL　ってほとんど使ってない。
皆さんの中では、常識なのかなーーー

[投稿情報: ジョー3]

＞　{=CHOOSE(MATCH(,SUMIF(J10:L12,">="&ROW($1:$8)),),"",,1,2,3,4,5,6)}
これだって、強敵だ。
MATCHの動きが・・・へーーーだった。
で、実験
{=MATCH(0,ROW(1:9)-4,0)}
うひゃーーー
ここで、皆さんの技を見てると、
頭が、変になりそうだねーーー

これらを考えると、
ジョー3は、特殊な使用してないから、
単純だよねーー

あーーーちかれた。

[投稿情報:]

sakudaさんも、すごいですねーーー
たくさん作られて、
で、

=LEN(SUM(COUNTIF(J10:L12,{1,2,3,4,5,6,7})*10^{1,2,3,4,5,6,7}))-2
あの、3方の後で見たら、わかりやすかった。
あーー良かった。
LENと　＾　の　ユニークさ・・・・

[投稿情報: y sakuda]

>あの、3方の後で見たら、わかりやすかった。
でしょ＾＾
私も頭のなか単純ですからｗ

>MATCHの動きが・・・へーーーだった。
私もこれ、？でした。
と言うより、中のSumIfで合計している意図がしばらく分からなかったです＾＾；

[投稿情報: ジョー3]

あはは、、
***イチャモン式***
余震が面白かった、

元に戻すボタンで、、
余震の起こり具合がいいなーーー
大地震の後は、中地震、小自身・・・
そのうち、微地震・・・・・

からくち　さんの式からはゆとりが感じられますねーー・・・

私は解くのが精一杯でした。

[投稿情報: minmax]

その後、いろいろ、考えましたが、やっばり完全循環無しは出来ないようですね。
変な提言をしてしまいましたねm(__)m

ジョー３さん
風邪の割に元気で解析してますね。良かった。
＞第一　CELL　ってほとんど使ってない。
普通は使わないですね。
私も実務では１、２回しか使ったこと無いです。

[投稿情報: からくち]

＞１）ぱっと見、なんで0を割るだろう・・・・
１でも２でもいいのですが
０が１番スッキリ？ 分かり易い？

＞２）０/０だけ、答えが１ね、
いや エラーです
その エラー と ０ の２種類を作っているのです

＞３）で答えが、０，０，０，１，１，１，０となると
エラー・エラー・エラー・０・０・０・エラー
になります

＞４）３番目の１が該当となるのね、
いや 従いまして６番目の１
つまり６番目の０を返します

＞からくちさんが、本家なんですか、
結構色々な式（考え方）を出して来ましたが
自身で考えたとは言え
それが本家か否かは分かりません
ただ広めたのはわたしかも知れません

＞＝結論：私にとって使いこなすのは難しい
理屈さえ分かってしまえば簡単・便利

=LOOKUP(10^17,A:A)
時に良く見るこれの応用です
検査範囲の数値より検査値が大きい場合
検査範囲の最後の数値を返します

その時エラーは無視します
この部分の応用です

=MATCH(1,0/FREQUENCY((J10:L12),{0,1,2,3,4,5,6}))-2
これもまた同様です

MATCH関数も同様の返し方をします
エラーを無視するところまで

[投稿情報: ジョー3]

＞＞２）０/０だけ、答えが１ね、
＞いや エラーです
あ、、お恥ずかしいミスでした。
セルで＝０/０で分かることなのにね、
わたしと、他のここにおいでの初心者
に役立つ解説ありがとうございました。

[投稿情報: y sakuda]

さて、次はなんだろ？
しばらく前、くまぷーさんが今後のスケジュール書いてらっしゃいましたが・・・・
忘れた＾＾；

[投稿情報: くまぷー]

>さて、次はなんだろ？

ふふふ・・・
次は誰あろう？
そう、あのお方です・・・

sakudaさんで～す！！　(^O^)

[投稿情報: ジョー3]

>sakudaさんで～す！！　(^O^)
なんだろう・・・
この前は素数
・・・
またなんかの数だったりして・・・・

[投稿情報: y sakuda]

あらっ、私のでしたか・・・・・
あれ、埋草みたいなもんで、しかも私自身あまり良い答えをもってませんから、出題者解答だすのが恥ずかしくなるかも。
大体自分のはいつも置いてきぼりになる傾向もあるしwww

[投稿情報: y sakuda]

>またなんかの数だったりして・・・・
今度はちがうんです。
「簡単なことだと思うのですが・・・・」と掲示板に良くある初心者の質問風に書いてみましたwww

[投稿情報: minmax]

全く関係ないことだけど
2/0=あてはまる数値がないからエラー
0/0=答えが1つじゃないからエラー

0/0=2…間違いじゃない
0/0=1…間違いじゃない
・・・ように見えます
0=2*0
0=1*0
0/2=0
0/1=0
ですしね。
ということで計算順を間違えるとエラーになる？

0^0=1