関数で出来ますか～？ 第２０問 何個あるでしょう？ 解答例

  今回,途中ＰＣトラブルで余りレス入れられずすいませんでした、、
からくちさんやminmaxさんのお陰で、皆さんなんとか一週間
お楽しみ頂けたみたいで助かりました(^^ゞ

一応、初期段階で私が用意していた解答だけ提示します。

■OFFSET使用
=COUNTIF(OFFSET(A4:C4,,MATCH(C9,B3:V3,)),F9)

■OFFSETなし
{=SUM(N(COLUMN(B:V)-MOD(COLUMN(B:V)-2,3)&B4:V4=MATCH(C9,3:3,)&F9))}



--
む印

Comments

[投稿情報: くまぷー]

遅れてすみません。

・・・とりあえず

こんなのしかできませんでした(^^ゞ

=COUNTIF(INDIRECT(CHAR(MATCH(C9,B3:V3,0)+65)&"4:"&CHAR(MATCH(C9,B3:V3,0)+67)&4),F9)

[投稿情報: y sakuda]

今回はからくちさんの掌からでられなかったみたいです。
Offset使用は皆さん同じみたいだから置いておいて、

Offset不使用
53
{=SUM(((COLUMN(A:U)-MATCH(C9,3:3,))^2<2)*(B4:V4=F9))}
素朴な78
=COUNTIF(4:4 INDIRECT(CHAR(64+MATCH(C9,3:3,))&":"&CHAR(66+MATCH(C9,3:3,))),F9)
これも素朴な73
=COUNTIF(4:4 CHOOSE((MATCH(C9,3:3,)+1)/3,B:D,E:G,H:J,K:M,N:P,Q:S,T:V),F9)

Offset、Match、Countifすべて不使用
66
{=SUM(((COLUMN(A:U)-SUM((B3:V3=C9)*COLUMN(B:V)))^2<2)*(B4:V4=F9))}
69
{=SUM((FLOOR(COLUMN(C:W),3)=SUM((B3:V3=C9)*COLUMN(C:W)))*(B4:V4=F9))}
Column⇒Rowに変えたけど、結局Nが必要になって字数が多くなった
70
{=SUM((FLOOR(COLUMN(C:W),3)=MMULT(N(B3:V3=C9),ROW(3:23)))*(B4:V4=F9))}

で、なぜか動かない65
{=SUM((INDIRECT(CHAR(63+FLOOR(COLUMN(C:W),3))&3)=C9)*(B4:V4=F9))}
F9で確認すると　Indirectで正しい配列が得られているのですが、
Indirect(　　）=C9　で生成される配列はすべて#Value　になってしまい動きません＾＾；

[投稿情報: minmax]

みなさんの解答は後でゆっくりみるとして、、、

からくちさんなどには想定の範囲かと思いますが、、

OFFSET系（ほかの４３はほかの方にお任せするとして）
43:=COUNTIF(OFFSET(値:D4,,MATCH(C9,3:3,)-2),F9)

SUMIF系（決して良い式では無いけど、これが一番好き）
66:=(SUMIF(3:3,C9,A4)=F9)+(SUMIF(3:3,C9,B4)=F9)+(SUMIF(3:3,C9,C4)=F9)
65:=SUM(SUMIF(3:3,C9,A4)=F9,SUMIF(3:3,C9,B4)=F9,SUMIF(3:3,C9,C4)=F9)

SUM系
53:{=SUM((B3:T3=C9)*((B4:T4=F9)+(C4:U4=F9)+(D4:V4=F9)))}
52:{=SUM((値:T3=C9)*((B4:T7=F9)+(C4:U7=F9)+(D4:V7=F9)))}

INDIRECT系
68:=COUNTIF(INDIRECT("R4C"&MATCH(C9,3:3,)&":R4C"&MATCH(C9,3:3,)+2,),F9)

INDEX系
68:=COUNTIF(INDEX(4:4,,MATCH(C9,3:3,)):INDEX(4:4,,MATCH(C9,3:3,)+2),F9)
67:=SUM(N(INDEX(4:4,,MATCH(C9,3:3,)):INDEX(4:4,,MATCH(C9,3:3,)+2)=F9))
69:=SUMIF(INDEX(4:4,,MATCH(C9,3:3,)):INDEX(4:4,,MATCH(C9,3:3,)+2),F9)/F9
84:=COUNTIF(INDEX((B4:D4,E4:G4,H4:J4,K4:M4,N4:P4,Q4:S4,T4:V4),,,MATCH(C9,3:3,)/3+1),F9)

SUBSTITUTE系
59:{=3-SUM((B3:T3=C9)*LEN(SUBSTITUTE(B4:T4&C4:U4&D4:V4,F9,)))}

[投稿情報: kir]

微妙なバリエーションも含めて投稿。
44：=COUNTIF(OFFSET(A4,,MATCH(C9,3:3,)-1,,3),F9)
44：=COUNTIF(OFFSET(A4:C4,,MATCH(C9,3:3,)-1),F9)
44：=COUNTIF(OFFSET(A:C,,MATCH(C9,3:3,)-1,4),F9)
53：{=SUM((MATCH(C9,3:3,)+{0;1;2}=COLUMN(3:3))*(4:4=F9))}
53：{=SUM(IF(B3:V3=C9,(B4:V4=F9)+(C4:W4=F9)+(D4:X4=F9)))}
53：{=SUM((B3:V3=C9)*((B4:V4=F9)+(C4:W4=F9)+(D4:X4=F9)))}
56：{=SUM(N(B3:V3&CHOOSE({1;2;3},B4:V4,C4:W4,D4:X4)=C9&F9))}
57：{=SUM((B3:V3=C9)*(CHOOSE({1;2;3},B4:V4,C4:W4,D4:X4)=F9))}
61：{=MAX(IF(B3:V3=C9,3-LEN(SUBSTITUTE(B4:V4&C4:W4&D4:X4,F9,))))}
67：{=SUM(N(TEXT(COLUMN(C:W)/3+FIND(B3,"月火水木金土日"),"aaa")&B4:V4=C9&F9))}

[投稿情報: y sakuda]

くまぷーさんのは私の78と殆ど同じですねーー
む印さんの非Offsetは
{=SUM(N(COLUMN(B:V)-MOD(COLUMN(C:W),3)&B4:V4=MATCH(C9,3:3,)&F9))}
で65になりますね。
こういう発想はしなかったです。

今minmaxさんの写して眺めてましたが、分かるよう分からないような・・・・・
53も私のとは全く違ってたし、全体に発想が全然違いますね。
A6まで使ってるし（良く分からないｗ）
投稿しようとしたらkirさんのがどっとでてる。なんか消化不良起こしそうｗ

[投稿情報: y sakuda]

そう言えばminmaxさんの43私のとちょっと違う
=COUNTIF(OFFSET(B4,,MATCH(C9,3:3,),,-3),F9)

[投稿情報:]

>そう言えばminmaxさんの43私のとちょっと違う
・・・・
わたしのも、、－３の型だった。

[投稿情報: ジョー３]

あはは・・・↑ジョー

[投稿情報: kir]

B6セルの乱数を使う手もあったんですね・・・
51：={SUM(N(TEXT(COLUMN(F:Z)/3+値,"aaa")&B4:V4=C9&F9))}

[投稿情報: ジョー３]

値・・・・って、１文字なのね、・・・
・・・・

みなさん、、いろいろ・・・・

[投稿情報: y sakuda]

とりあえずminmaxさんのざっと見ましたが・・・・
こうやって見ると私のは発想が貧困というか、関数の使い方知らないというか、平凡ですねーー

[投稿情報: かず]

あ～っ、高さと幅を省略できたんですね！
それに気付かず、４５文字…
=COUNTIF(OFFSET(A4,,MATCH(C9,B3:V3,0),,3),F9)

Offset無しでは、考え付きませんでした。

[投稿情報: kir]

>51：
51は「B6」の時でした。「値」に変えて50だったorz

名前定義の仕様は反則だったから、ラベルはグレーゾーン？
41：=COUNTIF(OFFSET(A4,,MATCH(C9,曜日,),,3),F9)

[投稿情報: minmax]

風呂からあがって、、、

まだ、式をよく見てませんが、
kirさんの
＞={SUM(N(TEXT(COLUMN(F:Z)/3+値,"aaa")&B4:V4=C9&F9))}
{=SUM(N(TEXT(COLUMN(F:Z)/3,"aaa")&B4:V4=C9&F9))}
で４８文字ではダメなのかな？

[投稿情報: からくち]

＞からくちさんなどには想定の範囲かと思いますが、、
遊ばせていただきましたので・・・
ここに書こうかな・・・どうしよう
と思っていた中で被ったのは
：=(SUMIF(3:3,C9,A4)=F9)+(SUMIF(3:3,C9,B4)=F9)+(SUMIF(3:3,C9,C4)=F9)
これくらいと思います、、、多分

：｛=SUM((INT(COLUMN(C:W)/3)*3-2=MATCH(C9,B3:V3,))*(B4:V4=F9))｝

：=INDEX(FREQUENCY((B4:V4=F9)*COLUMN(A:U),(ROW(1:8)-1)*3),MATCH(C9,3:3,)/3+2)

：｛=3-LEN(SUBSTITUTE(SUM((B3:T3=C9)*(B4:T4&C4:U4&D4:V4)),F9,))｝

：=LOOKUP(1,0/(B3:T3=C9),3-LEN(SUBSTITUTE((B4:T4&C4:U4&D4:V4),F9,)))

：｛=SUM(N(MID(SUM(IF(B3:T3=C9,(B4:T4&C4:U4&D4:V4))*1),{1,2,3},1)*1=F9))｝

：=INDEX((A4:T4=F9)+(B4:U4=F9)+(C4:V4=F9),MATCH(C9,3:3,))

：｛=SUM(N(INT(COLUMN(AG:BA)/3)*B4:V4=(INT(MATCH(C9,3:3,)/3)+11)*F9))｝

などなど・・・

あっ、、、そうそう もう１つ
自分的にはこれが１番好きな考え方かも・・・

：=RIGHT(INT(INDEX(10^(B4:T4)+10^(C4:U4)+10^(D4:V4),MATCH(C9,B3:V3,))/10^F9))

[投稿情報: y sakuda]

kirさんの途中で頭が痛くなってきたｗ
で、覗きに来たら、からくちさんのが・・・
ますますよう分からんのが増えた＾＾；
今晩見きれない感じですねーー

[投稿情報: む印]

うひょー、今回皆さんバリエーション豊富ですねー
からくちさんはいつものことだけど、
こんなに出てくるとは想像してませんでした、、

minさんはSUMIFの使い方とか、いろいろ面白いけど
特に「値:D4」って、・・・・こんなの知りませーん、
いったいどうなってるの？

kirさんの非OFFSETの最初のやつは
私も同じでしたｄ＾＾
本来なら保護して隠すつもりだったので
B6使用は想定外でした。

しかし、ラベルとは考えましたねぇー＾＾ｂ

＞む印さんの非Offsetは
＞{=SUM(N(COLUMN(B:V)-MOD(COLUMN(C:W),3)&B4:V4=MATCH(C9,3:3,)&F9))}
＞で65になりますね。
あぁっそうかぁー、なるほど！そうすればよかったんですねぇ～、、

いずれにせよ、どれも一見しただけでは理解し辛いですねぇー

[投稿情報: kir]

>で４８文字ではダメなのかな？
曜日の変動があるから「+値」が必要でした。

[投稿情報: y sakuda]

ところで、む印さん、値って名前は定義だけしてサンプルシートでは使わなかった残骸ですか？

[投稿情報: ますたあ]

皆さんの式に圧倒されてしまって．．．。^ ^;

今回は何とかできましたってだけで
式のアップは勘弁してもらおうかな。
こじ付けでやっと作った式だしね。(^^ゞ
披露するようなものではありません。

一応、ＳＵＭ関数とＮ関数を使いました。

[投稿情報: くまぷー]

いや～、頭の痛くなるような数式の
オンパレードですねぇ・・・

レベルが上がりすぎてあっぷあっぷです～

[投稿情報: minmax]

＞曜日の変動があるから「+値」が必要でした。
もしかしてと思って
サンプルシートをダウンロードして
B6をみたらB6に数式が入っていたのね。
自分はB6セルを何時のまにか消去していて何でと思ってしまった。
何で「=TEXT(2+値,"aaa")」
みたいな意味の無い式を使っているのかずっと疑問に思っていたんですが、自分が悪かったのね。

[投稿情報: む印]

値ってあれのことでしたかー

ホントは保護掛けて全部隠すつもりで作ったのですが、、
ちゃんとチェックできてませんでした、、
なので残骸ではなく「失敗作」ということで・・・
コンテストなら即没ですねぇ(-_-;）＞

[投稿情報: y sakuda]

値は曜日の所で使ってらっしゃいますね。
忘れてた＾＾；

[投稿情報: kir]

>む印さんの非Offsetは
{2,2,2,5,5,5・・・}の配列部分がもう少し短縮出来そう。
FLOOR(COLUMN(C:W),3)-1

[投稿情報: む印]

＞FLOOR(COLUMN(C:W),3)-1
うひょー、感激的な短縮ですぅー(^^)/

[投稿情報: ジョー３]

皆さん、凄すぎるので・・・・
単純なヤツを出しときます。
（はずかしいけど）
=(INDEX(B4:V4,MATCH(C9,B3:V3,0))=F9)+(INDEX(B4:V4,MATCH(C9,B3:V3,0)+1)=F9)+(INDEX(B4:V4,MATCH(C9,B3:V3,0)+2)=F9)

[投稿情報: kir]

からくちさんの
^（　）+^（　）+^（　）の括弧は無くてもＯＫでした。
興味が出たので別の桁取りパターンも考えてみました。
69：=LEFT(RIGHT(INDEX(10^B4:V4+10^C4:W4+10^D4:X4,MATCH(C9,B3:V3,)),F9+1))
64：{=MID(MAX((10^B4:V4+10^C4:W4+10^D4:X4+10^4)*(B3:V3=C9)),5-F9,1)}

[投稿情報: ジョー３]

＞興味が出たので別の桁取りパターンも考えてみました。
うひゃーー・・・・研究熱心だねーー

[投稿情報: kir]

もひとつ、からくちさんの真似で
64：=INDEX(FREQUENCY((B4:V4=F9)*COLUMN(C:W),MATCH(C9,3:3,)+{0;3}),2)

[投稿情報: む印]

いやはや、どれも面白すぎる、、

非OFFSET
＞((COLUMN(A:U)-MATCH(C9,3:3,))^2<2)
＞(B4:T4=F9)+(C4:U4=F9)+(D4:V4=F9)
＞CHOOSE({1;2;3},B4:V4,C4:W4,D4:X4)
＞(B4:T4&C4:U4&D4:V4)
　などなど、、みなさん3列単位を旨く取得されてるなぁー・・・

同単位結合セル範囲の考え方として、
いい勉強させていただきました！
　（次はランダム単位のセル結合でやってみたいけど
　　こればっかりはマクロ仕掛けないとｗｗｗ・・・sakudaさ～ん^^;）

それにしてもOFFSETの幅指定でマイナス使えるのは収穫でしたねぇー

[投稿情報: y sakuda]

毎度のことですが、からくちさんのLookupとFrequencyは上手く使うもんですねーー
感心します。
kirさんのText　aaa　も丸で無駄やって長くなるような気がするんですが、結構短くまとまるんですね。見せられると納得しちゃう＾＾；

[投稿情報: y sakuda]

>こればっかりはマクロ仕掛けないとｗｗｗ・・・sakudaさ～ん^^;）
問題の形にするの面倒なら、アイデアくまぷーさんに送れば具体化してくれるとオモフ・・・・
一つアイデア送りましたがどんな問題に化けるか興味深々ですｗ

>それにしてもOFFSETの幅指定でマイナス使えるのは収穫でしたねぇー
できるの知ってましたけど、普通あまり使って得する局面はないんじゃないかと思ってましたから、気が付くのにすごく時間がかかっちゃった＾＾；

[投稿情報: からくち]

＞^（　）+^（　）+^（　）の括弧は無くてもＯＫでした。
はい、ここに書くときは少しくらいは分かりやすくと・・・
文字数をより短くからは外れている式ですので

＞別の桁取りパターンも考えてみました。
実際は７０パターン程ありますので
：｛=MID(TEXT(SUM((B3:T3=C9)*(10^(3-B4:T4)+10^(3-C4:U4)+10^(3-D4:V4))),"000"),F9,1)｝
：｛=LEFT(RIGHT(0&SUM((B3:T3=C9)*(10^B4:T4+10^C4:U4+10^D4:V4)),F9+1))｝
：｛=RIGHT(INT(SUM((B3:T3=C9)*(10^B4:T4+10^C4:U4+10^D4:V4))/10^F9))｝
：｛=MID(TEXT(SUM((B3:T3=C9)*(10^B4:T4+10^C4:U4+10^D4:V4)),"0000"),4-F9,1)｝
：=INT(INDEX(10^(B4:T4=F9)+10^(C4:U4=F9)+10^(D4:V4=F9),MATCH(C9,B3:V3,))/10)
などなど
似たようなのもが幾つもあります

[投稿情報: からくち]

あっ、、、忘れていました
この問題に相応しい？１２３文字を

：｛=SUM(N(MID(TEXT(SUM(B4:M4*10^(12-COLUMN(A:L))),0)&TEXT(SUM(N4:V4*10^(9-COLUMN(A:I))),0),MATCH(C9,3:3,)+{-1,0,1},1)*1=F9))｝

[投稿情報: y sakuda]

>実際は７０パターン程ありますので
コメントすらできない・・・・・・
私なんか思いついた手法10通りもないと思う・・・・・

[投稿情報: minmax]

sakudaさん
＞{=SUM(((COLUMN(A:U)-MATCH(C9,3:3,))^2<2)*(B4:V4=F9))}
う～ん、こんな式よくおもいつくな～
それから、スペースの参照演算子、私も使おうと思いましたが長くなりそうなので止めました。

それにしても、みなさんの発想のすばらしさには感心します。
私の発想は単純だって感じた次第です。

からくちさんには、、、、まいった。。

[投稿情報: y sakuda]

^2は一筆書きでABSの代替で皆さん良く使ってた手法だと思いますけど＾＾

>それから、スペースの参照演算子、私も使おうと思いましたが長くなりそうなので止めました。
私も一筆書きのAreas,ISREF系以外で初めて使いました。
これでChooseのやつが10文字くらい短縮できました。

からくちさんの53が基準て発言に触発されてできたのが53の式で当初これ以外ありえないんじゃないかと思ってたんですが、minmaxさんの関数1種との発言で？？？って感じになりました。
それにしても皆さんのやり方が全然違うのに非Offsetの最短が53辺りに集中したの不思議ですねーー

[投稿情報: minmax]

ところで、
=(SUMIF(3:3,C9,A4)=F9)+(SUMIF(3:3,C9,B4)=F9)+(SUMIF(3:3,C9,C4)=F9)
のような数式については、以前研究したことがあるのですが、この場合、シート内の数式を変更しなくても必ず、ブックを閉じるときに保存するか聞いてきますよね。
（今回の場合、RANDを使っているので当たり前なのですが、まっさらなブックに前記数式を入れてある場合、そのブックを開いて、何もしないで閉じる際に保存するか聞いてきます。エクセル2003ならですが）
以前から、不思議に思っていました。
理由が分かりますか？
すみません。からくちさんなら、知っているかもと思い質問してみました。

[投稿情報: ますたあ]

やっぱり、式をアップすることにします。
式を示せなくては問題を解けた証明にないｒませんものね。^_^;

非常に単純な式です。
皆さんのような難解ではなくて
パッと見れば分かる式です。^_^;

私が投稿すると、ここのレベルを下げてしまいますが（くまぷーさん、すいません）
ギャラリーに甘んじておられる方々が
敷居が下がって参加しやすくなる？
かも知れませんからね。(^^ゞ

{=SUM(N(B3&B4:D4=C9&F9),N(E3&E4:G4=C9&F9),N(H3&H4:J4=C9&F9),N(K3&K4:M4=C9&F9),N(N3&N4:P4=C9&F9),N(Q3&Q4:S4=C9&F9),N(T3&T4:V4=C9&F9))}

[投稿情報: くまぷー]

昨日はインターハイの地区予選で１日中体育館で仕事をしていたので疲れてしまい
早く寝てしまいました。

さて、昨日も書きましたが難解な数式の山で・・・
全部、解読するのには何ヶ月もかかってしまいそう・・・

・・・というか一生かかってもわからないものも・・・(^^ゞ

いや、参りました。
◇＼(o・Ｑ・o)／◇

[投稿情報: くまぷー]

＞アイデアくまぷーさんに送れば具体化してくれるとオモフ・・・・
＞一つアイデア送りましたがどんな問題に化けるか興味深々ですｗ

あんまり、期待されるとプレッシャーが・・・(^^ゞ

[投稿情報: くまぷー]

＞私が投稿すると、ここのレベルを下げてしまいますが（くまぷーさん、すいません）

そんなことはありません。(^O^)
これからもよろしくです。m(_ _)m

やはり、わかりやすいのが
おいら的には一番です(^_^)b

[投稿情報: y sakuda]

>非常に単純な式です。
アイデアとしてはkirさんの67と改造版の50と同じですね。
出されて見ると当たり前に見えますが、提示されたのではkirさん以外にはなかったんじゃないかな？
私はC9&F9と比較するって発想はカケラも出なかったです。

[投稿情報: からくち]

＞知っているかもと思い質問してみました。
ご期待に応えられず申し訳ないですが、わたしは殆ど知識と言うものを持ち合わせていません
従いましてあくまで勝手な想像です

一般的な書き方
（１）=SUMIF(A1:A10,"A",B1:B10)
の場合では問題無いですが
（２）=SUMIF(A1:A10,"A",B1)
とした場合に起こりえる現象ですよね

これをもう少し進めて？
（３）=SUMIF(A1:A10,"A",B1:B5)
この様に書いた場合も同様の現象になるかと思います

逆に
（４）=SUMIF(A1:A10,"A",B1:B15)
この様に書いた場合では起こらないかと思います

ここで注目したいのは（３）と（４）です
勿論ですが一般的にはこの様な書き方をする人はいないと思いますが
（３）でも合計はＢ１０までされてしまいます

此方の事情で取りあえず今はＢ５までの数値が欲しい
ただ将来的にはＢ１０でに伸ばしたいので（３）の様に書いているだけ
としてもエクセル君は書いていないＢ１０まで計算してしまいます
若しこれが合計範囲の書き違いだったなら大変ありがたいですが
意図的な場合ですと余計なお世話
ありがた迷惑と言ったところ

式はあくまでＢ５なので取りあえずはＢ５まで計算すると思います
しかし範囲がＡ１０までありますので
改めてＢ１０まで計算して結果を出している
つまり勝手に反復計算をしているための現象
と言う想像は如何でしょうか

（４）の様な書き方をしてもＢ１０までしか計算されません
Ａ１５・Ｂ１５まで入力があっても
つまり反復計算は行なわれないようです
従いまして（４）ではこの現象は起きない

と勝手な想像をしてみました

お役に立てず
すみません

[投稿情報: minmax]

からくちさんから回答？がいただけて非常に感謝しております。
からくちさんのおっしゃるとおり、
第３引数が第１引数の範囲より短い場合に起こる現象ですよね。
私は、エクセル２００７を持っていませんが、２００７ではむしろ
=SUMIF(A1:A10,"A",B1)
のような使い方を一般的な使い方として認めているようですね。
その際に、２００３と同様の再計算的な現象が起こるかは不明ですが。

EWの日記にも書いたことがありますが、以前
http://www.efcit.co.jp/cgi-bin2/exqalounge.cgi?print+200705/07050052.txt
で色々やっていました。

しかし、このような現象を全てお見通しとは、恐れ入りました。

[投稿情報: minmax]

念のため、ツタンカーモンが私です。

[投稿情報: y sakuda]

今朝割と早く目を覚ましたので、昨晩コピーした式を眺めてました。
今回はバリエーションが豊富で面白かったですねーー
なるほど！っての満載で、今度使ってやろうかと思える手法も沢山あるんですが・・・
実際にいざと言う時に浮かんでくるのは極一部なんだろうな＾＾；

[投稿情報: からくち]

minmax さんへ

お役に立つことが出来ずすみませんでした
と言うことで何かないかと探してみました

既にご存知のことかも知れませんが
その場合は知らなかった人も見ているかもと言うことでご勘弁を ←・・・身勝手な発言

＞84:=COUNTIF(INDEX((B4:D4,E4:G4,H4:J4,K4:M4,N4:P4,Q4:S4,T4:V4),,,MATCH(C9,3:3,)/3+1),F9)
この式の
MATCH(C9,3:3,)/3+1
の部分に小数点以下がそのままになっています
この式では分母が３なので全く関係ありませんが

=INDEX({1,2,3,4,5,6,7,8,9,10},3.999999761465)
で３が戻り、
これを超える引数では、４が戻ります。

また
63.999999761465 は ６３
64.999999761465 は ６５
999.999999761465までは＋１
その後1000.999999761465からは切り捨てになります

長くなりますので止めますが
詳細はまだまだ続きます

ただしこの数値はわたし自身が割り出したものですので
誤りがありましたらごめんなさい
多分大丈夫と思いますけど

[投稿情報: minmax]

＞既にご存知のことかも知れませんが
いえいえ、存じません。

＞これを超える引数では、４が戻ります。
へー不思議ですね。
＞MATCH(C9,3:3,)/3+1
については今回土曜の朝に十分な検証をせずに書いた式です。

前にからくちさんから教えて頂いたTEXT関数の特性を思い出しました。

ありがとうございました。

[投稿情報: ますたあ]

くまぷーさん、y sakudaさん、コメントありがとうございます。

これからも、遠慮なく参加させてもらいます。(^^ゞ

まあ、来るなって言われても来ちゃうかもしれませんけどね。^^;

[投稿情報: minmax]

ますたあさんの式も結構好きですよ。

ところで、ちょっと眠れなかったので、
今さらですが、、
=COUNT(IF(N(INDIRECT("r4c"&MATCH(C9,3:3,)+{0,1,2},))=F9,))
（５８文字）
こんな式が有効とは？？
計算の途中でエラーになる？のですが、最後の結果はちゃんと返す？？
配列数式にする必要も無し。

[投稿情報: ますたあ]

＞ますたあさんの式も結構好きですよ。
サンクスです。(*^_^*)

＞=COUNT(IF(N(INDIRECT("r4c"&MATCH(C9,3:3,)+{0,1,2},))=F9,))

う～～む、ちょっとやそっとでは解読できそうにないな～～。^^;

[投稿情報: y sakuda]

＞=COUNT(IF(N(INDIRECT("r4c"&MATCH(C9,3:3,)+{0,1,2},))=F9,))

フィーリングとしてはなるほどなんですが、なぜNが無いと動かないのか謎＾＾；
どうもIndirectの中で配列使うとへんなことになるみたいですね。

[投稿情報: くまぷー]

みなさん、お早うございます。

今日、第21問を公開するつもりですが
部活指導のため、ちょっと遅くなりそうです。

[投稿情報: む印]

ちょっと来てなかったら、またいろいろと・・・

からくちさんの、桁取りパターンってまるでパズル的で凄いですねー
こんなに複雑な組み立てを思いつける頭脳が羨ましい！

minさんの
＞=COUNT(IF(N(INDIRECT("r4c"&MATCH(C9,3:3,)+{0,1,2},))=F9,))

実は私も５３を探してたとき
=SUM(COUNTIF(INDIRECT("R4C"&MATCH(C9,3:3,)+{0;1;2},),F9))
・・・というのが在りましたが、これとは雲泥の差がある、、
y sakudaさん同様にN関数をこうして使うことには驚きました！！
一見したとき、括弧の位置が間違ってると思ったぐらい・・・
因みに、
=COUNT(0/(N(INDIRECT("r4c"&MATCH(C9,3:3,)+{0;1;2},))=F9))
=SUM(N(N(INDIRECT("r4c"&MATCH(C9,3:3,)+{0,1,2},))=F9))
というのもやってみました。
又々面白いことを教わることが出来ましたｄ＾＾

[投稿情報: minmax]

む印さんの
ちなみに以下…
全くおんなじことやっていました。

[投稿情報: y sakuda]

>実は私も５３を探してたとき
そう言えばむ印さんの53ってのはどんなのでしょうか？
からくちさんが最初におっしゃってた基本５３てのも謎ですが・・・・・

[投稿情報: む印]

>そう言えばむ印さんの53ってのはどんなのでしょうか？
最初に見つけたのは kirさんのと同じ
｛=SUM((COLUMN(3:3)=MATCH(C9,3:3,)+{0;1;2})*(4:4=F9))｝　でした。

からくちさんの基本53はたぶん、minさんの53だと思うのですが・・・

[投稿情報: y sakuda]

私はてっきり私の53しかないと思い込んでたｗ
どうも普通のタイプじゃなかったみたいですねーー