第１３７回 逃げられないのは？ 解答例

解答例
【練習問題】
46 {=SUM(N(B2:J10+A2:I10+C2:K10+B1:J9+B3:J11=0))}
【問題】
83 {=SUM(N(LEN(B2:J10&TEXT(B1:J9,0)&TEXT(A2:I10,0)&TEXT(B3:J11,0)&TEXT(C2:K10,0))=5))}

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　(minさん）

Comments

[投稿情報: ｎｉ]

TEXTなんて、思いつかなかった・・・
というか、TEXTだよ　といわれても、分からない＾＾；

９４はみんな同じだと思うけど、
９４{=SUM(N(LEN(B2:J10&A2:I10&C2:K10&B1:J9&B3:J11)+(MOD(COLUMN(A:I),8)=1)+(MOD(ROW(1:9),8)=1)=5))}

[投稿情報: くまぷー]

よーし！！行くぞ！！

=SUM(N(IF(B2:J10>"",1,)+IF((B1:J9>"")+(B1:J9=0),1,)+IF((B3:J11>"")+(B3:J11=0),1,)+IF((A2:I10>"")+(A2:I10=0),1,)+IF((C2:K10>"")+(C2:K10=0),1,)=5))

１４５文字です。　(^^ゞ

[投稿情報: jyo-3]

>９４はみんな同じだと思うけど、
あはは、、、そそ、、、・・・・ん、、、、rowが先だった。・・・・
まあ、、、同じだよね、,,,・・・９９．９％

[投稿情報: くまぷー]

あやちゃんさんから解答を頂きました。

=SUMPRODUCT(((B2:J10="●")+(B3:J11="●")+(B1:J9="●")+(A2:I10="●")+(C2:K10="●")+({1,0,0,0,0,0,0,0,1}+{1;0;0;0;0;0;0;0;1})=5)*1)

１２４文字

maronさんからも全く同じものを頂きました。
HNは違うけど同一人物ですね？

maronさんから２つめということで・・・

◆すこし、短くなりましたが、108

=SUMPRODUCT((B2:J10&B3:J11&B1:J9&A2:I10&C2:K10&REPT("●",{1,0,0,0,0,0,0,0,1}+{1;0;0;0;0;0;0;0;1})="●●●●●")*1)

(maron)

maronさん、次回からは私にメールで送らないで
直接、コメント欄に投稿して下さいd(^-^)ネ!
よろしくお願いいたします。　m(__)m

[投稿情報: y sakuda]

練習問題ですが、数字として扱うと言う発想がなぜか抜け落ちちゃったｗ
50です。
{=SUM(N((B2:J10&B1:J9&B3:J11&A2:I10&C2:K10)*1=0))}
{=81-COUNT(0/(B2:J10&B1:J9&B3:J11&A2:I10&C2:K10))}

で、問題の方ですが、94にすらいきませんでした。
99
{=SUM(N(LEN(B2:J10&B1:J9&B3:J11&A2:I10&C2:K10&REPT(1,{1;0;0;0;0;0;0;0;1}+{1,0,0,0,0,0,0,0,1}))=5))}
Textなんか頭をかすめもしなかったですね。元々Textの扱いへたくそですけどねｗ

[投稿情報: y sakuda]

そうか94はそういう仕掛けか。
私の99の元は102で
{=SUM(N(LEN(B2:J10&B1:J9&B3:J11&A2:I10&C2:K10&REPT(1,(ABS(ROW(1:9)-5)=4)+(ABS(COLUMN(A:I)-5)=4)))=5))}
MODの方面には発想が行ってません。

[投稿情報: y sakuda]

maronさんてここでは新人？ですが、Answersなんかに良く出てくるmaron-23さんかな？
式の癖が似ているような気がします。

[投稿情報: む印]

きょうは運動会
先ほどまでくたばってて、、遅くなりました、、

とにかく思いついた式 全部です、、
練習問題
46
{=SUM(N(A2:I10+C2:K10+B1:J9+B3:J11+B2:J10=0))}
45
{=SUM(N(A2:I10+C2:K10+B1:J9+B3:J11=-B2:J10))}

問題
83
{=SUM(N(LEN(TEXT(A2:I10,0)&TEXT(B1:J9,0)&TEXT(B3:J11,0)&TEXT(C2:K10,0)&B2:J10)=5))}
91
{=SUM(N(TEXT(A2:I10,"●")&TEXT(B1:J9,"●")&TEXT(B3:J11,"●")&TEXT(C2:K10,"●")&B2:J10>"●●●●"))}
94を2種
{=SUM(N((A2:I10=0)+(B1:J9=0)+(B3:J11=0)+(C2:K10=0)+LEN(A2:I10&C2:K10&B1:J9&B3:J11&B2:J10)=5))}
{=SUM((TEXT(A2:I10,"●")&TEXT(B1:J9,"●")&TEXT(B3:J11,"●")&TEXT(C2:K10,"●")>"●●●")*LEN(B2:J10))}
95
{=COUNT(LN(LEN(A2:I10&C2:K10&B1:J9&B3:J11&B2:J10)-(A2:I10>0)-(B1:J9>0)-(B3:J11>0)-(C2:K10>0)))}

でした。

&禁止ならこんな感じで・・・
98
{=SUM(LEN(TEXT(A2:I10,0))*LEN(TEXT(B1:J9,0))*LEN(TEXT(B3:J11,0))
*LEN(TEXT(C2:K10,0))*LEN(B2:J10))}

[投稿情報: y sakuda]

む印さんの練習問題45もすごいですが、＆禁止でも98とは飛んでもねーな。

[投稿情報: min]

結局今日はいえにかえれません
家から持ってきた式を分割して出します

練習問題
これはむ印さんといっしょ
45{=SUM(N(B2:J10+A2:I10+C2:K10+B1:J9=-B3:J11))}

これでもいい

45{=SUM(N(B2:J10+A2:I10+C2:K10+B1:J9=B3:J11%))}  

[投稿情報: y sakuda]

なるほど、0の場合なら-でも％でもいいわけだ。

[投稿情報: min]

94は思っていたものとちょっとだけ違いました、

92{=SUM(N((A2:I2=0)+(B1:B9=0)+(C2:K2=0)+(B3:B11=0)+LEN(B2:J10&B1:J9&A2:I10&B3:J11&C2:K10)=5))}
91{=SUM(N((MOD(ROW(1:9),8)=1)+(A2:IW(1:9),8)=1)+(A2:I2>0=(C2:K2=0))+LEN(B2:J10&B1:J9&A2:I10&B3:J11&C2:K10)=5))}

[投稿情報: min]

うまく投稿できないので再度

練習問題
45{=SUM(N(B2:J10+A2:I10+C2:K10+B1:J9=-B3:J11))}
45{=SUM(N(B2:J10+A2:I10+C2:K10+B1:J9=B3:J11%))}  

問題 
92{=SUM(N((A2:I2=0)+(B1:B9=0)+(C2:K2=0)+(B3:B11=0)+LEN(B2:J10&B1:J9&A2:I10&B3:J11&C2:K10)=5))}
91{=SUM(N((MOD(ROW(1:9),8)=1)+(A2:I2=0)+(C2:K2=0)+LEN(B2:J10&B1:J9&A2:I10&B3:J11&C2:K10)=5))}
91{=SUM(N((MOD(ROW(1:9),8)=1)+(A2:I2>0=(C2:K2=0))+LEN(B2:J10&B1:J9&A2:I10&B3:J11&C2:K10)=5))}
 
106{=SUM(N(LEN(B2:J10&B1:J9&A2:I10&B3:J11&C2:K10&SUBSTITUTE(SUBSTITUTE(ROW(1:9)&COLUMN(A:I),1,22),9,22))=7))}
103{=SUM(N(LEN(B2:J10&B1:J9&A2:I10&B3:J11&C2:K10&SUBSTITUTE(MOD(ROW(1:9),8)&MOD(COLUMN(A:I),8),1,22))=7))} 

[投稿情報: min]

この問題、空白と未入力セルを区別する必要がある。
未入力のセルが０と等しいかを確認することで未入力セルかどうか判定できる。

その一方で未入力セルは、TEXT関数で数値と判定するので
これに気がつけば、
＝TEXT（範囲,0）
がすんなり出てくる可能性が多い。
これに気がついた方は、どう考えてもそれ以上短くならないと思うのでその瞬間に問題は終了してしまう。
TEXTに気がつく方は結構いると思ったんですが、案外少なかったので、ちょっとほっとした次第です。

＞９４はみんな同じだと思うけど、
私が想像していた９４はむ印さんの９４（TEXTを使わない方）の方でした。

[投稿情報: ｎｉ]

短くならない９４、空白セルの判定が難しかったです。

[投稿情報: ジョー３]

最初から、、
碁
みたいだなー・・・
と、、
面白かった。

niさんと、、完璧に、、思考が、、、同じだったことも、、
・・・・・・・・・・・・・・・・面白かった。

[投稿情報: む印]

＞(A2:I2=0)+(B1:B9=0)+(C2:K2=0)+
なるほど、、この範囲取りで２文字減らせるのか～
納得です！

[投稿情報: ジョー３]

>その一方で未入力セルは、TEXT関数で数値と判定するので・・・
気づいてなかった。

だから、、、
一応解けたから、、ってことで、、、

modの筋、、、＋αと、、、思い

α・・・が、閃かないだけと、思い込んだ。

[投稿情報: 春]

text関数の使い方…凄い
結局僕は、、
{=SUM((LEN((A2:I10&B1:J9&C2:K10&B3:J11))*(B2:J10="●")+({1,0,0,0,0,0,0,0,1}+{1;0;0;0;0;0;0;0;1})=4)*1)}
102文字どまりでした。
最初は外回りを81個分手打ちしたので、200文字超えてました。

[投稿情報: くまぷー]

>text関数の使い方…凄い ×２

＞最初は外回りを81個分手打ちしたので

おいらは外回りを「●」で埋めてしまいました　(^^ゞ

[投稿情報: jyo-3]

>最初は外回りを81個分手打ちしたので、200文字超えてました。
81個分の外回り?・・・だと３２個?

[投稿情報: jyo-3]

>81個分の外回り?・・・だと３２個?
あ、、、間違ってしまった。
・・・・・・・・あはは、、、安産良くない・・・ｎｏｎｏ
暗算良くない、、、間違い多い、、・・・

[投稿情報: む印]

今回皆さんのようにCOLUMN：{1,0,0,0,0,0,0,0,1}+ROW：{1;0;0;0;0;0;0;0;1}で
配列を作ってしまう方法は全く発想できませんでした、、

その発想を見習ってやってみましたが
91
{=SUM(N(LEN(B2:J10&B1:J9&A2:I10&B3:J11&C2:K10)+((ROW(1:9)-5)^4+(COLUMN(A:I)-5)^4)/256>=5))}
やはりまた、一筆書きっぽくなってしまいました、、、

[投稿情報: y sakuda]

よう、そんな上手い組み合わせ見つけるもんですねーー

[投稿情報: jyo-3]

ん？？
row、columnを使って９１ですか？・・・自分のとならべてみると、、

私９４
{=SUM(N(LEN(B2:J10&B1:J9&B3:J11&A2:I10&C2:K10)+(MOD(ROW(1:9),8)=1)+(MOD(COLUMN(B:J),8)=2)=5))}
む印さん９１
{=SUM(N(LEN(B2:J10&B1:J9&A2:I10&B3:J11&C2:K10)+((ROW(1:9)-5)^4+(COLUMN(A:I)-5)^4)/256>=5))}
なぜ、、/256とかが有るのに短い?・・・・
あ、、、、modの2回ないぶんか？

[投稿情報: min]

確かに一筆書に近い気が

大したもんだ～