第１７９回 人口は、、、 解答例（代理）

からくちさんのPCがトラブっていて出題者解答例を

送れないみたいなので僭越ながら・・・・

 

手順1：検索すべきデータを何とか規則的に並べる。

　　　　　国名、数字、という形に統一したい。ところが行末の

　　　　　数字には「、」がないので、それを補う。

　　　　　B7&"、"&B9&"、"&B11&"、"&B13&"、"&B15&"、"&B17&"、"&B19&"、"　　　　・・・（1）

 

手順2：Find関数で（1）から国名（B5）を検索する。

　　　　　=FIND(B5,B7&"、"&B9&"、"&B11&"、"&B13&"、"&B15&"、"&B17&"、"&B19&"、")　・・・(2)

 

手順3：人口を表す数字は(2)で求めた数値に国名の文字数プラス1（句点）から始まるので・・・

　　　　=FIND(B5,B7&"、"&B9&"、"&B11&"、"&B13&"、"&B15&"、"&B17&"、"&B19&"、")+LEN(B5)+1　・・・(3)

　　　　これで人口を示す数字の開始位置がわかった。

 

手順4：手順3で人口を示す数字の開始位置が分かったので終了位置を求めたい。

　　　　Find関数で検索開始位置を「人口を示す数字の開始位置」以降にして「、」の位置を求めると・・・

　　　　=FIND("、",B7&"、"&B9&"、"&B11&"、"&B13&"、"&B15&"、"&B17&"、"&B19&"、",(3)の式)　　・・・(4)

手順5：Mid関数で必要な部分を切り出す。

　　　　=MID(B7&"、"&B9&"、"&B11&"、"&B13&"、"&B15&"、"&B17&"、"&B19&"、",(3)の式,(4)の式-(3)の式)

 

いやあ、その結果・・・210文字　＼(><)/ギョッ

 

=MID(B7&"、"&B9&"、"&B11&"、"&B13&"、"&B15&"、"&B17&"、"&B19&"、",FIND(B5,B7&"、"&B9&"、"&B11&"、"&B13&"、"&B15&"、"&B17&"、"&B19&"、")+LEN(B5)+1,F5-(FIND(B5,B7&"、"&B9&"、"&B11&"、"&B13&"、"&B15&"、"&B17&"、"&B19&"、")+LEN(B5)+1))

（くまぷー）

 

 

 

Comments

[投稿情報: む印]

最初の考え方ではここまでが精一杯でした
74：=-LOOKUP(,-LEFT(LOOKUP(B7,MID(B7:B19,FIND(B5,B5&0&B7:B19,2),5)),ROW(1:5)))
72：{=MAX(TEXT(MIDB(B7:B19,FINDB(B5,B5&B7:B19&B5,2)+1,{2,4,6}),"0;;;!0")^1)}

54は、ただ短いだけでして・・・重いです・・・^^;
{=MATCH(,-FIND(B5&"、"&ROW(A:A),B7&PHONETIC(B:B)&B19))}

この54をもう少し軽くした63
{=MATCH(,-FIND(B5&"、"&ROW(A:A),LOOKUP(,-FIND(B5,B1:B19),B:B)))}

※一応全部、2003にも対応させたつもりです。

[投稿情報: maron]

◆夢の５０台の解答が出る前に・・・
◆maronの最短回答：７０
=-LOOKUP(,-MID(LOOKUP("ー",MID(B:B,FIND(B5&"、",B5&B:B),9)),2,ROW(1:5)))
◆関数のダブり使用のない回答：７７
{=MAX(TEXT(MID(B7:B19,FIND(B5,B7:B19&B5)+LEN(B5)+1,{1,2,3,4,5}),"0;;;!0")*1)}

[投稿情報: y sakuda]

皆さんの中身確認してませんが、私のは83
（A：Aタイプを使えば動きは遅いが77になります）
=LOOKUP(9^9,LEFT(SUBSTITUTE(MID(B7:B19,FIND(B5,B7:B19)+LEN(B5),9),"、"," "),9)*1)
範囲1個方式は全然短くならなかったです^^；
しかし、この問題初めて見たら結構奥が深く楽しかったです。

[投稿情報: ｼﾞｮｰ3]

phonetic やったが、、、うまくいかなかった。

lookup 　これも、・・・・・

２００７　で、・・・・・

[投稿情報: からくち]

すみません、、、お手数をおかけ致します
諦めました、、、明日家電屋さんに行って来ます

解答例をと思っていたのは
Find（b5,範囲）
これをmatchで括れば行
Lookupでは列を得られる事を使った式です

バックアップの必要性を強く感じている今日この頃、、、
今更遅い、、、

[投稿情報: y sakuda]

くまぷーさん
済みませんが、くまぷーさんのどこか貼り付けミスされてるんじゃ？
Valueになっちゃいます。

ところで、お二方ともTextうまく使われてるのがありますが、ちょいと教えてください。
今回そもそもTextって発想はなかったんでそこで終わってますがｗ
!0　って言うのを使われてるけど、これ知りませんでした。
改めて見て見ましたがそういう記述MS等のサイトにも見当たらないです。
Helpとかどこかに記述あるようなら教えてください。

お二方のものすごい奴ばかりなんで、私がいろいろ試した普通のやつをいくつか出します。
原始的にやった102
=LOOKUP(9^9,MID(B7&B9&B11&B13&B15&B17&B19,FIND(B5,B7&B9&B11&B13&B15&B17&B19)+LEN(B5)+1,COLUMN(A:E))*1)
素朴にエラー処理いれた123
{=MAX(IF(ISERR(MID(B7:B19,FIND(B5,B7:B19)+LEN(B5)+1,COLUMN(A:F))*1),,MID(B7:B19,FIND(B5,B7:B19)+LEN(B5)+1,COLUMN(A:F))*1))}
範囲指定を一つですまそうと無駄な努力をした99
=LOOKUP(9^9,LEFT(SUBSTITUTE(RIGHT(SUBSTITUTE(B7:B19,B5&"、",REPT(0,50)),50),"、",REPT(" ",50)),50)*1)

[投稿情報: y sakuda]

ありゃま、からくちさんサブPCとかバックアップファイルとか無いんですか？
キャリアの長い方だから、否応なしに古いPCとかいくつかそのまま転がってそうなんですがねｗ

しかし、投稿されてるってことは携帯かなんかからですか？
携帯持ってるんだｗ
σ(^^)未だに携帯すら持ってない人ですｗ

[投稿情報: y sakuda]

む印さんのPhonetic意味が良く分からん・・・・
ああ言うタイプの式だとF9で中身確認できないし・・・・
まあ、元々発想の方向性が全く違うから衝撃的でした。
なにを考えた式かまでは一応分かりましたが、まるで別世界じゃｗ

[投稿情報: む印]

＞!0
TEXTの表示形式は昔こちらで同じような質問をkirさんにして、
いろいろ教わったように記憶しています。

y sakudaのSUBSTITUTEを使うやり方ですが
第3引数の置き換え文字は空白4つですか？
LEFTBを使うと全角の空白二つで同じ様に出来ます。
=-LOOKUP(,-LEFTB(SUBSTITUTE(MID(B7:B19,FIND(B5,B5&B7:B19,2),9),"、","　　"),9))

[投稿情報: む印]

あ、y sakudaさん呼び捨ててました、、、
失礼しましたm(__)m

[投稿情報: y sakuda]

>あ、y sakudaさん呼び捨ててました
そういうのは気にしないで結構ですｗ
LeftBかそれも考えなかったな。
それに、マイナスにして、Lookupってのは考えなかったです。
昇順にならんでないと・・・・と言うのが固定観念になってたな。

Lookupと言えば、これが不思議
=LOOKUP(9^9,MID(B7:B19,FIND(B5,B7:B19)+LEN(B5)+1,COLUMN(A:E))*1)
でうまく行くはずと思ったんですがダメ。
どうも列の最初と最後には有効データがないと答えが出ないらしい・・・
一列全部が数字になってればOKなんでブラジル等最後の国やインドのように5ケタの国は正解が出ます。
まあ、エラーデータ込のLookupとかMatchなんて公式な動きの定義があるわけじゃないですがねｗ
そうか！０はkirさんか。そう言えばこの頃とんとお見かけしないですねーー

[投稿情報: y sakuda]

私の投稿、半角ブランクが消えちゃってますね。
ご指摘の通り4個です。
=LOOKUP(9^9,LEFT(SUBSTITUTE(MID(B7:B19,FIND(B5,B7:B19)+LEN(B5),9),"、","　　　　"),9)*1)
まあ、これが最短だったんですが、Substiを使わざる得なかったのが癪の種。
余程のことがないと短縮勝負じゃ使ったとたんに負け決定ですからねーー

[投稿情報: む印]

Phoneticはデフォルトではカタカナ設定の範囲セルのふりがなを
すべて繋いで返しますので、B7&B9&B11&B13&B15&B17&B19とするより5文字
減らせると思って使った反則です、、^^;

[投稿情報: kumapooh]

>くまぷーさん
>済みませんが、くまぷーさんのどこか貼り付けミスされてるんじゃ？

すみません。
きちんと代入していないところがありました。
正しくは・・・
=MID(B7&"、"&B9&"、"&B11&"、"&B13&"、"&B15&"、"&B17&"、"&B19&"、",FIND(B5,B7&"、"&B9&"、"&B11&"、"&B13&"、"&B15&"、"&B17&"、"&B19&"、")+LEN(B5)+1,FIND("、",B7&"、"&B9&"、"&B11&"、"&B13&"、"&B15&"、"&B17&"、"&B19&"、",FIND(B5,B7&"、"&B9&"、"&B11&"、"&B13&"、"&B15&"、"&B17&"、"&B19&"、")+LEN(B5)+1)-(FIND(B5,B7&"、"&B9&"、"&B11&"、"&B13&"、"&B15&"、"&B17&"、"&B19&"、")+LEN(B5)+1))

なんと驚異の344文字でした～！！

[投稿情報: y sakuda]

>すべて繋いで返しますので、
なるほど。それで、B7とB19 を&かｗｗｗ
良く考えるなーー

>なんと驚異の344文字でした～！！
代理解答ご苦労様でしたｗ

[投稿情報: ｼﾞｮｰ3]

>B7&PHONETIC(B:B)&B19
へーーー、、、、
アメリカ、日本、中国、、、、、が、、、、

へーーーー、、
そうなんですかーーーー

へーーーーー

[投稿情報: ｼﾞｮｰ3]

みなさん、、、２００７のしか、、、・・・・だせなくてごめん、、
６０

{=MAX(IFERROR(MID(B:B,FIND(B5,B5&B:B,2)+1,{1,2,3,4,5})*1,))

[投稿情報: maron]

◆む印さんをはじめ皆さんの解答は、見ているだけで楽しく参考になります、ありがとうございました

＞（A：Aタイプを使えば動きは遅いが77になります）
=-LOOKUP(,-MID(LOOKUP("ー",MID(B:B,FIND(B5&"、",B5&B:B),9)),2,ROW(1:5)))
◆A:Aタイプの解答ですが、それほど、動きは遅く感じませんが、maronだけでしょうか？

◆＆を使わない解答は、（む印さんの解答を参考にして）
=-LOOKUP(,-MID(LOOKUP(B5,MID(B:B,FIND(B5,B1:B19)+LEN(B5),9)),2,ROW(1:5)))

[投稿情報: からくち]

たて
match(,-find(b5,b7:b19))

よこ
-lookup(,-find(b5,b7:b19))

[投稿情報: maron]

◆次の、問題の発表はいつでしょうか？

[投稿情報: y sakuda]

在庫ゼロだと・・・・

[投稿情報: kumapooh]

>在庫ゼロだと・・・・

その通りで・・・

[投稿情報: ｼﾞｮｰ3]

さて、、
では、、、
途中までしか解けてないのを、、、出そうかなーーーー

今回も、、短くは解けそうになさそうなのに・・・
みんな、、解いてるからねーーー

さてさて、、、

[投稿情報: maron]

◆ｼﾞｮｰ3さん、お願いします、問題を見るのが楽しみです・・・

[投稿情報: ｼﾞｮｰ3]

あはは、、、実は、自分で遊んでるだけなのだ、、、が、、、

5段階、、、ランダム遊び・・・なのだ。

まだ、、、3段階までしか、、、解けてないのだ。。

[投稿情報: からくち]

ご迷惑をおかけいたしました

ＸＰより７に格上げしました（何故か８は避けてしまった）
まだまだ、、、使い難いです

＞まだ、、、3段階までしか、、、解けてないのだ。。
偶には結果、、、何方も解けなかった
そんな出題も、、、ありと思います

また、、、超～難しく我々には手におえなかっただけ
悔しいけど、、、そんな問題も面白い

[投稿情報: kumapooh]

maronさんから問題をいただきました。
ありがとうございます。

明日にでも公開いたしますので
皆様、よろしくお願いいたします。m(__)m